Hawkee (latest) review search

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	8.0
Scores Submitted	2
Date Added	Feb 28, 2008
Last Updated	Feb 28, 2008
Tags	hawkee latest review search

Introduction

This is my versions of mountaindews review search.
Command referance:
/reviews [#channel] [search criteria]
!reviews [search criteria]

Examples:
/reviews Wii - Searches for "Wii" and echos the info.
/reviews #Lindrian - Messages all the latest reviews to #Lindrian
/reviews #Lindrian Wii - Searches for "Wii" and messages the info to #Lindrian.

!reviews Wii - Searches for "Wii" and messages the info.
!reviews - Messages all the latest reviews to the channel.

If you want it to only return one result, uncomment the ".sockclose $sockname" on line 41.

Enjoy.

Grab the Code

alias reviews {
  unset %hawkee
  if ($left($1,1) isin $chantypes) var %chan = $1
  else var %search = $1-
  if ($2) && (!%search) var %search = $2-
  var %x = $+(reviews.,$r(0,9),$r(0,9),$r(0,9),$r(a,z),$r(a,z)), %u = $iif(%chan && $me ison $1,msg $1,echo -a)
  if (%hawkee.stop) %u This command was recently used, please wait a few seconds.
  else {
    %u $iif(%search,Searching for reviews matching $qt($iif($left($1,1) !isin $chantypes,$1-,$2-)),Looking up the latest reviews) on hawkee.com, please hold...
    sockopen %x www.hawkee.com 80
    sockmark %x $+(%chan,$chr(1),%search)
    set -u10 %hawkee.stop 1
  }
}
on *:SOCKOPEN:reviews.*: {
  tokenize 1 $sock($sockname).mark
  if ($sockerr) $iif($left($1,1) isin $chantypes && $me ison $1,msg $1,echo -a) There was an error while connecting to the hawkee server! Please try again later!
  else {
    sockwrite -nt $sockname GET $iif($left($1,1) !isin $chantypes || $2 && $1,/shop/search/ $+ $replace($iif($2,$2,$1),$chr(32),+) $+ /reviews/,/shop/reviews) HTTP/1.1
    sockwrite -nt $sockname Host: www.hawkee.com
    sockwrite -nt $sockname $crlf
  }
}
on *:SOCKREAD:reviews.*: {
  tokenize 1 $sock($sockname).mark
  var %x, %i = $iif($left($1,1) isin $chantypes && $me ison $1 && $1 ischan,msg $1,echo -a)
  sockread %x
  if ($regex(a,%x,/<div class='.*' style="height: 27px;">(.*?)<\/div>/i)) {
    %i $regml(a,1)
    .sockclose $sockname
  }
  if ($regex(b,%x,/<td align=left valign=top style="padding-left: 10px;"><a href='(.*?)' class='large'>(.*?)<\/a><\/td>/i)) set $+(%,$sockname) $+($regml(b,1),$chr(1),$regml(b,2),$chr(1))
  if ($regex(c,%x,/<td valign=top class='\w+' style="padding-left: 5px; padding-right: 0px;"><a href=".*?" class='product'>(.*?)<\/a><br><br>/i)) && (% [ $+ [ $sockname ] ]) {
    tokenize 1 $+(% [ $+ [ $sockname ] ],$regml(c,1))
    set $+(%,$sockname) $b(Title:) $2 $b(Product:) $3 $b(Link:) http://www.hawkee.com $+ $1
    inc %hawkee
  }
  if ($regex(d,%x,/(?!.*(?:http:\/\/|www)).*(?:by|on) <a href='.*?' class='smaller'>(.*?)<\/a><br>.*/i)) {
    %i $+($chr(35),%hawkee -) % [ $+ [ $sockname ] ] $b(By:) $regml(d,1)
    unset $+(%,$sockname)
    ; .sockclose $sockname
  }
}
on *:TEXT:!reviews*:#: reviews $chan $2-
alias -l b return $+($chr(2),$1,$chr(2))

Comments

(9) RSS

Go to Bottom

mountaindew

Comments: 1,636

mIRC Snippet: Hawkee (latest) review search
Posted on Feb 28, 2008 6:14 pm

nice job Lindrian

Lindrian

Comments: 755

mIRC Snippet: Hawkee (latest) review search
Posted on Feb 28, 2008 6:17 pm

Thanks :)

Hawkee

Comments: 566

mIRC Snippet: Hawkee (latest) review search
Posted on Feb 29, 2008 12:30 am

Don't forget there are different sort options.

Lindrian

Comments: 755

mIRC Snippet: Hawkee (latest) review search
Posted on Feb 29, 2008 3:39 am

Oh right. The only problem is how you will allow the user to function them. I would probably have to go and use switches, like /reviews -l would return the latest, etc etc. But that would be a little annoying in the channel i belive.

LordHawk

Comments: 18

mIRC Snippet: Hawkee (latest) review search
Posted on Feb 29, 2008 7:13 pm

nicely done

F*U*R*B*Y*

Comments: 567

mIRC Snippet: Hawkee (latest) review search
Posted on Feb 29, 2008 7:23 pm

dialog's <3

Lindrian

Comments: 755

mIRC Snippet: Hawkee (latest) review search
Posted on Mar 3, 2008 3:50 am

F*U*R*B*Y*: not in this case :p

SiLver_ShaDow

Comments: 5

mIRC Snippet: Hawkee (latest) review search
Posted on Mar 25, 2008 9:14 am

hi, ty for this cool snippet

but its verry flood,

�| L@�Gh @�T L@aD |�

if u can change it to view just the first 3 or 5 results

will be better

ty again :)

mountaindew

Comments: 1,636

mIRC Snippet: Hawkee (latest) review search
Posted on Apr 22, 2008 6:23 pm

Where you see the "; .sockclose $sockname", you could replace that with inc %var, and then if (%var == 3) sockclose $sockname

Hawkee (latest) review search

Introduction

Grab the Code

Comments

Lindrian

My Snippet Tags

Contact

Friends (15)

Sponsors

		Sweden
Last seen: Oct 03, 2008 Profile \| Website Likes (3) Friends (15) Scripts (1) Snippets (34) Images (23) Comments Received (547) Comments Submitted (755) Forum Posts (1199)