Simple Helpbot v1.3

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	7.6
Scores Submitted	11
Date Added	Jan 09, 2005
Last Updated	Sep 19, 2005
Tags	botscript helpdesk helpserv

Introduction

A Simple Helpdesk script for a mIRCbot in a Help Channel that was based from one of Undernet's Help Channel (#zT). When a user joins your help channel, they will be added to the queue then OPs type !next for the next user to be helped. The only time a user can be removed from the queue is when they are voiced, opped, kicked, quit, parted the channel. Copy/paste to your bot's remote section (ALT-R -> FILE -> NEW). To set/change the Help Channel, right click on the channel or click on the menu bar.

Grab the Code

;================================================
;  Simple Helpbot
;  Version 1.3 
;  Written by: xDaeMoN
;  Email: xdaemon@xdaemon.us
;
;    Commands:  (MUST BE AN OP)
;
;    !help on/off = To turn on/off the script
;    !next = will get the next user to be helped
;    !done <nick> = used after helping nick
;    !list = will list users on queue
;    !clist = will list users currently being helped (NEW)
;
;================================================

on !*:JOIN:%help.chan: {
  if ( $readini(uhelp.ini,config,stat) ) {
    writeini uhelp.ini $chan $_n1($nick) help
    .notice $nick Please wait for your turn as we are busy right now. You will be voiced automaticly when we finish with the current guests. You are number $ini(uhelp.ini,$chan,0) in line. Thank You
  }
}

on *:TEXT:!*:%help.chan: {
  if ( $nick isop $chan ) {
    if ( !help == $1 ) {
      if ( $2 == on ) {
        if (!$readini(uhelp.ini,config,stat)) {
          writeini uhelp.ini config stat 1
          .notice $nick ** Enabled Help Desk.
          .msg $chan Help Desk for $chan is now in session.
        }
        else .notice $nick Help desk is already enabled
      }
      elseif ( $2 == off ) {
        if ($readini(uhelp.ini,config,stat)) {
          .remove uhelp.ini
          .notice $nick ** Disabled Help Desk.
          .msg $chan Help Desk for $chan is now OFF.
        }
        else .notice $nick Help desk is already disabled
      }
    }
    elseif ( $1 == !next ) {
      if ($readini(uhelp.ini,config,stat)) {
        nextuser $nick $chan
      }
      else .notice $nick Help Desk is not Enabled.
    }
    elseif ( $1 == !done ) {
      if ( $readini(uhelp.ini,config,stat) ) {
        if ( $2 ison $chan ) { 
          if ( $readini(uhelp.ini,current,$_n1($2)) ) {
            mode $chan -v $2
            remini uhelp.ini current $_n1($2)
            .notice $2 Your query has been answered. Please part the channel now. Thank you.
          }
          else .notice $nick ** Insufficient Parameters: !done <nick that has been helped>
        }
        else .notice $nick ** Insufficient Parameters: $2 is not on $chan $+ .
      }
      else .notice $nick Help Desk is not Enabled
    }
    elseif ( $1 == !list ) {
      if ( $readini(uhelp.ini,config,stat) ) {
        if ($ini(uhelp.ini,$chan,0) ) {
          .notice $nick ** $v1 User(s) on Help list **
          var %hc = 1
          while $ini(uhelp.ini,$chan,%hc) {
            .notice $nick $_n2($v1) 
            inc %hc
          }
          .notice $nick ** End of Help List **
        }
        else .notice $nick Currently Helped list is empty.
      }
      else .notice $nick Help Desk is not Enabled
    }
    elseif ( $1 == !clist ) {
      if ( $readini(uhelp.ini,config,stat) ) {
        if ( $ini(uhelp.ini,current,0) ) {
          .notice $nick ** $v1 User(s) Currently Helped list **
          var %h = 1
          while $ini(uhelp.ini,current,%h) {
            .notice $nick $readini(uhelp.ini,current,$_n2($v1)) is currently helping $_n2($v1)
            inc %h
          }
          .notice $nick ** End of List **
        }
        else .notice $nick Help list is empty.
      }
      else .notice $nick Help Desk is not Enabled
    }
  }
}

alias nextuser {
  if ( $ini(uhelp.ini,$2,0) ) {
    if ( $_n2($ini(uhelp.ini,$2,1)) ison $2 ) {
      mode $2 +v $v1
      .notice $v1 $1 will help you now
      remini uhelp.ini $2 $_n1($v1)
      writeini uhelp.ini current $_n1($v1) $1
    }
    else {
      remini uhelp.ini $2 $_n1($v1)
      .timer 1 1 nextuser $1 $2
    }
  }
  else .notice $1 Help list is empty.
}

