Top
Home > Code Snippets > knoeki's Snippets > mIRC

Hilightcatcher v1.1


mIRC Code
+ 0 likes
Please Register to submit score.
Bookmark and Share
Average Score  8.0 (of 1 scores)
Date Added  Oct 09, 2009
Last Updated  Oct 09, 2009
Tags  catch  catcher  highlight  hilight  log 

Introduction

Just a simple hilightcatcher I wrote for some people on #zomgwtfbbq ;_) might be useful to more people, I guess.


Usage:

/hilights on - enables hilightcatching, will send a copy of every message containing your nick to a custom window.
/hilights off - disables hilightcatching.

May you accidentally close the window while the hilightcatcher is on, don't worry, it'll pop up again next time you're hilighted, unless you disable it first ;_)

I'd say it's pretty foolproof, but obviously mother nature will now feel challanged to create a better fool ;_)

Grab the Code

alias hilights {
    if ($1 == on) {
        set %k.hilight.catcher 1
        window -nak0 @hilights
        echo -a HilightCatcher enabled.
    }
    else {
        unset %k.hilight.catcher
        window -c @hilights
        echo -a HilightCatcher disabled.
    }
}
 
on *:TEXT:*:#: {
    if (%k.hilight.catcher == 1) {
        if ($window(@hilights) == $null) {
            window -nak0 @hilights
        }
        if ($me isin $1-) {
            window -g2 @hilights
            echo @hilights $+($([),$asctime(HH:nn:ss),$(][),$asctime(dd/mm/yyyy),$(])) :: $network / $chan $+(<,$nick($chan, $nick).pnick,>) $replace($1-, $me, $+(04,$me,))
        }
    }
}
 
on *:ACTION:*:#: {
    if (%k.hilight.catcher == 1) {
        if ($window(@hilights) == $null) {
            window -nak0 @hilights
        }
        if ($me isin $1-) {
            window -g2 @hilights
            echo @hilights $+($chr(91),$asctime(HH:nn:ss),$(][),$asctime(dd/mm/yyyy),$(])) :: $network / $chan * $nick($chan, $nick).pnick $replace($1-, $me, $+(04,$me,))
        }
    }
}
 
on *:START: {
    window -nak0 @hilights
}
 
on *:OPEN:@hilights: {
    echo @hilights Hilightcatcher v1.1 by Knoeki.
    echo @hilights For help, contact me at irc.p2p-network.net / #zomgwtfbbq
}

Comments

  (5)  RSS
DrtyDawg
Comments: 2
 
mIRC Snippet:  Hilightcatcher v1.1
Posted on Oct 9, 2009 4:55 am
Great stuff, simple idea - but very handy
Thx knoeki :)
gooshie
Comments: 66
 
mIRC Snippet:  Hilightcatcher v1.1
Posted on Oct 9, 2009 8:01 pm
Code:
alias hilights {
  if ($1 == on) {
    inc %k.hilight.catcher
    window -nak0 @hilights
    echo -a HilightCatcher enabled.
  }
  else {
    unset %k.hilight.catcher
    window -c @hilights
    echo -a HilightCatcher disabled.
  }
}
on *:TEXT:$($+(*,$me,*)):#:hilight.catcher t $1-
on *:ACTION:$($+(*,$me,*)):#:hilight.catcher a $1-
alias hilight.catcher {
  if %k.hilight.catcher {
    if !$window(@hilights) { window -nak0 @hilights }
    window -g2 @hilights
    echo @hilights $+($([),$time,][,$adate,]) :: $network / # $+($iif($1 = a,* $+ $chr(32),<),$nick(#,$nick).pnick,$iif($1 != a,>)) $replace($2-,$me,$+(04,$me,))
  }
}
on *:START:window -nak0 @hilights
knoeki
Comments: 120
 
mIRC Snippet:  Hilightcatcher v1.1
Posted on Oct 10, 2009 5:48 am
gooshie: yeah, that works, but in my eyes it looks horrible. The nice thing about coding though, is that everyone can have his/her own style. :_)
gooshie
Comments: 66
 
mIRC Snippet:  Hilightcatcher v1.1
Posted on Oct 10, 2009 8:03 am
Forgot to mention:
/help on open
==> The OPEN event does not trigger for custom windows.
knoeki
Comments: 120
 
mIRC Snippet:  Hilightcatcher v1.1
Posted on Oct 10, 2009 8:06 am
hrm.. strange how I overlooked that, because I could swear it works :x oh well

Commenting Options

Register or Login to Hawkee.com or use your Facebook or Twitter account by clicking the corresponding button below.

  
Bottom