Advanced Away Script with PM Accept/Decline

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	5.0
Scores Submitted	1
Date Added	Aug 04, 2008
Last Updated	Aug 05, 2008
Tags	accept away custom decline message mirc msg msl pm query script

Introduction

Ok, this has two features: An away script with on-load setup (to access it again type /setup) and also a query accept/decline feature, which shows the nick and the message.

/yoursettings for your current settings
/setcolour 1 2 to set your colours for the script
/onetime to turn a one-time message on/off
/mlog to turn your !log MESSAGE feature on/off
/nlog is for my own personal use (notices are logged with my BNC) so feel free to remove it
/inick to change your idle nickname
/gone NEWNICK REASON to go away
/back to return
Query accept/decline will open when you receive a query
Change:

(Jc|iCon|iConstruct|Jcfc|Jamie)

To your highlights (E.g., (Bob|Rob|Bobbie|Robbie|Builder|Cookies) - add more |'s to add more highlights)

^Picture of the query accept/decline

^Picture of the away script setup

Enjoy :)

Grab the Code

/*
###########Advanced Away Script with PM Accept/Decline###########
##################Scripted by iConstruct (Jcfc)##################
################Please post suggestions on Hawkee################
*/

;Aliases

alias col {
  if ($1 = 0) return white
  if ($1 = 1) return black
  if ($1 = 2) return blue
  if ($1 = 3) return green
  if ($1 = 4) return red
  if ($1 = 5) return brown
  if ($1 = 6) return purple
  if ($1 = 7) return orange
  if ($1 = 8) return yellow
  if ($1 = 9) return green
  if ($1 = 10) return turquoise
  if ($1 = 11) return cyan
  if ($1 = 12) return blue
  if ($1 = 13) return pink
  if ($1 = 14) return grey
  if ($1 = 15) return light grey
}

alias yoursettings { echo -at Notice log: %nlog
  echo -at Message log: %mlog
  echo -at One-time message: %onetime
  echo -at Colour 1: $c1($col($replace($c1,$chr(3),$null)))
  echo -at Colour 2: $c1($col($replace($c2,$chr(3),$null)))
  echo -at Idle away nick: %inick
  echo -at Idle away time: %itime minutes
}

alias setup { dialog -md setup setup }

alias bnc { set %nlog on | set %mlog off | echo -ate BNC Mode set. }
alias pcon { set %nlog off | set %mlog on | echo -ate AFK with PC on mode active. }

alias c1 { return %t1 $+ $1- $+ $chr(3) }
alias c2 { return %t2 $+ $1- $+ $chr(3) }

alias setcolour {
  set %t1 $+($chr(3),$iif($1 < 10,0),$1)
  set %t2 $+($chr(3),$iif($2 < 10,0),$2)
  echo -ate You have set your colours as $c1($col($1)) and $c2($col($2))
}

alias onetime { 
  if ($1 == on) { set %onetime on | echo -ate Onetime on. }
  elseif ($1 == off) { set %onetime off | echo -ate Onetime off. }
  else { echo -ate Unknown command. } 
}

alias mlog { 
  if ($1 == on) { set %mlog on | echo -ate Message log on. }
  elseif ($1 == off) { set %mlog off | echo -ate Message log off. }
  else { echo -ate Unknown command. } 
}

alias inick {
  set %inick $1
  echo -ate Idle nickname changed.
}

alias out { gone $1- }

alias gone { set %away 1
  set %fnick $me
  set %snick $1
  nick %snick
  set %asctime $asctime
  $iif($2,set %reason $2-,set %reason unknown)
  set %ctime $ctime
  set %away 1
  amsg [• $c1(I) $c2(am) $c1(now) $c2(away.) $c1(Reason:) $c2(%reason) •] [• $c1(Left) $c2(at) $c1(%asctime) •] [• $c1(/notice) $c2(log) $c1(is) $iif(%nlog == on,9on,4off) $chr(124) $c2(!log) $c1(message) $c2(is) $iif(%mlog == on,9on,4off) •]
}

alias back { nick %fnick
  amsg [• $c1(I) $c2(am) $c1(now) $c2(back) $c1(from:) $c2(%reason) •] [• $c1(Gone) $c2(for) $c1($duration($calc($ctime - %ctime))) •]
  echo -ate Your messages: $replace(%log,^,$lf)
  unset %reason %ctime %snick %fnick %away %told %log %loghosts %away
}

alias openquery { /dialog -md query query
  /did -ra query 3 $nick has sent you the following message:
  /did -ra query 4 $1- 
  set %anick $nick 
  msg %anick Please wait for $me to accept your query.
}

;Dialogs

dialog query {
  title "Query request"
  size -1 -1 146 53
  option dbu
  button "Accept query", 1, 1 25 144 12
  button "Decline query", 2, 1 39 144 12
  edit "", 3, 1 1 144 10, read
  edit "", 4, 1 12 144 10, read
}

dialog setup {
  title "Away script setup"
  size -1 -1 103 65
  option dbu
  check "Turn your message log on?", 1, 3 1 79 10
  check "Make your away PM reply only once?", 3, 3 9 100 10
  edit "Idle Nickname", 2, 3 19 97 10
  edit "", 4, 38 30 13 10, limit 2
  edit "", 5, 86 30 13 10, limit 2
  text "Colour 1", 6, 4 31 29 8, center
  text "Colour 2", 7, 55 31 29 8, center
  button "OK", 8, 1 55 101 9
  edit "", 9, 3 42 35 10
  text "Time until auto-away (minutes)", 10, 38 41 64 13, center
}

