;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;Script Manager---------------------;;
;;Coded By HeatedHeart---------------;;
;;For Use With XeroChat3-------------;;
;;All Rights Reserved:XeroChat Team--;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;#### Start Up
on *:DIALOG:SM:init:*: {
  ShowScript
}
;#### Aliase's
Alias ShowScript {
  var %Loop2 1
  var %z 1,8,9,10,11,12
  while (%Loop2 <= 6) {
    did -r $dname $gettok(%z,%Loop2,44)
    inc %loop2
  }
  Var %x $Script(0)
  Var %Loop 1
  while (%Loop <= %X) {
    did -a $dname 1 $NoPath($script(%Loop))
    inc %loop
  }
}
;#### Pop Ups
menu * {
  Script Manager:/dialog -vmd SM SM
}
;#### Dialog
dialog SM {
  title "XeroChat3 Script Manager"
  size -1 -1 417 353
  option pixels notheme
  box "Script Infromation", 2, 230 33 182 126
  list 1, 8 38 216 314
  text "Name:", 3, 236 52 35 17
  text "Size:", 4, 236 74 25 17
  text "Number Of Lines:", 5, 236 95 84 17
  text "Last Modified:", 6, 237 132 74 17
  text "Created:", 7, 237 114 41 17
  text "", 8, 271 53 102 17
  text "", 9, 262 74 100 17
  text "", 10, 322 96 66 17
  text "", 11, 282 114 100 17
  text "", 12, 311 132 82 17
  box "Control", 13, 231 197 83 133
  button "Unload", 14, 239 212 65 25
  button "Delete", 15, 239 299 65 25
  button "View Script", 16, 239 269 65 25
  button "Load Script", 17, 240 241 63 25
  link "www.XeroCreative.Com", 18, 250 330 129 17
  button "Refresh", 19, 9 6 398 25
  button "Exit", 20, 320 203 90 122
}
;#### Dialog Coding
on *:dialog:SM:SCLICK:*: {
  if ($did == 1) {
    var %Name $did(1).seltext
    var %Size $file($Script($Did(1).seltext)).size  
    var %Lines $lines($script($did(1).Seltext))
    var %LastMod $file($Script($Did(1).seltext)).mtime 
    var %created $file($Script($Did(1).seltext)).ctime
    did -a $dname 8 %Name
    did -a $dname 9 $bytes(%size,k) KB
    did -a $dname 10 %lines
    did -a $dname 11 $Gettok($asctime(%Created),1-3,32)
    did -a $dname 12 $Gettok($asctime(%lastMod),1-3,32)
  }
  if ($did == 14) {
    .unload -rs $did(1).seltext
    showscript
  }
  if ($did == 15) {
    var %x $?!="You Sure You Want To Unload This File and Delete It?"
    if (%x == $True) { 
      remove $qt($script($did(1).seltext)) 
      unload -rs $did(1).seltext
      dialog -v SM SM
      ShowScript
    }
    else { 
      halt
    }
  }
  if ($did == 16) {
    .run notepad.exe $qt($Script($did(1).seltext))
  }
  if ($did == 17) {
    var %x $qt($sfile(dir))
    .load -rs %x
    dialog -v SM SM
    showscript
  }
  if ($did == 19) {
    ShowScript
  }
  if ($did == 20) {
    dialog -x SM SM
  }
}
;#### End Script Manager
 

Commenting Options