Check the About and How to Use in the script. Use the Help menu to get there.
on *:load:{ $iif($hget(AutoOper),noop,hmake AutoOper 100) }
on *:start:{ $iif($hget(AutoOper),noop,hmake AutoOper 100) | autooperload }
on *:exit:{ autoopersave }
on *:connect:{ autooperup $server }
menu * {
AutoOper:autooper
}
dialog autooper {
title "AutoOper v1.0"
size -1 -1 109 130
option dbu
list 1, 6 11 96 53, size vsbar sort
edit "", 2, 10 77 85 12
edit "", 3, 10 101 85 12
button "OK/Cancel", 4, 10 116 35 12, default ok cancel
button "Save Info", 5, 60 116 35 12
box "Password", 6, 7 93 93 23
box "Oper Nick", 7, 7 69 93 23
box "Servers", 8, 3 3 102 65
menu "File", 9
item "Add Server", 10, 9
item "Delete Selected Server", 11, 9
item "Exit", 12, 9, ok
menu "Help", 13
item "How to Use", 14, 13
item "About", 15, 13
}
dialog aophtu {
title "How to Use AutoOper v1.0"
size -1 -1 155 84
option dbu
text "Adding a Server: To add a server, /simply click on File and then click Add Server. You will then be prompted to enter the Server and Oper Iniformation.", 2, 3 18 48 66
text "Deleting a Server: To delete a server, either double click on a Server in the list or select a Server from the list, then click File and select Delete Selected Server.", 3, 55 18 48 66
text "Savie/Update Info: To Save or Update your Oper info for a Server, simply select the Server from the list, fill in your information then click Save Info.", 4, 107 18 47 66
text "Press Esc or Click X to Close", 5, 2 1 68 8
}
dialog aopa {
title "Coded by Sonny"
size -1 -1 85 70
option dbu
text "© 2011", 1, 1 61 19 8
text "AutoOper is a script used to automate the task of becoming an Operator or Administrator on a Server using a specified Nickname and Password.", 2, 12 11 63 40
text "Email/IM: influxity@live.com", 3, 10 1 69 8
text "Version 1.0", 4, 2 54 29 8
button "Like Us!", 5, 46 56 37 12
link "Sonny", 6, 21 61 22 7
}
on *:dialog:aopa:sclick:5:{ run http://facebook.com/chatpad }
on *:dialog:aopa:sclick:6:{ run http://facebook.com/influxity }
on *:dialog:autooper:init:*:{
lautooperservs
did -b AutoOper 2,3
}
on *:dialog:autooper:sclick:*:{
if ($did > 6 || $did == 0) { did -b AutoOper 2,3 | did -u AutoOper 1 }
if ($did == 1) { if ($did(1).seltext) { did -e AutoOper 2,3 } }
if ($did == 4) { dialog -x AutoOper AutoOper }
if ($did == 1 && $did(AutoOper,1).seltext != $null) {
did -ra AutoOper 2 $gettok($hget(AutoOper,$v1),1,124)
did -ra AutoOper 3 $gettok($hget(AutoOper,$v1),2,124)
}
if ($did == 5) { sautooperinfo }
}
on *:dialog:autooper:menu:*:{
if ($did == 10) { autooperaddserv | lautooperservs }
;echo -a $did(AutoOper,1).seltext
if ($did == 11) {
if ($did(AutoOper,1).seltext != $null) {
autooperdel $did(AutoOper,1).sel
}
else { noop $input(You Did Not Select a Server from the List,hdo,Error: No Server Selected!) }
}
if ($did == 14) { dialog -m aophtu aophtu }
if ($did == 15) { dialog -m aopa aopa }
}
on *:dialog:autooper:dclick:1:{ if ($did(autooper,1).sel != 0) { autooperdel $v1 } }
alias autooper { dialog $iif($dialog(AutoOper),-x,-m) AutoOper AutoOper }
alias autooperaddserv {
var %s $iif($input(Input Server Name,ideok120,Input Server Name),$v1,$null)
var %n $iif($input(Input Oper Nickname for %s,ideok120,Input Oper Nickname),$v1,$null)
var %p $iif($input(Input Oper Password for %s $crlf $+ NOTE: This will be masked by *,idpok120,Input Oper Password),$v1,$null)
if (%s != $null && %n != $null && %p != $null) { hadd AutoOper %s $+(%n,|,%p) }
else { noop $input(The Information You Input Was Invalid. $crlf $+ Oper Information Was not Saved.,hdo,Error: Invalid Oper Information!)
}
}
alias autooperup {
if ($hget(AutoOper,$1)) {
oper $gettok($v1,1,124) $gettok($v1,2,124)
}
}
alias autooperdel {
if ($input(Are You Sure You Want to Delete $+($did(AutoOper,1,$1),?),idy,Prompt to Delete $did(AutoOper,1,$1)) == $true) {
.hdel -s AutoOper $did(AutoOper,1,$1)
did -r AutoOper 2,3
did -d AutoOper 1 $1
}
}
alias autoopersave { hsave AutoOper AutoOper.txt }
alias autooperload { hload AutoOper AutoOper.txt }
alias sautooperinfo {
var %a AutoOper
if ($did(%a,1).seltext != $null && $did(%a,2) != $null && $did(%a,3) != $null) {
hdel -s %a $did(%a,2)
hadd %a $did(%a,1).seltext $+($did(%a,2),|,$did(%a,3))
}
else { noop $input(Invalid Information Specified, Could not Save Oper Information.,hdo,Error: Invalid Oper Information!) }
}
alias lautooperservs {
var %n $hget(AutoOper,0).item
var %x 1
did -r AutoOper 1
while (%x <= %n) {
did -a AutoOper 1 $hget(AutoOper,%x).item
inc %x
}
}