That High

Platform: mIRC

Published May 07, 2011

Updated May 18, 2011

316 11

Random "That High" grabber from http://thathigh.com. Same thing as FML, MLIA etc, just stoner related. I didn't see one on here so I figured I'd post one up.

on $*:TEXT:/^([!.@])th$/Si:#:{ 

  if (!%f) { inc -u3 %f | if ($sock(thathigh)) sockclose thathigh

    sockopen thathigh www.thathigh.com 80

    sockmark thathigh $iif($regml(1) = !,msg #,notice $nick)~$&

      $+($chr(40) ThatHigh™ $chr(41))

  }

}



on *:SOCKOPEN:thathigh: {

  sockwrite -nt $sockname GET /random/ HTTP/1.1

  sockwrite -nt $sockname Host: $sock(thathigh).addr $+ $str($crlf,2)

}



on *:SOCKREAD:thathigh: {

  if !($sockerr) {

    var %thsock | sockread %thsock

    if (*storylink* iswm %thsock) {

      tokenize 32 %thsock

      $sock(thathigh).mark $nohtml(%thsock) | sockclose thathigh

    }

  }

}



alias nohtml { return $regsubex($$1-,/^[^<]*>|<[^>]*>|<[^>]*$/g,) }

Comments

cptpan - Dec 03, 2012

Dead

1 Response

MashhitDK - Apr 10, 2013

It has been for a long time... but site back up now...
and random pages actually works... wrote one earlier
and just tested the above... it's working \o/

hxck - Oct 11, 2011

Thanks

Respond

Xavia - Oct 10, 2011

+Like

Respond

MashhitDK - May 15, 2011

EPiC idea... more stoner related scripting please \o/

Respond

napa182 - May 08, 2011

@troll Jethro_'s version of it does what you asked

Respond

troll - May 08, 2011

I love the concept and the script , but can you implent

'ON $*:TEXT:/^[@!.]th(that|high)/Si:#:{

and

$iif($left($1,1) == @,msg $chan,notice $nick)

so that it can be public or priv ?

Respond

hxck - May 07, 2011

I used my "Feels Like" weather script napa, the one you helped me with a while back, which was originally written when I was first learning sockets so it was pieced together from a few scripts I had found. I just changed a few things and threw it up here, cause I had looked for one a couple weeks ago and didn't find one.

Respond

napa182 - May 07, 2011

almost looks like you used that socket maker to make this. an yes this can be done a lot of diff ways urs is one Jethro_'s was another an mine is another way. in mine i added the Puff an Pass ratings just for the hell of it..
Oh an to say if it ain't broke don't fix it is just dumb. This site is to show diff ways to go about things. Thats why people post diff versions as comments.

		Code 			
on $*:text:/^@thc$/iS:#:{  
  if (!%f) { inc -u3 %f
    if ($sock(thc)) sockclose thc
    sockopen thc www.thathigh.com 80  
    sockmark thc msg # 09[04That High09]
    msg # ***Looking up Random "That High Quote"***
  } 
}
on *:sockopen:thc: { 
  sockwrite -nt thc GET /random/ HTTP/1.1  
  sockwrite -nt thc Host: $+($sock(thc).addr,$str($crlf,2)) 
}
on *:sockread:thc: { 
  var %thc | sockread %thc
  if ($regex(%thc,/<a class="storylink.+>(.+?)<\/a>/)) { hadd -m thc 1 $sock(thc).mark $regml(1) }
  if ($regex(%thc,/<a rel="nofollow" href=.+>(.+?)<\/a>\s(\50\d+\51)/)) { inc -u3 %thcc 1
    $iif(%thcc = 1,hadd -m thc 2 $+(04,$regml(1),09) $regml(2),$&
      $hget(thc,1) $hget(thc,2) $+(04,$regml(1),09) $regml(2)) 
  }
}	

Respond

Jethro - May 07, 2011

I wasn't attempting to correct the author of this snippet. I was encouraging the author to use the mIRC inbuilt command and identifier in place of the global variable and the common no html alias. This is what Hawkee is for, a social networking site where every one of us can have a say or input of a posted snippet. Those who read the comment shouldn't feel acrimonious in any way.

P.S. The example that I showed above was a modification of someone's FML's snippet, ported for a different website. I posted it under his snippet thread. I re-posted here to show it to other people, and don't surprised that they do use examples found under a snippet thread.

Respond

RicJames - May 07, 2011

More than one way to skin a cat and if it ain't broke don't fix it imo. Plus Jethro_ the reason he and others missed it is you haven't posted it to hawkee snippets so how are they to find it.

You should submit yours as well that way people can have a choice.

Respond

Jethro - May 07, 2011

You probably have missed mine. I made this for someone a few days ago:

		Code 			
on $*:text:/^([!.@])TH$/Si:#:{
  if (!%pro) { inc -u4 %pro | if ($sock(TH.)) sockclose $v1
    sockopen TH. www.thathigh.com 80
    sockmark TH. $iif($regml(1) = !,msg #,notice $nick)~$&
      $+($chr(3),1,$chr(40),$chr(3),2,Random ThatHigh™,$chr(3),1,$chr(41))
  }
}
On *:SOCKOPEN:TH.:{
  if (!$sockerr) {
    sockwrite -n $sockname GET /random/ HTTP/1.1
    sockwrite -n $sockname Host: $sock(TH.).addr $+ $str($crlf,2)
  }
}
On *:SOCKREAD:TH.:{
  if (!$sockerr) {
    var %TH | sockread %TH | if (storylink isin %TH) {
      tokenize 62 $remove($v2,<a class=" $+ $v1 $+ " href="//",</a)
      $gettok($sock(TH.).mark,1,126) $* | sockclose $sockname
    }
  }
}	

On a side note, you should really take advantage of the sockmark and $sock().mark for temporary data storage. The generic no html alias can also be omitted.

Respond