Top

Basic Ops


mIRC Code
+ 0 likes
Please Register to submit score.
Bookmark and Share
Average Score  8.0 (of 1 scores)
Date Added  Sep 20, 2009
Last Updated  Oct 01, 2009
Tags  massmode  ops 

Description

Basic Ops including mass bans, mass modes, mass kick, voice/devoice all,
channel central, ban list clear, and channel lock/unlock. Commands are
hidden when not supported by lack of proper mode.

Voice All only voices modeless nicks
DeVoice All only devoices nicks who only have +voice

Grab the Code

menu NickList {
  -
  $iif($1 && $nick(#,$me,~&@%),Channel Operator Commands)
  .Mass Ban:massmode +b $1-
  .Mass unBan:massmode -b $1-
  .Mass Kick:masskick $1-
  .-
  .Mass Voice:massmode +v $1-
  .Mass DeVoice:massmode -v $1-
  .$iif($nick(#,$me,~&@),Mass Half-Op):massmode +h $1-
  .$iif($nick(#,$me,~&@),Mass DeHalf-Op):massmode -h $1-
  .$iif($nick(#,$me,~&@),Mass Op):massmode +o $1-
  .$iif($nick(#,$me,~&@),Mass Deop):massmode -o $1-
  .-
  .Kick $1 (why):kick # $1 $$?="Kick Reason"
  .Ban/Kick $1 5min:ban -ku300 $1 2
  $iif($nick(#,$me,~&@%),+Voice All (except ops)):voiceall
  $iif($nick(#,$me,~&@%),-Voice All (except ops)):devoiceall
  $iif($nick(#,$me,~&@%),Channel Central):.channel
  $iif($nick(#,$me,~&@%),Clear Ban List):clearbans
  $iif($nick(#,$me,~&@%),(+mi) Lock/Moderate):mode # +mi
  $iif($nick(#,$me,~&@%),(-mi) UnLock):mode # -mi
  -
}
 
alias clearbans {
  var %i 1,%n
  while $ibl(#,%i) {
    %n = %n $v1
    if (%i = $ibl(#,0)) || ($numtok(%n,32) = $modespl) {
      mode # $+(-,$str(b,$numtok(%n,32))) %n
      %n = ""
    }
    inc %i
  }
}
alias devoiceall voiceall d
alias voiceall {
  var %i 1,%n,%s $iif($1 = d,-,+),%m $iif($1 = d,v,r)
  while $nick(#,%i,%m,~&@%) {
    %n = %n $v1
    if (%i = $nick(#,0,%m,~&@%)) || ($numtok(%n,32) = $modespl) {
      mode # $+(%s,$str(v,$numtok(%n,32))) %n
      %n = ""
    }
    inc %i
  }
}
alias masskick {
  var %i 1
  while $gettok($1-,%i,32) {
    kick # $v1
    inc %i
  }
}
alias MassMode {
  var %i 1,%g,%n $2-,%s $left($1,1),%m $mid($1,2,1)
  if %m = b {
    %n = ""
    while $gettok($2-,%i,32) {
      %n = %n $address($v1,2)
      inc %i
    }
  }
  while %n {
    %g = $gettok(%n,1- $+ $modespl,32)
    mode # $+(%s,$str(%m,$numtok(%g,32))) %g
    %n = $gettok(%n,$calc($modespl +1) $+ -,32)
  }
}
 

Comments

  (4)  RSS
Jethro_
Comments: 945
 
mIRC Snippet:  Basic Ops
Posted on Sep 20, 2009 9:39 pm
I see this is only supported for @ and %, but can be modified for higher $nickmode

Nice script, gooshie.
FordLawnmower
Comments: 620
 
mIRC Snippet:  Basic Ops
Posted on Sep 20, 2009 9:55 pm
Looks good gooshie but what is --->> exk mode?
It's called in the voiceall alias.
Jethro_
Comments: 945
 
mIRC Snippet:  Basic Ops
Posted on Sep 20, 2009 10:01 pm
I think that's a typo. It's needless. By removing it, it works well. But with it, you get an error. Nice keen eyesight to spot it.
gooshie
Comments: 181
 
mIRC Snippet:  Basic Ops
Posted on Sep 21, 2009 6:14 am
Sorry exk is my echo color test thing like my mIRC E.R.K Scripting Tool.
Forgot to remove it.
Note to self: Search exk b4 posting.

Is it possible to have mode ~ or & without being an op?
I just found out it is possible to have only ~ or & mode.
I had that question b4 I posted and didnt check.

Good looking out Jethro_ and FordLawnmower!
I make the changes.

Commenting Options

Register or Login to Hawkee.com or use your Facebook or Twitter account by clicking the corresponding button below.

  

Bottom