;On events

on *:LOAD:*:{ if (%setup != 1) { dialog -md setup setup } }

on $*:TEXT:/(Jc|iCon|iConstruct|Jcfc|Jamie)/Si:#:{ if (%away == 1) && ($nick !isin %told) { notice $nick [• $c1(Sorry,) $c2(I) $c1(am) $c2(away.) $c1(!log) $c2(MESSAGE) $c1(to) $c2(leave) $c1(a) $c2(message.) $c1(Reason:) $c2(%reason) •] [• $c1(Left) $c2(at) $c1(%asctime) •]
    if (%onetime == on) { set %told %told $nick }
} }

on $*:TEXT:/^[.!@^]log/Si:#:{ if ($address($nick,2) !isin %loghosts) && (%away = 1) && (%mlog == on) { set %log %log ^ < $+ $time $+ > < $+ $nick $+ > $2- | notice $nick Message recieved. | set %loghosts %loghosts $address($nick,2) }
  elseif ($address($nick,2) isin %loghosts) && (%away = 1) && (%mlog == on) { notice $nick You have already sent a message. }
  elseif ($address($nick,2) !isin %loghosts) && (%away != 1) && (%mlog == on) { notice $nick This person is not away. }
  elseif ($address($nick,2) !isin %loghosts) && (%away != 1) && (%mlog != on) { notice $nick This person does not accept messages. }
else { notice $nick There was an error processing your message. This could be because they are not away, you have already sent a message, or this person is not away. } }

on *:OPEN:?:*:{ if (%away == 1) { notice $nick Sorry, but $me is away ( $+ %reason $+ ). He left at %asctime $+ . }
else { openquery $1- } }

on *:DIALOG:query:sclick:*:{
  if ($did == 1) { msg %anick $me has 9accepted your query. | dialog -x query | window -a %anick | unset %anick }
  if ($did == 2) { msg %anick $me has 4declined your query. | dialog -x query | close -m %anick | unset %anick  }
}

on *:DIALOG:setup:sclick:8:{
  set %mlog $iif($did(setup,1).state == 1, on, off)
  set %nlog off
  set %onetime $iif($did(setup,3).state == 1, on, off) 
  set %inick $did(setup,2).text
  set %itime $did(setup,9).text
  set %t1 $+($chr(3),$iif($did(setup,4) < 10,0),$did(setup,4))
  set %t2 $+($chr(3),$iif($did(setup,5) < 10,0),$did(setup,5))
  set %setup 1
  dialog -x setup 
}

on *:TEXT:*:*: {
  if (%away != 1) {
    if ($idle > $calc(%itime * 60)) {
      gone %inick Auto away after %itime minutes idle
    }
  }
}

Comments

(4) RSS

Go to Bottom

Typo

Comments: 230

mIRC Snippet: Advanced Away Script with PM Accept/Decline
Posted on Aug 5, 2008 7:35 am

Quote:

To start, put it in your remotes, save, unload, then reload.

HUH???
Why in the world would you have to do that? You don't even have an On Unload event and the on load will be processed when the user hits ok to close the script editor window after adding the code so I just don't get why the heck you would reccomend that process?

Another thing I noticed were that you used the / in a few i nstances and the / is not needed inside of scripts.

The last thing that caught my eye was the fact that the

Code:

on $*:TEXT:/(Jc|iCon|iConstruct|Jcfc|Jamie)/Si:#:{

event is only going to work for you and your names and not anybody else that installs the script.

irchainscriptz

Comments: 46

mIRC Snippet: Advanced Away Script with PM Accept/Decline
Posted on Aug 5, 2008 8:13 am

Iam not sure why you have to load and then Unload also? Typo he did mention on the above paragrah to change it.

Code:

other then that nice. But theres way to many away snippets LOL

Jcfc

Comments: 3

mIRC Snippet: Advanced Away Script with PM Accept/Decline
Posted on Aug 5, 2008 9:01 am

I'll remove that, 'cos you don't have to; you just have to type /setup. It's just that I thought some people would try and do it and say "WTF IT DONT WORK" because they didn't read it - a bit like you and the highlights, typo.

Typo

Comments: 230

mIRC Snippet: Advanced Away Script with PM Accept/Decline
Posted on Aug 5, 2008 10:08 am

I had actually overlooked the part that said to change that manually. Sorry bout that but it does make me wonder why you would make a setup dialog and not make it have the ability to manage the names to be highlighted.

I was also wondering if you had a good reason for not incorporating mircs away features into your script which would have allowed you to use the $away, $awaymsg and $awaytime identifiers.

A suggestion I would make would be to use $cid in the away variable and alter the scrip accordingly to allow your script to support network sepcific away settings. The way it is now your away on everything or nothing.

Another idea would be to use a timer to check your idle time instead of counting on the user to be in an active channel by using the On Text event to trigger it.

Anyhow thats all Ill bother you with for now, I can come up with a ton more ideas if you need.

Great job so far.

Advanced Away Script with PM Accept/Decline

Introduction

Grab the Code

Comments

Jcfc

My Snippet Tags

Contact

Sponsors


Last seen: Aug 28, 2008 Profile Snippets (2) Comments Received (8) Comments Submitted (3)