Translator

mIRC Code

+ 4 likes

Please Register to submit score.

Average Score	9.6
Scores Submitted	17
Date Added	Mar 04, 2008
Last Updated	Jun 25, 2008
Tags	alias dialog dutch english french german italian portuguese spanish trans translate translator

Introduction

This is a translator script that I made, it uses Google Translator. It translates English, Spanish, French, Italian, Portuguese, Dutch, and German. But most languages only translate into English.

Syntax: [!translate|/translate] [from-to] [words]

Examples:

/translate fr-en au revoir
!translate es-en Tengo un script muy interesante!

Also, there's a dialog. Right click on any window and click "Translator". You click the original language from the left, and then click the language you want to translate to on the right. Type what you want to translate in the edit box, and click "Translate". The translation will show up in the read-only edit box below it.

Screens

Enjoy

Grab the Code

;~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~
;                Translator                      *
;            Made by MountainDew                 ~ 
; IRC.DeltaAnime.Net » #Lindrian #mIRC-Scripting *
;  US.UnderNet.Org » #Hawkee.com #mircscripting  ~
;*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*~*

menu * {
  Translator: trans_dialog
}
alias trans_dialog dialog $iif($dialog(trans),-v,-m) trans trans
dialog trans {
  title "Translator"
  size -1 -1 99 137
  option dbu
  list 1, 8 22 35 49, size
  list 2, 56 22 35 49, size
  box "To", 3, 53 13 41 61
  box "From", 4, 5 13 41 61
  text "Translator", 5, 37 3 29 8
  edit "", 6, 9 79 83 10, multi autohs autovs
  button "OK", 7, 40 126 20 9, ok cancel
  button "Translate", 8, 36 91 28 9, disable
  box "Translation", 9, 5 103 89 20
  edit "", 10, 8 111 83 10, read multi autovs
}
on *:dialog:trans:*:*:{
  if ($devent == init) {
    didtok trans 1,2 32 English Spanish French Portuguese German Dutch Italian
  }
  if ($devent == sclick) {
    if ($did isnum 1-2) {
      if ($did(trans,2).seltext) && ($did(trans,1).seltext) && ($did(trans,6).text) did -e trans 8
      did -r trans 10
    }
    if ($did == 8) {
      if ($did(trans,1).seltext == $did(trans,2).seltext) {
        noop $input(You can't translate to the same language!,ho,Error!)
        did -b trans 8
        halt
      }
      did -b trans 8
      did -r trans 10
      set %t.d 1
      sockopen trans translate.google.com 80
      sockmark trans $+($lang($did(trans,1).seltext),~,$lang($did(trans,2).seltext),~,$did(trans,6))
    }
  }
  if ($devent == edit) {
    did $iif($did(trans,6).text && $did(Trans,2).seltext,-e,-b) trans 8
    did -r trans 10
  }
}
alias translate {
  if ($sock(trans)) {
    %t.msg There's already a translation in progress.
    halt
  }
  set %t.msg $iif(%t.chan,msg $v1,echo -a)
  if (!$regex($$1,/^(?:it|pt|es|nl|de|fr|en)-(?:it|pt|es|nl|de|fr|en)\b/i)) {
    %t.msg Syntax: $iif(%t.chan,!,/) $+ translate from-to [words]
    %t.msg Languages: English (en) French (fr) Spanish (es) Italian (it) Portuguese (pt) German (de) Dutch (nl)
    halt
  }
  elseif (!$2) {
    %t.msg Syntax: $iif(%t.chan,!,/) $+ translate from-to [words]
    halt
  }
  if ($left($1,2) == $right($1,2)) {
    %t.msg You can't translate into the same language!
    halt
  }
  sockopen trans translate.google.com 80
  sockmark trans $+($left($1,2),~,$right($1,2),~,$2-)
  $iif(%t.chan,describe $v1 translates,echo -a Translating) $qt($2-) from $replace($1,-,$chr(32) to $chr(32),es,Spanish,en,English,fr,French,it,Italian,pt,Portuguese,nl,Dutch,de,German) $+ ...
}
on *:sockopen:trans:{
  sockwrite -nt $sockname GET $+(/translate_t?langpair=,$gm($sockname,1,126),$chr(124),$gm($sockname,2,126),&text=,$replace($gm($sockname,3,126),$chr(32),+)) HTTP/1.1
  sockwrite -nt $sockname Host: translate.google.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:trans:{
  sockread &x
  if ($bfind(&x,1,<div id=result_box)) { 
    sockmark $sockname $+($sock($sockname).mark,~,$replace($bvar(&x,$calc($v1 + 29),$calc($bfind(&x,$v1,</div>)- $v1 -29)).text,&#39;,'))
    if (%t.d) {
      did -a trans 10 $gm($sockname,4,126)
      did -e trans 8
    }
    else %t.msg 4Translation: $gm($sockname,4,126)
    sockclose $sockname
    unset %t.*
  }
}
alias lang return $replace($1,Spanish,es,English,en,French,fr,Portuguese,pt,Italian,it,Dutch,nl,German,de)
alias gm return $gettok($sock($1).mark,$2,$3)
alias trans translate $1-
on $*:text:/^[!@.]trans(lat(e|ion))?\b/Si:#:{
  set %t.chan $chan
  translate $2-
}

Comments

(61) RSS

Go to Bottom

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Mar 20, 2008 4:25 pm

I fixed the script, it should work now.

Enjoy

DarkNES

Comments: 11

mIRC Snippet: Translator
Posted on Mar 20, 2008 7:28 pm

menu Channel {
Translator: dialog $iif($dialog(trans),-v,-m) translate translate
}

Added that to it. Might be more useful.

DarkNES

Comments: 11

mIRC Snippet: Translator
Posted on Mar 20, 2008 7:29 pm

I'll give it a 10. Ya, it's much better than ones I've seen in the past lol. (And you spelled everything right :D)

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Mar 20, 2008 7:40 pm

Quote:

menu Channel {
Translator: dialog $iif($dialog(trans),-v,-m) translate translate
}

Added that to it. Might be more useful.

Thank you very much for pointing that out, I forgot about that. (I have it my "MountainDew's Scripts" menu, so I forgot that other people don't have that ;)

And I'm glad you like it

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Mar 20, 2008 7:43 pm

^^ Also, if you added that to the script, the dialog is "trans_dialog", not "translate"

But I updated the script.

Eugenio

Comments: 1,097

mIRC Snippet: Translator
Posted on Mar 20, 2008 10:50 pm

It works now.

ShAmPi

Comments: 12

mIRC Snippet: Translator
Posted on Mar 22, 2008 11:40 am

Nice script
1 small error though

Code:

(&ShAmPi) !translate en-pt This is a test
(&Pantsu-man) Translating "This is a test" from English to PortuguSpanishe...
(&Pantsu-man) Translation: Este � um teste

PortuguSpanishe ^^
Probably because of the ES in PortuguESe

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Apr 10, 2008 3:59 pm

Thanks for catching that ShAmPi, I'll try to fix it right now.

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Apr 10, 2008 4:25 pm

Alright, it should be fixed now.

SweeTCooL

Comments: 13

mIRC Snippet: Translator
Posted on Apr 12, 2008 10:08 am

Nice work :D keep it up

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Apr 14, 2008 9:35 am

Thanks SweeTCooL, I'm glad ya like it

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Apr 18, 2008 5:03 pm

Updated:

It now uses Google Translator, it should work much better than Babelfish :)

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Apr 19, 2008 11:12 am

Updated, the host and GET were on the same line for some reason ;)

jonesy44

Comments: 1,085

mIRC Snippet: Translator
Posted on Apr 19, 2008 12:09 pm

snazzy, gj bud xD

testing now ;-)

jonesy44

Comments: 1,085

mIRC Snippet: Translator
Posted on Apr 19, 2008 12:11 pm

im finding it's not returning anything in the dialog :s

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Apr 19, 2008 12:21 pm

Ugh, someone else said that too. I don't know why, it seems to be working fine for me :/

jonesy44

Comments: 1,085

mIRC Snippet: Translator
Posted on Apr 19, 2008 1:54 pm

Quote:

Translating "Hello" from English to French...
Translation:

are you using a translator specified for a country/region. like google has .co.uk .ca etcetc.. for diff countries.?

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Apr 19, 2008 2:03 pm

www.google.com/translate_t

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Apr 21, 2008 3:02 pm

Awesome, I got it working :)

