Irssi theme for mIRC, new version :)
alias say {
var %target = $active, %string = $$1-
if (%target ischan) msg $v1 %string
elseif ($query(%target)) msg $v1 %string
elseif (=* iswm %target) msg $v2 %string
}
alias me {
var %target = $active, %string = $$1-
if (%target ischan) describe $v1 %string
elseif ($query(%target)) describe $v1 %string
elseif (=* iswm %target) describe $v2 %string
}
alias msg {
if ($isid) return
!.msg $$1-
if ($show) {
if ($1 ischan) {
var %prefix = $chr(32)
if ($me isowner $1) var %prefix = ~
elseif ($me isop $1) var %prefix = @
elseif ($me ishelp $1) var %prefix = %
elseif ($me isvo $1) var %prefix = +
echo -ti $+ $calc($indent + $len($me) + 5) $1 $+(14<15,%prefix,00,$me,14>) $+(15,$2-,)
}
elseif ($query($1)) {
echo -ti $+ $calc($indent + $len($me) + 4) $1 $+(14<00,$me,14>) $+(15,$2-,)
}
elseif (=* iswm $1) {
echo -ti $+ $calc($indent + $len($me) + 4) $1 $+(14<00,$me,14>) $+(15,$2-,)
}
else {
echo -ti $+ $calc($indent + 5) 14[05message14(04 $+ $1 $+ 14)14] $+(15,$2-,)
}
}
}
alias describe {
if ($isid) return
!.describe $$1-
if ($show) {
if ($1 ischan) {
echo -ti $+ $calc($indent + 5) $1 00 * $me $+ $+(15,$2-,)
}
elseif ($query($1)) {
echo -ti $+ $calc($indent + 5) $1 00 * $me $+ $+(15,$2-,)
}
elseif (=* iswm $1) {
echo -ti $+ $calc($indent + 5) $1 00 * $me $+ $+(15,$2-,)
}
else {
echo -ti $+ $calc($indent + 5) 14[05action14(04 $+ $1 $+ 14)14] $+(15,$2-,)
}
}
}
alias notice {
if ($isid) return
!.notice $$1-
if ($show) {
echo -ti $+ $calc($indent + 5) 14[05notice14(04 $+ $1 $+ 14)14] $+(15,$2-,)
}
}
alias ctcp {
if ($isid) return
!.ctcp $$1-
if ($show) {
echo -ti $+ $calc($indent + 5) 14[05ctcp14(04 $+ $1 $+ 14)14] $+(15,$2,) $+(15,$3-,)
}
}
alias ctcpreply {
if ($isid) return
!.ctcpreply $$1-
if ($show) {
echo -ti $+ $calc($indent + 5) 14[05notice14(04 $+ $1 $+ 14)14] $+(15,$2,) $+(15,$3-,)
}
}
alias query {
if ($isid) return
!.query $$1-
if ($show) {
var %query = $window(*,$window(*,0))
echo -nti $+ $calc($indent + 5) %query 12-15!12- 00Irssi: 15Starting query in $+(00,$network,) 15with $+(00,%query,)
}
}
alias indent {
if ($gettok($readini($mircini,options,n4),12,44)) return $len($timestamp)
return 0
}
on *:START: {
scid -a clearall
}
on *:EXIT: {
var %i = $scid(0)
while (%i) {
unset %sync. [ $+ [ $scid(%i) ] $+ ] .*
unset %names. [ $+ [ $scid(%i) ] $+ ] .*
unset %whois. [ $+ [ $scid(%i) ] $+ ] .*
unset %whowas. [ $+ [ $scid(%i) ] $+ ] .*
dec %i
}
}
on *:CONNECT: {
}
on *:DISCONNECT: {
unset %sync. [ $+ [ $cid ] $+ ] .*
unset %names. [ $+ [ $cid ] $+ ] .*
unset %whois. [ $+ [ $cid ] $+ ] .*
unset %whowas. [ $+ [ $cid ] $+ ] .*
}
on *:INPUT:*: {
if ($mid($1,1,1) === $readini($mircini,text,commandchar)) {
if ($ctrlenter) { }
else {
return
}
}
if ($halted) return
haltdef
var %target = $active, %string = $1-
if (%target ischan) msg $v1 %string
elseif ($query(%target)) msg $v1 %string
elseif (=* iswm %target) msg $v2 %string
}
on *:OPEN:?:*: {
echo -mti $+ $calc($indent + 5) $nick 12-15!12- 00Irssi: 15Starting query in $+(00,$network,) 15with $+(00,$nick,)
}
on *:OPEN:=: {
echo -nti $+ $calc($indent + 5) =$nick 12-15!12- 00Irssi: 15Starting query in $+(00,$network,) 15with $+(00,=$nick,)
}
on *:CLOSE:=: {
echo -nti $+ $calc($indent + 5) =$nick 12-15!12- 00Irssi: 15Closing query with $+(00,=$nick,)
}
on ^&*:TEXT:*:*: {
if ($halted) return
haltdef
if (# ischan) {
var %prefix = $chr(32)
if ($nick isowner #) var %prefix = ~
elseif ($nick isop #) var %prefix = @
elseif ($nick ishelp #) var %prefix = %
elseif ($nick isvo #) var %prefix = +
if ($highlight($1-)) {
echo -lbfmti $+ $calc($indent + $len($nick) + 5) # $+(14<15,%prefix,08,$nick,14>) $+(15,$1-,)
}
else {
echo -lbfmti $+ $calc($indent + $len($nick) + 5) # $+(14<15,%prefix,15,$nick,14>) $+(15,$1-,)
}
}
else {
echo -lbfmti $+ $calc($indent + $len($nick) + 4) $nick $+(14<04,$nick,14>) $+(15,$1-,)
}
}
on ^&*:ACTION:*:*: {
if ($halted) return
haltdef
if (# ischan) {
echo -lbfmti $+ $calc($indent + 5) # 00 * $nick $+ $+(15,$1-,)
}
else {
echo -lbfmti $+ $calc($indent + 5) $nick 00 * $nick $+ $+(15,$1-,)
}
}
on ^&*:NOTICE:*:*: {
if ($halted) return
haltdef
if (# ischan) {
echo -lbfmti $+ $calc($indent + 5) $+(14-13,$nick,14:06,#,14-) $+(15,$1-,)
}
else {
echo -lbfmti $+ $calc($indent + 5) 14-13 $+ $nick $+ 14(06 $+ $address $+ 14)14- $+(15,$1-,)
}
}
on ^&*:CHAT:*: {
if ($halted) return
haltdef
if (CTCP_MESSAGE ACTION ?* iswm $1-) {
echo -lbfmti $+ $calc($indent + $len($nick) + 11) =$nick 00 (*dcc*) $nick $+ $+(15,$mid($1-,22,-1),)
}
elseif (ACTION ?* iswm $1-) {
echo -lbfmti $+ $calc($indent + $len($nick) + 11) =$nick 00 (*dcc*) $nick $+ $+(15,$mid($1-,9,-1),)
}
else {
echo -lbfmti $+ $calc($indent + $len($nick) + 4) =$nick $+(14<04,$nick,14>) $+(15,$1-,)
}
}
on ^&*:JOIN:#: {
if ($halted) return
haltdef
if ($nick == $me) {
inc %sync. [ $+ [ $cid ] $+ . $+ [ # ] ]
set %sync. [ $+ [ $cid ] $+ . $+ [ # ] $+ ] .ticks $ticks
set %sync. [ $+ [ $cid ] $+ . $+ [ # ] $+ ] .mode $true
set %sync. [ $+ [ $cid ] $+ . $+ [ # ] $+ ] .ial $true
set %sync. [ $+ [ $cid ] $+ . $+ [ # ] $+ ] .ibl $true
;set %sync. [ $+ [ $cid ] $+ . $+ [ # ] $+ ] .iel $true
;set %sync. [ $+ [ $cid ] $+ . $+ [ # ] $+ ] .iil $true
who #
mode # b
;mode # e
;mode # I
}
echo -ti $+ $calc($indent + 5) # 12-15!12- $+(11,$nick,) $+(14[10,$address,14]) 15has joined $+(00,#,)
}
on ^&*:PART:#: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) # 12-15!12- $+(10,$nick,) $+(14[15,$address,14]) 15has left $+(00,#,) $+(14[15,$1-,14])
}
on ^&*:KICK:#: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) # 12-15!12- $+(10,$knick,) 15was kicked from $+(00,#,) 15by $+(00,$nick,) $+(14[15,$1-,14])
}
on ^&*:NICK: {
if ($halted) return
haltdef
if ($nick == $me) {
var %c = $comchan($newnick,0)
while (%c) {
echo -ti $+ $calc($indent + 5) $comchan($newnick,%c) 12-15!12- 15You're is now known as $+(00,$newnick,)
dec %c
}
}
else {
var %c = $comchan($newnick,0)
while (%c) {
echo -ti $+ $calc($indent + 5) $comchan($newnick,%c) 12-15!12- $+(10,$nick,) 15is now known as $+(11,$newnick,)
dec %c
}
}
}
on ^&*:QUIT: {
if ($halted) return
haltdef
var %c = $comchan($nick,0)
while (%c) {
echo -ti $+ $calc($indent + 5) $comchan($nick,%c) 12-15!12- $+(10,$nick,) $+(14[15,$address,14]) 15has quit $+(14[15,$1-,14])
dec %c
}
if ($query($nick)) {
echo -ti $+ $calc($indent + 5) $nick 12-15!12- $+(10,$nick,) $+(14[15,$address,14]) 15has quit $+(14[15,$1-,14])
}
if ($chat($nick)) {
echo -ti $+ $calc($indent + 5) =$nick 12-15!12- $+(10,$nick,) $+(14[15,$address,14]) 15has quit $+(14[15,$1-,14])
}
}
on ^&*:TOPIC:#: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) # 12-15!12- $+(00,$nick,) 15changed topic of $+(00,#,) 15to: $+(15,$1-,)
}
on ^&*:RAWMODE:#: {
if ($halted) return
haltdef
if (. isin $nick) {
echo -ti $+ $calc($indent + 5) # 12-15!12- $+(04ServerMode15/10,#,) $+(14[15,$1-,14]) 15by $+(00,$nick,)
}
else {
echo -ti $+ $calc($indent + 5) # 12-15!12- $+(15mode/10,#,) $+(14[15,$1-,14]) 15by $+(00,$nick,)
}
}
on ^&*:SNOTICE:*: {
if ($halted) return
haltdef
echo -mti $+ $calc($indent + 5) 12-15!12- $+(03!,$nick,) $+(15,$1-,)
}
on ^&*:INVITE:#: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$nick,) 15invites you to $+(00,#,)
}
on ^&*:USERMODE: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Mode change $+(14[15,$1-,14]) 15for user $+(00,$nick,)
}
on ^&*:NOTIFY: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$nick,) 15is now online
}
on ^&*:UNOTIFY: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$nick,) 15is now offline
}
on &*:CTCPREPLY:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 15CTCP $+(00,$1,) 15reply from $+(00,$nick,) $+ 15: $+(15,$2-,)
}
CTCP &*:*:*: {
if ($1 == DCC) return
if ($halted) return
haltdef
if (# ischan) {
echo -ti $+ $calc($indent + 5) $+(09,$nick,) $+(14[03,$address,14]) 03requested CTCP $+(09,$1,) 03from $+(09,#,) $+ 15: $+(15,$2-,)
}
else {
echo -ti $+ $calc($indent + 5) $+(09,$nick,) $+(14[03,$address,14]) 03requested CTCP $+(09,$1,) 03from $+(09,$me,) $+ 15: $+(15,$2-,)
}
}
RAW 311:*: {
if ($halted) return
haltdef
if (%whois. [ $+ [ $cid ] ]) {
echo -ti $+ $calc($indent + 5) 12-15!12- 15End of WHOIS
dec %whois. [ $+ [ $cid ] ]
if (%whois. [ $+ [ $cid ] ] = 0) unset %whois. [ $+ [ $cid ] ]
}
inc %whois. [ $+ [ $cid ] ]
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$2,) $+(14[15,$3,@,$4,14])
echo -ti $+ $calc($indent + 17) 12-15!12- 15ircname 15: $+(15,$6-,)
}
RAW 319:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 17) 12-15!12- 15channels 15: $+(15,$sorttok($3-,32,c),)
}
RAW 312:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 17) 12-15!12- 15server 15: $+(15,$3,) $+(14[15,$4-,14])
}
RAW 330:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 17) 12-15!12- 15auth 15: $+(15,$3,)
}
RAW 338:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 17) 12-15!12- 15realip 15: $+(15,$4-,) $+(14[15,$3,14])
}
RAW 313:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 17) 12-15!12- 15: $+(00,$5-,)
}
RAW 317:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 17) 12-15!12- 15idle 15: $+(15,$duration($3),) 14[15signon: $+(15,$asctime($4),) $+ 14]
}
RAW 318:*: {
if ($halted) return
haltdef
if (%whois. [ $+ [ $cid ] ]) {
echo -ti $+ $calc($indent + 5) 12-15!12- 15End of WHOIS
dec %whois. [ $+ [ $cid ] ]
if (%whois. [ $+ [ $cid ] ] = 0) unset %whois. [ $+ [ $cid ] ]
}
}
RAW 301:*: {
if ($halted) return
haltdef
if (%whowas. [ $+ [ $cid ] ]) {
echo -ti $+ $calc($indent + 17) 12-15!12- 15away 15: $+(15,$3-,)
}
else {
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$2,) 15is away: $+(15,$3-,)
}
}
RAW 314:*: {
if ($halted) return
haltdef
inc %whowas. [ $+ [ $cid ] ]
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$2,) $+(14[15,$3,@,$4,14])
echo -ti $+ $calc($indent + 17) 12-15!12- 15was 15: $+(15,$6-,)
}
RAW 369:*: {
if ($halted) return
haltdef
if (%whowas. [ $+ [ $cid ] ]) {
echo -ti $+ $calc($indent + 5) 12-15!12- 15End of WHOWAS
dec %whowas. [ $+ [ $cid ] ]
if (%whowas. [ $+ [ $cid ] ] = 0) unset %whowas. [ $+ [ $cid ] ]
}
}
RAW 352:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ial) {
return
}
else {
echo -ti $+ $calc($indent + 5) 12-15!12- $+(10,$str($chr(160),$calc(10 - $len($2))),$mid($2,1,10),) $+(00,$6,$str($chr(160),$calc(9 - $len($6))),) $+(15,$7,$str($chr(160),$calc(3 - $len($7))),) $+(15,$8,$str($chr(160),$calc(2 - $len($8))),) $+(15,$3,@,$4,) $+(14[00,$9-,14])
}
}
RAW 315:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ial) {
var %sync = 0, %ial = $false, %ibl = $false, %iel = $false, %iil = $false
if ($chan($2).ial) var %ial = $true, %sync = %sync + 1
if ($chan($2).ibl) var %ibl = $true, %sync = %sync + 1
;if ($chan($2).iel) var %iel = $true, %sync = %sync + 1
;if ($chan($2).iil) var %iil = $true, %sync = %sync + 1
if (%sync == 2) {
var %ms = $ticks - %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ticks
echo -nti $+ $calc($indent + 5) $2 12-15!12- 00Irssi: 15Join to $+(00,$2,) 15was synced in $+(00,$int($calc(%ms / 1000)),) 15secs
dec %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ]
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ] = 0) unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ]
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ticks
}
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ial
}
else {
echo -ti $+ $calc($indent + 5) 12-15!12- 15End of /WHO list
}
}
RAW 367:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ibl) {
return
}
else {
var %#, %ibl = 0
if ($2 ischan) var %# = $v1
if ($ibl($2,0)) var %ibl = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- $+(15,%ibl,) 15- $+(00,$2,) $+ 15: 15ban $+(10,$3,)
}
}
RAW 368:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ibl) {
var %sync = 0, %ial = $false, %ibl = $false, %iel = $false, %iil = $false
if ($chan($2).ial) var %ial = $true, %sync = %sync + 1
if ($chan($2).ibl) var %ibl = $true, %sync = %sync + 1
;if ($chan($2).iel) var %iel = $true, %sync = %sync + 1
;if ($chan($2).iil) var %iil = $true, %sync = %sync + 1
if (%sync == 2) {
var %ms = $ticks - %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ticks
echo -nti $+ $calc($indent + 5) $2 12-15!12- 00Irssi: 15Join to $+(00,$2,) 15was synced in $+(00,$int($calc(%ms / 1000)),) 15secs
dec %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ]
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ] = 0) unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ]
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ticks
}
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ibl
}
else {
var %#
if ($2 ischan) var %# = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- 15End of Channel Ban list
}
}
RAW 348:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .iel) {
return
}
else {
var %#, %iel = 0
if ($2 ischan) var %# = $v1
if ($iel($2,0)) var %iel = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- $+(15,%iel,) 15- $+(00,$2,) $+ 15: 15ban exception $+(10,$3,)
}
}
RAW 349:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .iel) {
var %sync = 0, %ial = $false, %ibl = $false, %iel = $false, %iil = $false
if ($chan($2).ial) var %ial = $true, %sync = %sync + 1
if ($chan($2).ibl) var %ibl = $true, %sync = %sync + 1
;if ($chan($2).iel) var %iel = $true, %sync = %sync + 1
;if ($chan($2).iil) var %iil = $true, %sync = %sync + 1
if (%sync == 2) {
var %ms = $ticks - %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ticks
echo -nti $+ $calc($indent + 5) $2 12-15!12- 00Irssi: 15Join to $+(00,$2,) 15was synced in $+(00,$int($calc(%ms / 1000)),) 15secs
dec %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ]
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ] = 0) unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ]
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ticks
}
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .iel
}
else {
var %#
if ($2 ischan) var %# = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- 15End of Channel Exception list
}
}
RAW 346:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .iil) {
return
}
else {
var %#, %iil = 0
if ($2 ischan) var %# = $v1
if ($iil($2,0)) var %iil = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- $+(15,%iil,) 15- $+(00,$2,) $+ 15: 15invite $+(10,$3,)
}
}
RAW 347:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .iil) {
var %sync = 0, %ial = $false, %ibl = $false, %iel = $false, %iil = $false
if ($chan($2).ial) var %ial = $true, %sync = %sync + 1
if ($chan($2).ibl) var %ibl = $true, %sync = %sync + 1
;if ($chan($2).iel) var %iel = $true, %sync = %sync + 1
;if ($chan($2).iil) var %iil = $true, %sync = %sync + 1
if (%sync == 2) {
var %ms = $ticks - %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ticks
echo -nti $+ $calc($indent + 5) $2 12-15!12- 00Irssi: 15Join to $+(00,$2,) 15was synced in $+(00,$int($calc(%ms / 1000)),) 15secs
dec %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ]
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ] = 0) unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] ]
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .ticks
}
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .iil
}
else {
var %#
if ($2 ischan) var %# = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- 15End of Channel Invite list
}
}
RAW 324:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .mode) {
unset %sync. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ ] .mode
}
else {
var %#
if ($2 ischan) var %# = $v1
echo -nti $+ $calc($indent + 5) %# 12-15!12- $+(15mode/10,$2,) $+(14[15,$3-,14])
}
}
RAW 329:*: {
if ($halted) return
haltdef
var %#
if ($2 ischan) var %# = $v1
echo -nti $+ $calc($indent + 5) %# 12-15!12- 15Channel $+(10,$2,) 15created $asctime($3) $+
}
RAW 353:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $3 ] ]) {
return
}
elseif ($3 ischan) {
return
}
else {
echo -nti $+ $calc($indent + 5) 12-15!12- 15Names on $+(00,$3,) $+ 15: $+(15,$4-,)
}
}
RAW 355:*: {
if ($halted) return
haltdef
if (%sync. [ $+ [ $cid ] $+ . $+ [ $3 ] ]) {
return
}
elseif ($3 ischan) {
return
}
else {
echo -nti $+ $calc($indent + 5) 12-15!12- 15Names on $+(00,$3,) $+ 15: $+(15,$4-,)
}
}
RAW 366:*: {
if ($halted) return
haltdef
if ($2 ischan) {
echo -ti $+ $calc($indent + 5) $2 12-15!12- 14[03Users $+(09,$2,) $+ 14]
var %i = $nick($2,0), %long = 0, %0 = $nick($2,0)
while (%i) {
var %nickname = $nick($2,%i), %i = %i - 1
if ($len(%nickname) > %long) var %long = $v1
}
var %i = 1, %c = 1, %column = $floor($calc(($window($2).dw / $width(*,$window($2).font,$window($2).fontsize,$window($2).fontbold) - $indent - 4) / (%long + 4))), %row = $ceil($calc(%0 / %column))
while (%c <= %column) {
var %r = 1, %c = %c + 1
while (%r <= %row) {
var %n = %r, %r = %r + 1
if (%i <= %0) {
var %prefix = $chr(32), %nick = $nick($2,%i), %i = %i + 1
if (%nick isowner $2) var %prefix = ~
elseif (%nick isop $2) var %prefix = @
elseif (%nick ishelp $2) var %prefix = %
elseif (%nick isvoice $2) var %prefix = +
set %names. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ . $+ [ %n ] ] %names. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ . $+ [ %n ] ] $+(14[00,%prefix,15,%nick,,$str( ,$calc(%long - $len(%nick))),14])
}
}
}
var %n = 1
while (%n <= %row) {
echo -t $2 %names. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ . $+ [ %n ] ]
unset %names. [ $+ [ $cid ] $+ . $+ [ $2 ] $+ . $+ [ %n ] ]
inc %n
}
echo -ti $+ $calc($indent + 5) $2 12-15!12- 00Irssi: $+(00,$2,) $+ 15: 15Total of $+(00,%0,) 15nicks 14[ $+ $+(00,$nick($2,0,o),) 15ops, $+(00,$nick($2,0,h),) 15halfops, $+(00,$nick($2,0,v),) 15voices, $+(00,$nick($2,0,r),) 15normal14]
}
else {
echo -nti $+ $calc($indent + 5) 12-15!12- 15End of /NAMES list
}
}
RAW 331:*: {
if ($halted) return
haltdef
var %#
if ($2 ischan) var %# = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- $+(00,$2,) $+ 15: 15No topic set
}
RAW 332:*: {
if ($halted) return
haltdef
var %#
if ($2 ischan) var %# = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- 15Topic for $+(10,$2,) $+ 15: $+(15,$3-,)
}
RAW 333:*: {
if ($halted) return
haltdef
var %#
if ($2 ischan) var %# = $v1
echo -ti $+ $calc($indent + 5) %# 12-15!12- 15Topic set by $+(00,$3,) $+(14[15,$asctime($4),14])
}
RAW 404:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Unable to message $+(00,$2,)
}
RAW 482:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$2,) 15You're not channel operator
}
RAW 396:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$2,) 15is now your hidden host
}
RAW 451:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Register first!
}
RAW 441:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 14[05invite14(04 $+ $2 $+ 14)14] $+(15,$3,)
}
RAW 443:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$2,) 15is already on $+(00,$3,)
}
RAW 421:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(15,$2,) 15Unknown command
}
RAW 433:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Nick $+(00,$2,) 15is already in use
}
RAW 471:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Cannot join to channel $+(00,$2,) 15(Channel is full)
}
RAW 473:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Cannot join to channel $+(00,$2,) 15(You must be invited)
}
RAW 474:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Cannot join to channel $+(00,$2,) 15(You are banned)
}
RAW 475:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Cannot join to channel $+(00,$2,) 15(You need a key)
}
RAW 477:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Cannot join to channel $+(00,$2,) 15(Registered only)
}
RAW 401:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15There is no such nick $+(15,$2,)
}
RAW 406:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15There is no such nick $+(15,$2,)
}
RAW 403:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(00,$2,) $+ 15: 15No such channel
}
RAW 251:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15There are $+(15,$4,) 15users and $+(15,$7,) 15invisible on $+(15,$10,) 15servers
}
RAW 252:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(15,$2,) 15operator(s) online
}
RAW 253:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(15,$2,) 15unknown connection(s)
}
RAW 254:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(15,$2,) 15channels formed
}
RAW 255:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15I have $+(15,$4,) 15clients and $+(15,$7,) 15servers
}
RAW 001:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Welcome to the Internet Relay Network, $+(15,$($+($,$0),2),)
}
RAW 002:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15Your host is $+(15,$left($5,-1),) $+ 15, running version $+(15,$8,)
}
RAW 003:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- 15This server was created $+(15,$6-,)
}
RAW 004:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(15,$2,) $+(15,$3,) $+(15,$4,) $+(15,$5,)
}
RAW 005:*: {
if ($halted) return
haltdef
echo -ti $+ $calc($indent + 5) 12-15!12- $+(15,$deltok($2-,-5-,32),) 15are supported by this server
}
RAW *:*: {
if ($numeric == 321) || ($numeric == 322) || ($numeric == 323) return
if ($halted) return
haltdef
if ($0 > 1) {
echo -ti $+ $calc($indent + 5) 12-15!12- $+(15,$2-,)
}
}
hello spoofing,
thank you for update irssi theme, can you show us what is fixed in this version, what is new?
do you remove away feature in this version?
please take a look for that suggestion i've told you of shorten nickname eg: --> [ MyNick....] on my channel a lot of user use very long nickname, and looks very bad when i join the channel.
Please let us know what do you have change in theme and what is new.
Thank you for update, still my fav theme so far.