Acronym Finder

mIRC Code

+ 1 likes

Please Register to submit score.

Average Score	8.6
Scores Submitted	7
Date Added	Jun 17, 2008
Last Updated	Jun 23, 2008
Tags	acro acronym acronyms acros finder mirc search searches socket word words

Introduction

So this is just a little acronym finder. You right click and hit "Acronym Finder" to open up the dialog, and you type in the acronym and click search. For example, you type in "BBL" and hit the search button.

Here's a screen:

Enjoy

Grab the Code

;~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*
;         Acronym Finder          ;
;       Made by MountainDew       ;
; IRC.UnderNet.org ~ #Hawkee.com  ;
;     IRC.SwiftIRC.net ~ #mSL     ;
;~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*

menu * {
  Acronym Finder: acronyms
}

alias noresults noop $input(Sorry $+ $chr(44) no results found.,io,No results)
alias acronyms dialog $iif($dialog(acronyms),-v,-m) acronyms acronyms

dialog acronyms {
  title "Acronym Finder"
  size -1 -1 87 100
  option dbu
  button "OK", 1, 31 89 23 9, ok cancel
  text "Acronym Finder", 2, 23 3 40 8, center
  edit "", 3, 6 20 45 10
  button "Search", 4, 54 20 27 10, disable
  list 5, 6 42 75 42, size hsbar vsbar
  box "Definitions", 6, 3 34 81 53
  box "Acronym", 7, 3 12 81 21
}
on *:dialog:acronyms:*:*:{
  if ($devent == edit && $did == 3) {
    did $iif($did($dname,3) != $chr(32) && $v1,-e,-b) $dname 4
    did -r $dname 5
  }
  if ($devent == sclick && $did == 4) {
    if ($sock(acro)) sockclose acro
    did -b $dname 4
    did -r $dname 5
    sockopen acro silmaril.ie 80
    sockmark acro $gettok($did($dname,3),1,32)
  }
}

on *:sockopen:acro:{
  sockwrite -nt $sockname GET /cgi-bin/uncgi/acronyms/?terms= $+ $sock($sockname).mark HTTP/1.1
  sockwrite -nt $sockname Host: silmaril.ie
  sockwrite -nt $sockname $crlf
}
on *:sockread:acro:{
  var %x
  sockread %x
  if ($regex(%x,/<dd><b><a title=".+">(.+)<\/a><\/b>/i) && $dialog(acronyms)) did -a acronyms 5 $regml(1)
  if (Found: isin %x) {
    if ($dialog(acronyms)) {
      did -e acronyms 4
      did -z acronyms 5
    }
    if (!$mid(%x,11,1)) .timernoresults 1 0 noresults
    sockclose $sockname
  }
}

Comments

(10) RSS

Go to Bottom

Jamiie

Comments: 140

mIRC Snippet: Acronym Finder
Posted on Jun 17, 2008 7:00 pm

Neat work mountaindew, works great. :)

8/10

Cheiron

Comments: 328

mIRC Snippet: Acronym Finder
Posted on Jun 17, 2008 7:14 pm

awesome basically. gets the thumbs up here and a 10 rating. nice one mountaindew and thanks for posting it

vaseline28

Comments: 154

mIRC Snippet: Acronym Finder
Posted on Jun 18, 2008 1:04 am

Works great, and a nice small, easy to use interface!
Edit: 10, I found no bugs and with english not as my first language, anything to help the acronyms is good (very useful)

Noutrious

Comments: 355

mIRC Snippet: Acronym Finder
Posted on Jun 18, 2008 1:58 am

Thanks for the socket part, re-edited it and made it for my bot :)

Comments: 1,382

mIRC Snippet: Acronym Finder
Posted on Jun 18, 2008 2:06 am

ROFL butcherer:P,aint tested it yet MD but looks good.`-.-´

Seven_Dayss

Comments: 9

mIRC Snippet: Acronym Finder
Posted on Jun 18, 2008 2:26 am

whoaa,,

looking good & works great!

lol

vaseline28

Comments: 154

mIRC Snippet: Acronym Finder
Posted on Jun 21, 2008 2:59 am

If you close the dialog when it is processing an acronym, then you get an error message because it is trying to add a line to a closed dialog. You could go:

Quote:

did -a acronyms 5 $iif($dialog(acronyms),$regml(1),)

RagBot

Comments: 34

mIRC Snippet: Acronym Finder
Posted on Jun 22, 2008 11:20 am

Quote:

If you close the dialog when it is processing an acronym, then you get an error message because it is trying to add a line to a closed dialog.

You could always be careful not to do that, and you'd just hae to turn the dialog back on, but that code could help stop future problems.(good work vaseline28 on the code)
Other than that it's a great script that's could be fun and handy 9/10

vaseline28

Comments: 154

mIRC Snippet: Acronym Finder
Posted on Jun 22, 2008 2:21 pm

Yeah, it's not a particularily necessary thing to do, it's just nice to totally clean out any possibility of an error message, however small, unlikely and irrelevant.

mountaindew

Comments: 1,645

mIRC Snippet: Acronym Finder
Posted on Jun 23, 2008 6:19 pm

Added if ($dialog(acronyms)) {

Acronym Finder

Introduction

Grab the Code

Comments

mountaindew

My Snippet Tags

Contact

Friends (49)

Sponsors

		United States
Last seen: Oct 10, 2008 Profile \| Website Likes (75) Friends (49) Snippets (32) Images (22) Products (7) Reviews (12) Comments Received (869) Comments Submitted (1645) Forum Posts (922)