Karaoke Player v2.0

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	0.0
Scores Submitted	0
Date Added	Apr 26, 2008
Last Updated	Apr 27, 2008
Tags	karaoke mp3 music player wma

Introduction

I was bored, and I haven't seen an mp3/wav player that could use lrc files
so I figured I would give it a go. any bugs/errors/suggestions contact me in #msl (irc.swiftirc.net) - I'll be using the nicknames Syrus or Triton.

NEW: Dialog, Visualization (Might add more later).
-- Visualization reacts with the lyrics!

Sample Songs: http://www.hotlinkfiles.com/files/1252693_agtf3/karaoke.zip
LRC Files: http://lrcdb.org/
LRC Google: http://www.google.com/search?hl=en&q=.lrc&btnG=Search

Flash Demo: http://bobdole.co.uk/karaoke-demo/
Visualization Demo: http://bobdole.co.uk/karaoke-demo/vis-demo.gif
Thanks to Foshizzle's work on the awesome visualization.

1) Place a folder named "karaoke" in the main dir of you mIRC.
2) Put songs and .lrc files into the karaoke folder.
3) Name the song and .lrc file the same. ("Born to be wild.wav" = "Born to be wild.lrc")
4) Right click in channel, nicklist, query > Karaoke Player - or type /karcon2
5) Make sure there are 2 or 3 extra lines at the top of the .lrc, filled in with artist/song/Album
([00:00] Artist: Los Lobos / [00:00] Album : Retro Soundtracks / [00:00] Title : La Bamba)

Grab the Code

/*
~ Karaoke Player v2.0, By Syrus ~
Sample Songs: http://www.hotlinkfiles.com/files/1252693_agtf3/karaoke.zip
LRC Files: http://lrcdb.org/
LRC Google: http://www.google.com/search?hl=en&q=.lrc&btnG=Search
Thanks to Foshizzle's work on the awesome visualization.

;------------
Player Dialog
*/
dialog karcon2 {
  title "Karaoke Player v2.0 - By, Syrus"
  size -1 -1 197 198
  option dbu
  text "Song List", 1, 2 1 23 8
  button "Reload", 2, 26 0 27 9
  list 3, 2 9 193 50, size
  text "Artist / Title / Album", 4, 2 59 49 8
  list 5, 2 67 193 26, size
  text "Karaoke Lyrics", 6, 2 93 36 8
  list 7, 2 101 193 68, size
  box "Controls", 8, 2 173 193 22
  button "Visual", 9, 6 181 37 12
  button "Stop", 10, 43 181 37 12
  button "Pause", 11, 80 181 37 12
  button "Resume", 12, 117 181 37 12
  button "Close", 13, 154 181 37 12, ok
}
on *:dialog:karcon2:*:*: {
  if ($devent == init) { var %x did -a $dname 5 $chr(160) | %x | %x | %x
    noop $findfile($+(",$mircdir,karaoke,"),*.wav;*.mp3,N,did -a $dname 3 $nopath($1-))
  }
  if ($devent == dclick && $did == 3) { 
    did -r $dname 5 | did -r $dname 7 | .timerk* off
    $karaoke2($+(",$mircdir,karaoke,\,$did(3).seltext,"))
  }
  if ($devent == sclick) {
    if ($did == 2) { did -r $dname 3 | noop $findfile($+(",$mircdir,karaoke,"),*.wav;*.mp3,N,did -a $dname 3 $nopath($1-)) }
    if ($did == 9) { visual }
    if ($did == 10) { .splay stop | .timerk* off }
    if ($did == 11) { $iif($insong,tpause2,karstp2)  }
    if ($did == 12) { $iif($insong.pause,tresume2,karstp2)  }
  }
  if ($devent == close) { $iif($insong,splay stop) | $iif($inwave,splay stop) | .timerk* off }
}