^^Script's updated

Mae

Comments: 5

mIRC Snippet: Translator
Posted on May 7, 2008 7:24 pm

Im a total noob to scripting and i was wondering if you could tell where to put thing si know this is probly really dumb of me to ask but i just cant get it to work i keep getting Syntax: !translate from-to [words] (Note: I may not be able to translate to that language) Plz help Ps love the script

Mae

Comments: 5

mIRC Snippet: Translator
Posted on May 7, 2008 8:22 pm

I figured out the syntax but now ive got the problem of the translation itself
o/<18:21>/o <Mae> !translate en-de Hi
o/<18:21>/o <Archer> Translating "Hi" from English to German...
o/<18:21>/o <Archer> Translation:
I get nothing else help please :(

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on May 7, 2008 8:45 pm

Ugh...looks like it's screwed up...

I don't think I'm gonna be able to use google translator anymore, I'll see what I can do tomorrow.

Mae

Comments: 5

mIRC Snippet: Translator
Posted on May 7, 2008 9:30 pm

Alright Sorry for having brought that to your attention :(

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on May 7, 2008 9:32 pm

Nah, don't be sorry ;)

It worked fine with babelfish, but babelfish sucked at translating, so I went with google translator, and it seems to only work with me and not others for some odd reason.

Mae

Comments: 5

mIRC Snippet: Translator
Posted on May 8, 2008 6:38 am

Hmm ill try it again thanks for checking it out

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on May 8, 2008 4:13 pm

So it's updated, I switched it to FreeTranslation

jonesy44

Comments: 1,085

mIRC Snippet: Translator
Posted on May 8, 2008 5:15 pm

I praise that website .. spanish :D

Ryan1981

Comments: 5

mIRC Snippet: Translator
Posted on May 9, 2008 1:00 pm

Hi,

First of all, really really nice work, this is probably one of the most usefull scripts for a chat program.

I am hoping that you will be able to get back to Google translate, I think it is the most promising translater of them all. It worked for me a week ago and now it suddenly does not return the translation.

If you need some debug info I'll be glad to provide it. Just say wich variables to echo and I'll do it.

With Kind Regards,

Ryan

Ryan1981

Comments: 5

mIRC Snippet: Translator
Posted on May 9, 2008 3:29 pm

Hi,

Really sorry to be buggin you again, I tried your version of freetranslate and it works fine. Unfortunately I forgot to backup your google translate version and since the translations from freetranslate are much worse than those of google I'd really like the old code to try and see if I could make it work again.

With Kind Regards,

Ryan

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on May 9, 2008 3:53 pm

I'm sorry Ryan, I don't have the Google one anymore =/

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on May 9, 2008 4:02 pm

Hmm

I noticed Google has a Beta Translator out

I'll try writing it again with Google, because I agree, it's the best translator.

Ryan1981

Comments: 5

mIRC Snippet: Translator
Posted on May 9, 2008 4:02 pm

Ahhh shoot lol, I saw U used binvars for it and I am not very familiar with those :( Thanks for the answer anyway

Ryan1981

Comments: 5

mIRC Snippet: Translator
Posted on May 9, 2008 4:03 pm

Ahh cool :D

Ryan1981

Comments: 5

mIRC Snippet: Translator
Posted on May 9, 2008 4:10 pm

I did some googling and there seems to be some sort of API out to be used for ajax and java. I read on a forum some guy saw it implemented into IRC, maybe he was talking about your script, I am not really into these things.

http://googlesystem.blogspot.com/2008/03/google-launched-another-ajax-api-this.html

Maybe you can avoid the binvars (just a wild guess from my side) when you try to call this API directly instead of using the web interface.

Sorry if this is what you already did since I am not that familiar with html-mirc coding :$

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on May 9, 2008 4:39 pm

I have no clue what any of that means, lol.

Ryan, I pm'ed you a rough script of Google Translator. PM me back and tell me if it works for you.

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on May 11, 2008 3:46 pm

Alright, so I know I've been jumping from translator to translator, but now, I've finally gotten it to work with Google Translator again :)

The cool thing about Google is that it's for one, more accurate, and also, you can translate any language to any language.

And thanks for helping me out with testing it and stuff, Ryan

SpotRedDog

Comments: 81

mIRC Snippet: Translator
Posted on May 12, 2008 1:39 pm

Never Mind

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on May 12, 2008 1:54 pm

Well if I'm not mistaken, I believe the other languages just show up as boxes :/

SpotRedDog

Comments: 81

mIRC Snippet: Translator
Posted on May 12, 2008 3:32 pm

Never Mind

SweeTCooL

Comments: 13

mIRC Snippet: Translator
Posted on May 27, 2008 3:15 am

i got this -> * /did: invalid parameters (line 93, Translator.txt)

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Jun 5, 2008 2:03 pm

Hmm it must of had an error or something, type //unset %t.*

Bahamut

Comments: 5

mIRC Snippet: Translator
Posted on Jun 6, 2008 1:19 am

Wonderful for my foreign language classes. On initation of the dialog, why not use /didtok? Nice snippet.

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Jun 6, 2008 6:06 am

That's a great idea, I never thought of using /didtok :P

Edit: Updated it using didtok

SweeTCooL

Comments: 13

mIRC Snippet: Translator
Posted on Jun 9, 2008 6:51 pm

oh ok thx dude :D

knoeki

Comments: 6

mIRC Snippet: Translator
Posted on Jun 21, 2008 4:39 pm

it stopped working for me...

ShAmPi

Comments: 12

mIRC Snippet: Translator
Posted on Jun 23, 2008 5:28 pm

Yeah same for me.
Again an empty output :(

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Jun 23, 2008 6:16 pm

Really? It seems to work fine for me. Are there any errors in you guys' status windows?

ShAmPi

Comments: 12

mIRC Snippet: Translator
Posted on Jun 25, 2008 4:24 pm

Well.
It works now :D
Might have been googles problem ;)

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Jun 25, 2008 6:01 pm

Updated, there was a problem with the &binvars

TropicalMeltdown

Comments: 76

mIRC Snippet: Translator
Posted on Aug 23, 2008 9:33 am

dude its not the rite spanish 5/10

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Aug 23, 2008 10:16 am

TropicalMeltdown, I didn't make the translations themselves, it sockets to Google Translator. There's no such thing as a perfect translator anyways.

TropicalMeltdown

Comments: 76

mIRC Snippet: Translator
Posted on Aug 23, 2008 10:41 am

awww sorry mi bad

new2k4

Comments: 1

mIRC Snippet: Translator
Posted on Sep 23, 2008 5:31 pm

why not put more languages there? i modified it for myself by adding some more. Though i left out the one that need language pack installed, like Chinese, Japanese...

and it's very nice :) ty

Bullet_Dodger

Comments: 195

mIRC Snippet: Translator
Posted on Sep 28, 2008 9:45 am

Very Good Script
[10/10] +Like

^Neptune

Comments: 341

mIRC Snippet: Translator
Posted on Sep 28, 2008 10:15 am

Yeah would be quite nice to add all available languages on the site. Nice job though.

Bullet_Dodger

Comments: 195

mIRC Snippet: Translator
Posted on Sep 28, 2008 10:19 am

The only reason Japanese , Chinese isnt on there is because on mIRC it comes out ? or �
instead of the letters

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Sep 29, 2008 2:31 pm

Yea I did add more languages once but I like lost the script when I updated mIRC or something. I'll try to add them again when I get a chance.

SuPeRFlY

Comments: 14

mIRC Snippet: Translator
Posted on Sep 29, 2008 6:45 pm

Great script. Excelent work. 10/10

Jamiie

Comments: 140

mIRC Snippet: Translator
Posted on Oct 1, 2008 11:28 pm

Nicely done mountaindew. 10/10+like.. how would you go about making it message chan or active using the alias? instead of the ! event.

mountaindew

Comments: 1,645

mIRC Snippet: Translator
Posted on Oct 2, 2008 2:10 pm

Thanks Jamiie.

In this line:

Code:

set %t.msg $iif(%t.chan,msg $v1,echo -a)

change "echo -a" to "msg $active".

Jamiie

Comments: 140

mIRC Snippet: Translator
Posted on Oct 2, 2008 9:03 pm

Done, I took out the line that says "translation" and switched a few switches around to short alias' to make people think I'm speaking a different language. :P

Translator

Introduction

Grab the Code

Comments

mountaindew

My Snippet Tags

Contact

Friends (49)

Sponsors

		United States
Last seen: Oct 10, 2008 Profile \| Website Likes (75) Friends (49) Snippets (32) Images (22) Products (7) Reviews (12) Comments Received (869) Comments Submitted (1645) Forum Posts (922)