on *:TEXT:!learn *:#: {
  if (!$3) {
    notice $nick You didn't specify the right parameters.
    notice $nick Syntax: !learn <topic> <description>
  }
  else {
    hadd -m learn $strip($2) $3-
    msg $chan Data $3- saved as topic: $strip($2)
  }
}
on *:TEXT:!remember *:#: {
  if (!$2) {
    notice $nick You didn't specify the right parameters.
    notice $nick Syntax: !remember <topic>
  }
  elseif (!$hget(learn,$strip($2))) {
    msg $chan No data was found for $2 $+ .
  }
  else {
    msg $chan Results for $strip($2) $+ : $hget(learn,$2)
  }
}
on 10:TEXT:!forget *:#: {
  if (!$2) {
    notice $nick You didn't specify the right parameters.
    notice $nick Syntax: !forget <topic>
  }
  elseif (!$hget(learn,$strip($2))) {
    msg $chan No data was found for $strip($2) $+ .
  }
  else {
    msg $chan Removed topic $strip($2) ( $+ $hget(learn,$strip($2)) $+ ) from the database.
    hdel learn $strip($2)
  }
}
alias viewlearn {
  window -a @Learn
  var %x = 1
  while (%x <= $hget(learn,0).item) {
    echo -g @Learn $hget(learn,%x).item $+ : $hget(learn,%x).data
    inc %x
  }
}
on *:EXIT: { hsave learn learn.txt }
on *:START: { 
  if (!$isfile(learn.txt)) {
    noop $input(The hash table for the learn bot could not be found.,uwo,Error!)
  }
  else {
    hmake learn 100
    hload learn learn.txt 
  }
}

Commenting Options