Simple MemoServ 1.3

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	6.2
Scores Submitted	6
Date Added	Mar 07, 2005
Last Updated	Oct 22, 2005
Tags	addon botscript memo system

Introduction

A simple botscript which acts like Memoserv that will save the message & notify the person addressed to retrieve it. If the person is offline, they will be notified when they get back online.**Update: User needs to be registered to be able to send & retrieve a message. I added a simple register system and you could also change your password.Copy & paste to your bot's remotes section. (ALT-R -> FILE -> NEW)

Grab the Code

;===============================================
; Simple Memoserv
; Version 1.3 
; Written by: xDaeMoN
; Email: xdaemon@xdaemon.us
;
;** Commands: **
;
; To send message: /msg botname !send <nick> <message>
; To retrieve message: /msg botname !read <password>
;
; Note: User needs to be registered to be able to send & retrieve a message
;
; To register: /msg botname !register <password>
; To change password: /msg botname !cpass <oldpassword> <newpassword>
;===============================================

On *:START: { 
  hmake memo 100 
  if ($isfile(memo.dat)) hload memo memo.dat 
}

On *:EXIT: hsave -o memo memo.dat

on ^*:OPEN:?:!*: {
  if ( $1 == !send ) {
    if ( $level($nick) == memo ) {
      if ( $3 ) {
        if ( $level($2) == memo ) { 
          hadd -m memo $+($network,.,$2) $addtok($hget(memo,$+($network,.,$2)),$+($nick,:) $3- $+(<,$fulldate,>),157)
          if ($2 !isnotify) .notify $2
          $+(.,timer,notify,.,$2) 1 5 checknick $2 $nick $network
        }
        else notice $nick ** $2 is not registered to receive messages.
      }
      else notice $nick !Syntax: !send <nick> <message>
    }
    else .notice $nick Sorry, you are not registered. To register, do "/msg $me !register <yourpassword>".
  }
  elseif ( $1 == !read ) {
    if ( $level($nick) == memo ) { 
      if ( $2 ) {
        if ( $md5($2) == $ulist($nick,memo,1).info ) {
          if ( $hget(memo,$+($network,.,$nick)) ) {
            var %r = 1
            .timer 1 2 .notice $nick � � You have $numtok($v1,157) message $+ $iif( $numtok($v1,157) > 1, s)
            while $gettok($hget(memo,$+($network,.,$nick)),%r,157) {
              .timer 1 $calc(%r * 2) .notice $nick %r $+ ) $v1
              inc %r
            }
            .timer 1 $calc(%r * 2) .notice $nick � � End of Messages.
            .notify -r $nick
            hdel memo $+($network,.,$nick)
          }
          else .notice $nick You have no messages.
        }
        else .notice $nick Wrong password.
      }
      else .notice $nick Syntax: !read <password>
    }
    else .notice $nick Sorry, you are not registered. To register, do "/msg $me !register <yourpassword>".
  }
  elseif ( $1 == !register ) {
    if ( $level($nick) != memo ) { 
      if ( $2 ) {
        .auser memo $nick $md5($2)
        .notice $nick ** Added $nick to database Successfully.
      }
      else .notice $nick Syntax: !register <password> 
    }
    else .notice $nick $+(",$nick,") already exists in the database.
  } 
  elseif ( $1 == !cpass ) {
    if ( $level($nick) == memo ) { 
      if ( $3 ) {
        if ( $md5($2) == $ulist($nick,memo,1).info ) {
          .auser memo $nick $md5($3)
          .notice $nick ** Password for $nick changed Successfully.
        }
        else .notice $nick Wrong Password.
      }
      else .notice $nick Syntax: !cpass <oldpassword> <newpassword> 
    }
    else .notice $nick Sorry, you are not registered. To register, do "/msg $me !register <yourpassword>".
  } 
  haltdef
}

alias -l checknick {
  if ( !$notify($1).ison ) .notice $2 $1 is offline & will be notified when online.
  else .notice $2 Message $+ $iif( $numtok($hget(memo,$+($3,.,$1)),157) > 1, s) sent to $1 $+ .
}

