;Prowl api iphone highlight script by Ford_Lawnmower irc.MindForge.org #USA-Chat
;This script was made at the request of Geekologist irc.WyldRyde.org
;Installation of OpenSSL is required to use Prowl api --->>  http://www.mirc.com/download/openssl-0.9.8k-setup.exe
;Install OpenSSL and then restart mIRC before using this script.
;You will also be prompted to accept or reject Prowl, as they do not have a SSL Certificate for some reason ;/
;To use this script, you will have to accept. 
;Help installing Prowl on your iphone and mac/pc is here -->>  https://prowl.weks.net/installation.php
;Register to use Prowl here --->>  https://prowl.weks.net/register.php
;To create an api key go here -->> https://prowl.weks.net/settings.php  <<---You must be registered and logged in.
;Your iphone or other device must be logged on to Prowl for this to work.
;Message limit is 1000 messages per hour!
;
;Alias Syntax /Prowl apikey priority event-must-be-one-string text to send.
alias Prowl {
  if ($2 !isnum -2-2) || (!$4) { echo -st Syntax is /Prowl apikey priority event-must-be-one-string text to send. -- Priority must be a number between -2 and 2. | return }
  sockopen -e prowl prowl.weks.net 443
  sockmark prowl $1 $2 $fixurl($+($network,-,$chan)) $fixurl($3) $fixurl($4-)
}
On *:sockopen:prowl:{
  tokenize 32 $sock($sockname).mark
  sockwrite -nt $sockname GET $+(/publicapi/add?apikey=,$1,&priority=,$2,&application=,$3,&event=,$4,&description=,$5-)
  sockwrite -n  $sockname Host: prowl.weks.net $+ $+($crlf,2)
}
On *:sockread:prowl:{
  if (!$sockerr) {
    var %prowl | sockread %prowl
    if (<success code isin %prowl) { echo -at 07Message sent Successfully!  | sockclose $sockname }
    if (<error code isin %prowl) { echo -at 04An error occurred. Your message was not sent! | sockclose $sockname }
  }
}
#prowl on
On *:text:*:*:{
  if (%ProwlAwayOnly) && (!$away) { return }
  if ($istok($strip($1-),$me,32)) && (%Prowlapikey) {
    if ($timer($+(prowl,$nick,$network))) { return }
    .timer $+ $+(prowl,$nick,$network) 1 5 noop
    Prowl %prowlapikey 1 Highlight $nick said: $1-
  }
}
#prowl end
menu status,channel {
  Prowl Highlight
  .Set api key: set %prowlapikey $$?"Enter Your Prowl API Key"
  .$iif(!%prowlapikey,$style(2),$iif($group(#prowl) == on,$iif((!%ProwlAwayOnly),$style(1)))) Prowl Highlight Always On:.enable #prowl | unset %ProwlAwayOnly
  .$iif(!%prowlapikey,$style(2),$iif(%ProwlAwayOnly == on,$style(1))) Prowl Highlight On Away Only:.enable #prowl | set %ProwlAwayOnly on
  .$iif($group(#prowl) == off,$style(1)) Prowl Hightlight Off:.disable #prowl | unset ProwlAwayOnly
}
alias -l fixurl return $regsubex($1-,/([^a-z0-9])/ig,% $+ $base($asc(\t),10,16,2))
 

Commenting Options