This is a simple Magic 8-Ball with menu controls
and $iggy AutoReply AntiFlood protection that uses
the twenty responses from the original Magic 8-Ball.

on *:TEXT:!8ball *:%8ball:if !$iggy($nick) { msg # $nick ==> $M8ball }
alias iggy {
  var %g,%cid $hget(iggy,$cid)
  if $hget(iggy,$1) || (%cid > 3) { %g = 1 }
  if !$v1 { hinc -mu9 iggy $1 }
  if !%cid || (%cid < 4) { hinc -mu9 iggy $cid }
  return %g
}
alias M8ball {
  goto $r(a,t)
  :a | return As I see it, yes
  :b | return It is certain
  :c | return It is decidedly so
  :d | return Most likely
  :e | return Outlook good
  :f | return Reply hazy, try again
  :g | return Ask again later
  :h | return Better not tell you now
  :i | return Cannot predict now
  :j | return Concentrate and ask again
  :k | return Don't count on it
  :l | return My reply is no
  :m | return My sources say no
  :n | return Outlook not so good
  :o | return Very doubtful
  :p | return Signs point to yes
  :q | return Without a doubt
  :r | return Yes
  :s | return Yes - definitely
  :t | return You may rely on it
}
menu channel {
  $iif(!%8ball,Enable Magic 8-Ball Specific Channels):set %8ball $$?="Enter comma separated list of channels"
  $iif(!%8ball,Enable Magic 8-Ball #):set %8ball # | msg # Ask Magic 8-Ball a question: !8ball question?
  $iif(!%8ball,Enable Magic 8-Ball All Channels,Disable Magic 8-Ball):$iif(!%8ball,set %8ball $chr(35),unset %8ball)
  $iif(%8ball,Advertize Magic 8-Ball to #):msg # Ask Magic 8-Ball a question: !8ball question?
}