on *:NOTIFY: if ( $hget(memo,$+($network,.,$nick)) ) $+(.timermsg,$cid,$nick) 1 5 .notice $nick You have messages. Do "/msg $me !read <password>" to retrieve them.

Comments

(16) RSS

Go to Bottom

xDaeMoN

Comments: 696

mIRC Snippet: Simple MemoServ 1.3
Posted on Mar 7, 2005 2:47 pm

Updated. Messages are now read in ascending order.

splatted

Comments: 42

mIRC Snippet: Simple MemoServ 1.3
Posted on Mar 10, 2005 6:38 pm

very nice. Have you considered adding password protection? I find quite a few people use my nick when i'm not online. Anyone curious enough will check to ensure the message isn't for them, thereby inadvertantly deleting the message for the intended person

xDaeMoN

Comments: 696

mIRC Snippet: Simple MemoServ 1.3
Posted on Mar 10, 2005 6:55 pm

That is a nice suggestion, I'll update it when I have time. :)

DarthReven

Comments: 468

mIRC Snippet: Simple MemoServ 1.3
Posted on Mar 10, 2005 10:56 pm

nice lil script xDaeMon

xDaeMoN

Comments: 696

mIRC Snippet: Simple MemoServ 1.3
Posted on May 21, 2005 9:26 pm

** Updated. Added a user system so people needs to register first before they could send/receive a message.

xDaeMoN

Comments: 696

mIRC Snippet: Simple MemoServ 1.3
Posted on May 27, 2005 3:41 pm

** Updated. Now using hash tables.

storMaz

Comments: 3

mIRC Snippet: Simple MemoServ 1.3
Posted on Oct 22, 2005 12:39 am

it won't work for me, nothing happens with the commands at all, no reaction.

I just rewrote the commands a little, and translated it to swedish.

if you need to see code: http://pastebin.com/401653

storMaz

Comments: 3

mIRC Snippet: Simple MemoServ 1.3
Posted on Oct 22, 2005 12:41 am

nevermind, it was just me, sorry! your script works fine.

xDaeMoN

Comments: 696

mIRC Snippet: Simple MemoServ 1.3
Posted on Oct 22, 2005 7:16 pm

Minor Update: Added delay on reading the messages.

`Kazuma

Comments: 254

mIRC Snippet: Simple MemoServ 1.3
Posted on Nov 4, 2005 6:51 pm

very nice. gj

xtr

Comments: 18

mIRC Snippet: Simple MemoServ 1.3
Posted on Jan 26, 2006 11:32 am

and now update so we can delete memos ???

laff

xDaeMoN

Comments: 696

mIRC Snippet: Simple MemoServ 1.3
Posted on Jan 26, 2006 11:40 am

@ xtr, that would be included in the add-on version.

xtr

Comments: 18

mIRC Snippet: Simple MemoServ 1.3
Posted on Jan 26, 2006 12:14 pm

sounds nice.. i need this script 2tm... im using a ircd with my own auth/oper service and can�t use the memoserv as normal used with the same ircd version.... are you to be found on irc ?

xDaeMoN

Comments: 696

mIRC Snippet: Simple MemoServ 1.3
Posted on Jan 26, 2006 12:35 pm

Here's the addon I made & submitted at ms.org:http://www.mircscripts.org/comments.php?cid=2984

Cleaning out of old memos will be included in the next update along with some other fixes & updates.

mkh

Comments: 3

mIRC Snippet: Simple MemoServ 1.3
Posted on Jan 26, 2006 1:03 pm

yes, that is the one i have...... :/

`Kazuma

Comments: 254

mIRC Snippet: Simple MemoServ 1.3
Posted on Jan 31, 2006 12:37 pm

I'm not into bots, but its alright

Simple MemoServ 1.3

Introduction

Grab the Code

Comments

xDaeMoN

My Snippet Tags

Contact

Friends (17)

Sponsors

		United States Of Calamity
Last seen: Sep 24, 2008 Profile Friends (17) Scripts (3) Snippets (18) Comments Received (398) Comments Submitted (696) Forum Posts (5954)