alias _n1 { return $replace($1,[,�,],�) }

alias _n2 { return $replace($1,�,[,�,]) }

on !*:PART:%help.chan: {
  if ( $readini(uhelp.ini,current,$_n1($nick)) ) remini uhelp.ini current $_n1($nick)
  elseif ( $readini(uhelp.ini,$chan,$_n1($nick)) ) remini uhelp.ini $chan $_n1($nick)
}

on !*:OP:%help.chan: {
  if ( $readini(uhelp.ini,$chan,$_n1($opnick)) ) remini uhelp.ini $chan $_n1($opnick)
}

on *:SERVEROP:%help.chan: {
  if ( $readini(uhelp.ini,$chan,$_n1($opnick)) ) remini uhelp.ini $chan $_n1($opnick)
}

on !*:QUIT: {
  if ( $readini(uhelp.ini,current,$_n1($nick)) ) remini uhelp.ini current $_n1($nick)
  elseif ($readini(uhelp.ini,%help.chan,$_n1($nick))) remini uhelp.ini %help.chan $_n1($nick)
}

on !*:KICK:%help.chan: {
  if ( $readini(uhelp.ini,current,$_n1($knick)) ) remini uhelp.ini current $_n1($knick)
  elseif ($readini(uhelp.ini,$chan,$_n1($knick))) remini uhelp.ini $chan $_n1($knick)
}

on !*:VOICE:%help.chan: {
  if ( $readini(uhelp.ini,$chan,$_n1($vnick)) ) {
    remini uhelp.ini $chan $_n1($vnick)
  }
}

menu menubar,channel {
  Help Channel $iif(%help.chan, $+($chr(40),$v1,$chr(41)), (NONE))
  .$iif(%help.chan,Change, Set Help Channel):set -s %help.chan #$$?="Enter Help #Channel:"
}

Comments

(65) RSS

Go to Bottom

spikey

Comments: 8

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 12, 2005 4:24 am

When i do !next it doesn\'t voice the user :/

legan

Comments: 10

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 12, 2005 5:43 am

xDaeMoN: i Think this is more for :: hosting companeys :: nice job :) :: are you dutch ?

spikey

Comments: 8

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 12, 2005 6:53 am

okay i got it to work :)

xDaeMoN

Comments: 696

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 12, 2005 8:52 am

Legan: Thanks. No, I\'m Filipino. =)

xDaeMoN

Comments: 696

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 13, 2005 2:35 am

Updated. Used ini files to track users.

legan

Comments: 10

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 13, 2005 5:13 pm

XdeaMoN how doest this works ? Must i doe somthing special ? it wont work :S if i do !next i get there is now one in the list :: hwo can i add poeple ? i have tried wuth +m and -M and trying to hop en stuf :S i dont know

xDaeMoN

Comments: 696

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 13, 2005 5:40 pm

Kinda messed it up when I last updated it. It\'s fixed now. Thanks to kiko.

legan

Comments: 10

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 14, 2005 1:58 am

:D its work now ^^ i thouch thath somthing was missing :: ^^

xDaeMoN

Comments: 696

mIRC Snippet: Simple Helpbot v1.3
Posted on Jan 29, 2005 3:09 pm

Updated. Added on/off trigger.

GRAZ

Comments: 1

mIRC Snippet: Simple Helpbot v1.3
Posted on Feb 4, 2005 12:04 pm

I like it but what section do I put it in? And for some reason it\'s not writing users in the ini file. Or it\'s just not giving me users when I type !next also what section does it go in? Does all go in remote?

xDaeMoN

Comments: 696

mIRC Snippet: Simple Helpbot v1.3
Posted on Feb 4, 2005 12:21 pm

This goes to the remotes section. ALT-R -> FILE ->NEW then paste this script. You would also need to set the help channel by doing \"/set %help.chan <#channel>\". This will auto-add the users to the list & type !next to retrieve the next user in line.

Psycho3

Comments: 14

mIRC Snippet: Simple Helpbot v1.3
Posted on Feb 8, 2005 11:54 am

Users with []-_` ect wont get +v why?!

Psycho3

Comments: 14

mIRC Snippet: Simple Helpbot v1.3
Posted on Feb 8, 2005 11:57 am

And the /set ... dosent work when i type the /set.. nothing happens :S. Did i do somthing wrong?

Psycho3

Comments: 14