menu * {
  iPod Firmware $chr(9) /iPodFW:ipodfw
}
alias ipodfw { dialog $iif($dialog(ipodfw),-v,-m)) ipodfw ipodfw }
alias ipodfw.getlist { if ($sock(ipodfw)) { sockclose ipodfw } | sockopen ipodfw www.felixbruns.de 80 | did -b ipodfw 3-5 | did -ra ipodfw 6 Downloading iPod firmware list .. | did -r ipodfw 3 | unset %ipodfw.* }
on *:sockopen:ipodfw: {
  sockwrite -nt $sockname GET /iPod/firmware/ HTTP/1.1
  sockwrite -nt $sockname Host: www.felixbruns.de
  sockwrite -nt $sockname $crlf
}
on *:sockread:ipodfw: {
  var %x | sockread %x
  if ($regex(%x,/<option value="(.*)"\s.*>(.*)</option>/Si)) { if ($dialog(ipodfw)) { set $+(%,ipodfw.,$replace($regml(2),$chr(32),_)) $gettok($regml(1),1,34) | did -a ipodfw 3 $regml(2) } }
  elseif (*Copyright* iswm %x) { did -e ipodfw 3-5 | did -r ipodfw 6 | sockclose $sockname }
}
on *:dialog:ipodfw:init:*: { ipodfw.getlist }
on *:dialog:ipodfw:close:*: { unset %ipodfw.* | sockclose ipodfw }
on *:dialog:ipodfw:sclick:*: {
  if ($did == 4) { ipodfw.getlist }
  elseif ($did == 5) {
    if ($did(3)) { 
      if (!$lock(run)) { run %ipodfw. [ $+ [ $replace($did(3),$chr(32),_) ] ] }
      else { noop $input(There is a lock enabled on the "run" command. Here is the link to your download;,ie,Firmware - Link,%ipodfw. [ $+ [ $replace($did(3),$chr(32),_) ] ]) }
    }
    else { noop $input(No firmware selection was made. Please try again,wo,Firmware - Error) }
  }
}
dialog ipodfw {
  size -1 -1 400 140
  title "iPod/iPhone Firmware Files"
  option pixels
  text "How to restore or update your iPod/iPhone:", 1, 5 5 390 15
  text "After downloading the desired firmware below, you can shift-click (PC) or option-click (Mac) the Restore or Update  buttons in iTunes. A file dialog will open and let you choose the downloaded ipsw-file.", 2, 5 25 390 50
  combo 3, 5 85 390 15, drop
  button "Refresh", 4, 190 110 100 23
  button "Download", 5, 295 110 100 23
  text "", 6, 5 115 180 23
}

Commenting Options