hi, the scripts don't works :(

FullMetalAlchemist, it won't work for repeated punctuation characters. (If you mean that they enter them as !!!!!!!! or ........ repeatedly) The script aims for CAPS abuse. But with some modification of my code example, it will do what you want:

on @*:text:*:#:$iif($check($1-).caps,$v1,$check($1-).reps)
on @*:action:*:#:$iif($check($1-).caps,$v1,$check($1-).reps)
on @*:notice:*:#:$iif($check($1-).caps,$v1,$check($1-).reps)
alias -l check { 
  var %. ,a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z,%; $len($remove($1- [ %. ] )),%: $len($1-) - %;
  if ($nick !isop #) {
    if ($calc(100*($len($removecs($1- [ %. ] ))-%;)/%:) > 50) && (%: > 5) {
      set -u2 $+(%,c,$chr(32),$int($v1)) | if ($prop = caps) { inc $+(%,$nick)
        if ($($+(%,$nick),2) > 2) {
          ban -ku600 # $nick 2 You've used $+(%c,%) of CAPS, and you were warned twice!
          unset $($+(%,$nick),1)
        }
        elseif ($($+(%,$nick),2) = 2) { .msg # You've used $+(%c,%) of CAPS, and this is your $ord($($+(%,$nick),2)) warning! }
        else { .msg # You've used $+(%c,%) of CAPS, and this is your first warning! }
      }
    }
    elseif ($prop = reps) && ($regex($1-,/(.)(\1{6,})/)) { inc $+(%,$nick,reps)
      if ($($+(%,$nick,reps),2) > 2) {
        ban -ku600 # $nick 2 You've used $len($regml(2)) repeated punctuation characters, and you were warned twice!
        unset $($+(%,$nick,reps),1)
      }
      elseif ($($+(%,$nick,reps),2) = 2) { 
        .msg # You've used $len($regml(2)) repeated punctuation characters, and this is your $ord($($+(%,$nick,reps),2)) warning! 
      }
      else { .msg # You've used $len($regml(2)) repeated punctuation characters, and this is your first warning! }
    }
  }
}

The script will now look for repeated punctuation characters if he or she exceeds 6 or more. You can adjust this bit {6,} to a higher number. The smaller the number, the stricter the script becomes.

hm, for some reason it doesn't work if they use ! or . =\

xBox_gamer1, have you got pranked up before? Like, someone drives up to you and tells you to hop in, then once you proceed to, that person drives away, parks and tells you to come in...then drives away in a repeated manner. :p

Deshan19, here is a non-regex one:

on @*:text:*:#:capscheck $1-
on @*:action:*:#:capscheck $1-
on @*:notice:*:#:capscheck $1-
alias -l capscheck {
  var %. ,a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z,%; $len($remove($1- [ %. ] )),%: $len($1-) - %;
  if ($nick !isop #) && ($calc(100*($len($removecs($1- [ %. ] ))-%;)/%:) > 50) && (%: > 5) { 
    set -e $+(%,c,$chr(32),$int($v1))
    inc $+(%,$nick) 
    if ($($+(%,$nick),2) > 2) {
      ban -ku600 # $nick 2 You've used $+(%c,%) of CAPS, and you were warned twice! 
      unset $($+(%,$nick),1)
    }
    elseif ($($+(%,$nick),2) = 2) { 
      .msg # You've used $+(%c,%) of CAPS, and this is your $ord($($+(%,$nick),2)) warning! 
    }
    else { 
      .msg # You've used $+(%c,%) of CAPS, and this is your first warning! 
    }
  }
}

It has two warnings before a kick/ban for 10 minutes. The percentage and ban time are fully adjustable.

@deshan19 your a justin.tv bot user :-o

hmmmmm it works fine for me

but i made other caps kick's for my bot..... and i am not going to post it on here

sorry if it did not working for you :(
xbox_gamer1

for some reason when i paste it in the remote section it doesnt work. how do i fix this?

also im trying to use it on justin.tv

um how is it a 10 min time out? If all you are doing is kicking them...

could also do

on @*:TEXT:*:#:{
  if ($nick !isop # && %capskick && $len($1-) > 5) {
    var %caps.percent $calc($regex($1-,/[A-Z]/Sg)/$len($1-)*100)
    if (%caps.percent > %caps.allowed) {
      inc %kick
      ban -ku600 # $nick 2 $round(%caps.percent,0) $+ % CAPS! 4[ $+ %kick $+ ]
      .msg $nick You got 10 minute time-out automatically for using Caps Lock!
    }
  }
  if ($regex($1-,/^!!capskick\s(o(n|ff)?|set)?\s?(\d+)?/iS) && $nick isop #) {
    if ($istok(on off,$regml(1),32)) { 
      $+($iif($regml(1) = off,un),set) %capskick on
      msg # Capskick is  $iif(%capskick,on,off) 
    }
    if ($regml(1) = set && $regml(2)) {
      set %caps.allowed $v1
      msg # Caps allowed set to $v1 $+ %
    }
  }
}

Nice but you don't need some of the stuff. It could be written this way:

on @*:TEXT:*:#: {
  if ($nick !isop $chan) && (%capskick == on) && ($len($1-) > 5) {
    set %caps.percent $calc($regex($1-,/[A-Z]/g)/$len($1-)*100)
    if (%caps.percent > %caps.allowed) {
      inc %kick
      kick $chan $nick $round(%caps.percent,0) $+ % CAPS! 4[ $+ %kick $+ ]
      msg $chan $nick $+! , you got 10 minute time-out automatically for using Caps Lock!
    }
  }
  elseif ($nick !isop $chan) && ($1 == !capskick) {
    if ($2 == on) { set %capskick on | msg $chan Capskick is on }
    if ($2 == off) { set %capskick off | msg $chan Capskick is off }
    if ($2 == set) { set %caps.allowed $3 | msg $chan Caps allowed set to %caps.allowed $+ % }
  }
}