/*
Player Aliases
*/
alias min2sec2 {
  if ($right($gettok($1,1,58),1) = 0) { return $gettok($1,2,58) }
  else { return $calc($gettok($1,1,58) * 60 + $gettok($1,2,58)) }
}
alias lrcsinfo2 {
  if (!$exists($1-)) { did -a karcon2 7 No .lrc file for this song! }
  else {
    var %1 4, %2 1
    while (%1 != %2) {
      var %x $read($1-,%2)
      did -i karcon2 5 $iif(%2 > 3,halt,%2) $iif($gettok(%x,2,93) = $null,$chr(160),$gettok(%x,2,93))
      inc %2
    }
    $lrctimers2($1-)
  }
}
alias lrctimers2 {
  var %l1 $lines($1-), %l2 0
  while (%l1 > %l2) {
    var %x $read($1-,%l2)
    if (%l2 > 3) $+(.timerk,%l2) 1 $min2sec2($remove($gettok(%x,1,93),[)) did -d karcon2 7 10 $chr(124) did -i karcon2 7 1 $iif($gettok(%x,2,93) = $null,$chr(160),$gettok(%x,2,93)) $chr(124) did -c karcon2 7 1 $chr(124) $!FXC
    inc %l2
  }
}
alias karaoke2 {
  $iif($insong,splay stop) | $iif($inwave,splay stop) | splay $1-
  $lrcsinfo2($replace($1-,.mp3,.lrc,.wav,.lrc))
}
alias karstp2 { 
  if (*.mp3 iswm $insong.fname) { noop $tip(kar,Karaoke Player,Song not paused.) }
  elseif ($inwave) { noop $tip(kar,Karaoke Player,Can not pause/rusume *.wav files. $ctrl Press stop.) }
}
alias karcon2 dialog -m karcon2 karcon2
alias tpause2 {
  if (!$exists($qt($replace($insong.fname,mp3,lrc)))) { splay pause }
  if ($timer(0) isnum 1-150) { splay pause | set %paused $timer(0) | var %x $timer(0), %y | while (%x != %y) { $+(.timer,$timer(%y)) -p | inc %y } }
}
alias tresume2 { 
  if (!$exists($qt($replace($insong.fname,mp3,lrc)))) { splay resume }
  if (%paused isnum 1-150) { splay resume | var %x %paused, %y | while (%x != %y) { $+(.timerk,%y) -r | inc %y } | unset %paused }
}
alias FXC if ($window(@FX)) { .timer -m 20 0 if ($window(@FX)) drawrect -rinf @FX $r(100,16777115) 1 0 0 300 300 }
alias visual {
  window -pkdoCfB +l @FX -1 -1 300 300
  drawfill -r @FX 0 0 0 0
  fektoid 10
}
alias -l fektoid { if ($window(@FX)) { var %ticks $ticks
    drawline -rni @FX $r(1,16777215) 4 10 10 290 290
    if (20 // $1) drawdot -rin @FX $r(0,16777215) 30 $r(40,260) $r(40,260)
    drawrot -fmbn @FX 0 $iif(2 // $1, $1, - $+ $1) 0 0 300 300
    drawcopy -nt @FX 0 0 0 300 150 @FX 0 300 300 -150
    drawcopy -nm @FX 0 0 300 300 @FX 0 0
    drawdot @FX
    titlebar @FX - FPS: $ceil($calc(1000 / ($ticks - %ticks)))
    .timer -m 1 0 fektoid $calc($1 + 1)
} }

/*
Menu
*/
menu channel,nicklist,query {
  Karaoke Player v2.0
  .Open: if (!$dialog(karcon2)) karcon2
  .Visualization:visual
}

Comments

(0) RSS

Go to Bottom

humming_hi

		Oregon, USA
Last seen: Apr 27, 2008 Profile Snippets (4) Images (1) Comments Received (2) Comments Submitted (9)

My Snippet Tags

Contact

Add to Friends

Send Private Message