Idle Kicker

Please Register to submit score.

Average Score	8.3
Scores Submitted	3
Date Added	Mar 28, 2008
Last Updated	Mar 28, 2008
Tags	channel exempt idle kick multi network

Introduction

This is an idle kicker that works across mulitple networks and in multiple channels. Settings are on a channel by channel basis, and are set/reset via channel menu. Settings are stored in a hash table.
Exemptions can be set based on access level (op, half-op, voice and/or regular) as well as by specific nick. NOTE: If the number of characters in the list of exempted nicks exceeds approximately 500, then an error will occur. I have not used binary variables to get around the length limitation, but if the average nick is 20 characters in length, then you still have room for about 25 nicks.

Grab the Code

ctcp *:version:*:  ctcpreply $nick VERSION Idle Kicker 03.28.2008 by Russel Bairstow
on *:start:{
  if !$hget(idle_kick) { .hmake idle_kick 10 }
  if $exists($qt($scriptdiridlekick.hsh)) {    .hload idle_kick $qt($scriptdiridlekick.hsh)  }
  load_idle
}
on *:exit:{
  .timers off
  .hsave -o idle_kick $qt($scriptdiridlekick.hsh)
}
on *:disconnect:{
  $+(.timer,$network,*) off
  .hsave -o idle_kick $qt($scriptdiridlekick.hsh)
}
menu channel {
  Idle Kick
  .$iif(!$hget(idle_kick,$+($network,.,$chan,.,Idle)),Set,Reset) Allowed idle time : hadd -m idle_kick $+($network,.,$chan,.,Idle) $iif($duration($$?="Time in hh:mm:ss format. Note that hh and mm are not required and will default to 0 if not supplied") isnum,$v1,$duration($v1))
  .$iif($hget(idle_kick,$+($network,.,$chan,.,Idle)),Clear Idle Time $duration($hget(idle_kick,$+($network,.,$chan,.,Idle)),3)) : .hdel idle_kick $+($network,.,$chan,.,Idle)
  .$iif(!$hget(idle_kick,$+($network,.,$chan,.,Exempt)),Set,Reset) Exempt : {
    var %exempt = $$?="Enter characters for exemption status (o = op, h = half-op, v = voice, r = regular)"
    var %exempt1 = $remove(%exempt,o,h,v,r)
    .hadd -m idle_kick $+($network,.,$chan,.,Exempt)  $remove(%exempt,%exempt1)
  }
  .$iif($hget(idle_kick,$+($network,.,$chan,.,Exempt)),Clear Exempt $hget(idle_kick,$+($network,.,$chan,.,Exempt))) : .hdel idle_kick $+($network,.,$chan,.,Exempt)
  .Exempt Nick(s) : {
    var %exempt.nicks = $replace($$?="Nick(s) to exempt",$chr(44),$chr(32))
    var %a = 1, %b = $numtok(%exempt.nicks,32)
    while %a <= %b {
      .hadd -m idle_kick $+($network,.,$chan,.,Exempt.Nick) $addtok($hget(idle_kick,$+($network,.,$chan,.,Exempt.Nick)),$gettok(%exempt.nicks,%a,32)
      inc %a
    }
  }
  .Manual Check : check_idle $chan
}
on *:op:#:{
  if $opnick == $me {
    var %exempt = $hget(idle_kick,$+($network,.,$chan,.,Exempt)), %a = 1, %b = $nick($chan,0,a,%exempt)
    while %a <= %b {
      if !$istok($hget(idle_kick,$+($network,.,$chan,.,Exempt.Nick)),$nick($chan,%a,a,%exempt),32) {
        $+(.timer,$network,.,$chan,.,$nick($chan,%a,a,%exempt)) -m 0 500 check_idle $chan $nick($chan,%a,a,%exempt)
      }
      inc %a
    }
  }
  if o isin $hget(idle_kick,$+($network,.,$chan,.,Exempt)) && $timer($+($network,.,$chan,.,$opnick)) {    $+(.timer,$network,.,$chan,.,$opnick) off  }
}
on *:help:#:{
  if h isin $hget(idle_kick,$+($network,.,$chan,.,Exempt)) && $timer($+($network,.,$chan,.,$hnick)) {    $+(.timer,$network,.,$chan,.,$hnick) off  }
}
on *:voice:#:{
  if v isin $hget(idle_kick,$+($network,.,$chan,.,Exempt)) && $timer($+($network,.,$chan,.,$vnick)) {    $+(.timer,$network,.,$chan,.,$vnick) off  }
}
alias -l check_idle {
  if !$2 {
    var %exempt = $hget(idle_kick,$+($network,.,$1,.,Exempt)), %a = 1, %b = $nick($1,0,a,%exempt), %idle = $hget(idle_kick,$+($network,.,$1,.,Idle))
    while %a <= %b {
      .timer 1 %a $iif($nick($1,%a,a,%exempt).idle > %idle && $v2,.kick $1 $nick($1,%a,a,%exempt) No idling allowed)
      inc %a
    }
  }
  elseif $nick($1,$2).idle > %idle && $v2 {        .kick $1 $nick($1,%a,a,%exempt) No idling allowed      }
}
alias -l load_idle {
  var %a = 1, %b = $scon(0)
  while %a <= %b {
    .scon %a
    var %c = 1, %d = $chan(0)
    while %c <= %d {
      var %exempt = $hget(idle_kick,$+($network,.,$chan(%c),.,Exempt)), %e = 1, %f = $nick($chan(%c),0,a,%exempt)
      while %e <= %f {
        $+(.timer,$network,.,$chan(%c),.,$nick($chan,%e,a,%exempt)) -m 0 500 check_idle $chan $nick($chan(%c),%e,a,%exempt)
        inc %e
      }
      inc %c
    }
    inc %a
  }
}
on *:quit:{
  $+(.timer,$network,*,$nick)) off
}
on *:part:#:{
  if $nick == $me {    $+(.timer,$network,.,$chan,*) off  }
  elseif $timer($+($network,.,$chan,.,$nick)) {    $+(.timer,$network,.,$chan,.,$nick) off  }
}
on *:kick:#:{
  if $knick == $me {    $+(.timer,$network,.,$chan,*) off  }
  elseif $timer($+($network,.,$chan,.,$knick)) {    $+(.timer,$network,.,$chan,.,$knick) off  }
}
on @*:join:#:{
  if !$istok($hget(idle_kick,$+($network,.,$chan,.,Exempt.Nick)),$nick,32) {
    $+(.timer,$network,.,$chan,.,$nick) -m 0 500 check_idle $chan $nick
  }
}

Comments

(4) RSS

Go to Bottom

CicatrixZ

Comments: 2

Posted on Mar 29, 2008 11:47 am

Good Job Dude.. This is really What i Like... Im using it now.. TY.. SO Useful.. TY Again.. <3

N00bd00b

Comments: 1

Posted on Apr 27, 2008 3:35 pm

Please forgive me for being a n00b but I can't get this to work.
It doesn't seem to be kicking and when I try to add an exempt nick, I get the message:
* Invalid format: $addtok

Do I need to go through and edit something?

BusyElf

Comments: 1

Posted on May 15, 2008 12:46 am

I'm getting the same problem Noob, Tried a few attempts to cure it but..... ^shrugs^

SnoooP

Comments: 125

Posted on May 15, 2008 4:20 am

i had a little go of this before and it worked of for me

Please Register or Login to start posting comments.

Idle Kicker

Introduction

Grab the Code

Comments

RusselB

My Snippet Tags

Contact

Friends (6)

		Sarnia, ON, Canada
Last seen: May 15, 2008 Profile Friends (6) Snippets (20) Images (2) Comments Received (188) Comments Submitted (113) Forum Posts (4882)