Hawkee Snippet Search
Platform: mIRC
Published Mar 17, 2008
Updated Aug 01, 2010
This snippet searches for other snippets from Hawkee. You can search through all of them, or specify a category.
Syntax: [/snippets|!snippets] <-type> [search criteria]
[] = Required
<> = optional
Types:
* -asp
* -cpp
* -cfm
* -css
* -hi5
* -java
* -js
* -jsp
* -mirc
* -myspace
* -mysql
* -net
* -opensocial
* -perl
* -php
* -python
* -ruby
* -tcl
Examples:
/snippets trivia
!snippets -php print
Screen:
As default, it returns the top 3 matches. If you'd like to change the number of matches it returns, change "if (%N == 3)" to "if (%N == NUMBER)"
Enjoy
Thanks FordLawnmower for editing the script to work properly ;~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~
; Hawkee Snippet Search *
; Made by MountainDew ~
; Revisions made by FordLawnmover ~
; IRC.DeltaAnime.Net » #Lindrian #mIRC-Scripting *
; US.UnderNet.Org » #Hawkee.com #mircscripting ~
;*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*
on $*:TEXT:/^[.!@](snip(pets)?|hawk(ee)?)/Si:#:{
set %s.chan $iif($chan == #msl,$nick,$v1)
snippets $2-
}
alias snippets {
if ($sock(snippets)) {
%smsg Wait until the current search has been finished.
halt
}
set %smsg $iif(%s.chan,$iif(%s.chan == #msl,notice,msg) %s.chan,echo -a)
if (!$1) {
%smsg Syntax: $iif(%s.chan,!,/) $+ snippets [-type] <search criteria>
halt
}
if ($left($1,1) == -) {
if ($istok(-asp|-cfm|-css|-java|-js|-jsp|-mirc|-mysql|-net|-perl|-php|-python|-ruby|-tcl|-myspace|-opensocial|-cpp|-hi5,$1,124)) {
if (!$2) {
%smsg Please specify search criteria.
halt
}
set %s.prop $1
}
else {
%smsg The available switches are: -asp cpp -cfm -css -hi5 -java -js -jsp -mirc -myspace -mysql -net -opensocial -perl -php -python -ruby -tcl
halt
}
}
set %s.search $iif(%s.prop,$2-,$1-)
$iif(%s.chan,describe %s.chan searches,echo -a Searching) for $qt(%s.search) in $iif(%s.prop,$replace(%s.prop,-asp,ASP,-cpp,C++,-cfm,CFM,-css,CSS,-java,Java,-js,JavaScript,-jsp,JSP,-mirc,mIRC,-mysql,MYSQL,-net,.NET,-perl,Perl,-php,PHP,-python,Python,-ruby,Ruby,-tcl,TCL,-myspace,MySpace,-opensocial,OpenSocial,-hi5,Hi5)) Snippets...
sockopen snippets www.hawkee.com 80
}
on *:sockopen:snippets:{
set %s.url $+(/,$iif(%s.prop,$+($mid(%s.prop,2-),/)),snippets/search/,$replace(%s.search,$chr(32),+),/)
unset %s.prop
if (!$sockerr) {
sockwrite -nt $sockname GET %s.url HTTP/1.0
sockwrite -n $sockname Host: www.hawkee.com
sockwrite -n $sockname $crlf
}
else { echo -st Socket Error $nopath($script) }
}
on *:sockread:snippets:{
var %x
sockread %x
if (We couldn't find any snippets to match your search. isin %x || We have not received any snippets for this section yet. isin %x) {
%smsg Sorry, no matches were found for $qt(%s.search) $+ .
unset %s.*
sockclose $sockname
}
if ($regex(%x,/'>([^<]*) like\(s\)/i)) set %s.likes $regml(1)
if ($regex(%x,/Score: <b>([^<]*)<\/b>/)) set %s.rating $regml(1)
if ($regex(%x,/<a href='([^<]*)' class='large'>([^<]*)<\/a>/)) {
set %s.title $regml(2)
set %s.url2 http://www.hawkee.com $+ $regml(1)
}
if ($regex(%x,/Added:<\/span> ([^<]*\x2C\s[\d^<]{4})/)) { set %s.date $regml(1) }
if ($regex(%x,/By:<\/span> <a href='http:\/\/www.hawkee.com\/profile\/[^<]*\/'>([^<]*)<\/a>/)) { set %s.by $regml(1) }
if ($regex(%x,/<a href="\/.*\/snippets\/">([^<]+)<\/a>/i)) {
set %s.lang $regml(1)
inc %N
%smsg 9• 4Title: %s.title 4Author: %s.by 4Sumbitted: %s.date 4Language: %s.lang 4Score: %s.rating 4Likes: %s.likes 4URL: %s.url2
if (%N == 3) {
unset %s.* %N %smsg
sockclose $sockname
}
}
if (<div id="sidebar"> isin %x) sockclose $sockname
}
on *:sockclose:snippets: unset %s.* %N %smsg
alias hawk snippets $1-
alias snip snippets $1-
alias hawkee snippets $1-
