Call of Duty 4 server checker

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	8.8
Scores Submitted	4
Date Added	Feb 18, 2008
Last Updated	Feb 18, 2008
Tags	4 call checker duty of server

Introduction

I recently started playing call of duty 4, so I thought, why not make a mirc script for it? Might come in handy.
I got the idea from this guy: http://www.hawkee.com/snippet/3708/
This is simply my version of this :)

Command referance:

/codchk [-astc] <ip:port> [alias] [nickname] [Delay]

the -a switch will return the values to an alias, if you want to use this in a channel or similar, you get the point.
the -s switch will "Search" for a user and highlight him in the user list.
the -t switch will enable a delay, which is optional. If no number was specified, 10 seconds will be used.
the -c switch is a simple lookup with echoing.

The script will highlight the user with the lowest ping and show additional information about the server itself and the players.

Examples:

/codchk -c 66.135.53.77:28960
/codchk -cs 66.135.53.77:28960 Lindrian
/codchk -ct 66.135.53.77:28960 50
/codchk -cst 66.135.53.77:28960 Lindrian 50

/codchk -a 66.135.53.77:28960 cod_alias
/codchk -as 66.135.53.77:28960 cod_alias Lindrian
/codchk -at 66.135.53.77:28960 cod_alias 50
/codchk -ast 66.135.53.77:28960 cod_alias Lindrian 50

Screenshot:

I have avoided all usage of pure color codes, cause I hate that shit. So im using aliases to return the $chr(), much cleaner imo.

Please report any bugs or suggestions you may have, I havent been working on this very much. I did some vague testing but thats it!

----------------------------------------

Updates:
The sript has been updated, channel triggers has been added. Be sure to change "#channel" into your channel name for it to work.

Enjoy! :-)

Grab the Code

; ---------------------------------------------------------
; Call of Duty 4 - Modern warefare server information
; By Lindrian
; Contact: irc.deltaanime.net @ #Lindrian
; Email: firas.dib@gmail.com
; ---------------------------------------------------------

; ###############################
; # Aliases                     #
; ###############################

alias -l br {
  var %cod.r = $+($b,$chr(40),$b,$c,07,$1,$c,$b,$chr(41),$b)
  return $iif($2,$strip(%cod.r,$2),%cod.r)
}
alias -l cod.op return $iif($1 isop $2,1,0)
alias -l cod.chan {
  if (%cod4.chan) && ($me ison %cod4.chan) msg $v2 $1-
}
alias -l gp return $replacecs($1,ctf,Capture the Flag,dm,Free For All,war,Team Deathmatch,sab,Sabotage,sd,Search & Destroy,koth,Headquarters,dom,Domination)
alias -l mp return $replace($1,mp_backlot,Backlot,mp_bloc,Bloc,mp_bog,Bog,mp_cargoship,Wet Work,mp_citystreets,District,mp_convoy,Ambush,mp_countdown,Countdown,mp_crash_snow,Crash [Snow],mp_crash,Crash,mp_crossfire,Crossfire,Mp_farm,Downpour,mp_overgrown,Overgrown,mp_pipeline,Pipeline,mp_shipment,Shipment,mp_showdown,Showdown,mp_strike,Strike,mp_vacant,Vacant)
alias -l cod.timeout {
  .sockclose cod_server
  cod.msg The connection timed out, the server might be down.
  cod.tmr -s
  unset %cod.e
}
alias -l cod.chk {
  if (!%cod.u) cod.done
}
alias -l cod.done {
  cod.tmr -s
  cod.msg %cod.s
  if (%cod.z1) {
    var %u = 1
    while (%cod.z [ $+ [ %u ] ]) {
      inc %cod.tmp2 $numtok($v1,1)
      inc %u
    }
    cod.msg Players $br($+(%cod.tmp2,/,%cod.o)) $+($chr(40),$b(N),ame -,$chr(32),$b(S),core -,$chr(32),$b(P),ing,$chr(41)) $+ :
    var %cod.1 = 1, %cod.2 = 1, %h = %cod.m, %z = %cod.q, %r = %cod.search
    while (%cod.z [ $+ [ %cod.1 ] ]) {
      var %k = %cod.z [ $+ [ %cod.1 ] ]
      var %cod.y1 = $gettok(%k,$findtok(%k,%z,1,32),32)
      if (%cod.y1) set $+(%,cod.z,%cod.1) $reptok(%k,%cod.y1,$+($c,04,%cod.y1,$c),32)
      var %k = %cod.z [ $+ [ %cod.1 ] ]
      var %cod.y2 = $gettok(%k,$findtok(%k,%h,1,32),32)
      if (%cod.y2) set $+(%,cod.z,%cod.1) $reptok(%k,%cod.y2,$+($c,10,%cod.y2,$c),32)
      if (%r) {
        var %k = %cod.z [ $+ [ %cod.1 ] ]
        var %cod.y = $gettok(%k,$findtok(%k,%r,1,32),32)
        if (%cod.y) set $+(%,cod.z,%cod.1) $reptok(%k,%cod.y,$+($c,03,%cod.y,$c),32)
      }
      inc %cod.1
    }
    while (%cod.z [ $+ [ %cod.2 ] ]) {
      var %k = $v1
      cod.msg $left($replace(%k,$i,$chr(44)),-1)
      inc %cod.2
    }
  }
  unset %cod.e %cod.c
}
alias -l ck {
  if (!$findtok($1,$2,1,92)) return ???
  var %cod.r = $gettok($1,$calc($findtok($1,$2,1,92) +1),92)
  return $iif(_ !isin $left(%cod.r,1),$iif(%cod.r,$cc($v1),???),$ci($1,%cod.r))
}
alias -l cc return $+($replacecs($1,^1,$c(4),^2,$c(03),^3,$c(08),^4,$c(04),^5,$c(11),^6,$c(13),^7,$c(00),^0,$c(01)),$c)
alias -l cod.tmr {
  if ($timer(cod4)) .timercod4 off
  if ($timer(.cod4)) && ($1) .timer.cod4 off
}
alias -l cod.msg {
  $iif(%cod.c,$(%cod.c,2),echo -a) $1-
  if ($sock(cod.getstatus)) .sockclose cod_server
}
alias -l c return $chr(3) $+ $iif($1,$1)
alias -l b return $iif(!$1,$chr(2),$+($chr(2),$1,$chr(2)))
alias -l i return $chr(1)
alias -l cod.ip {
  noop $regex($1,/^((?:(?:[01]?\d?\d|2[0-4]\d|25[0-5])\.){3}(?:[01]?\d?\d|2[0-4]\d|25[0-5])):(\d{4,})$/) 
  return $regml(1) $regml(2)
}
alias -l cod.save hsave -o cod $qt($scriptdircod.hsh)
alias codchk {
  if (!%cod.�) {
    if (!%cod.e) {
      if ($cod.ip($2)) && ($regex($1,/-?[satc]/iA)) {
        unset %cod.*
        var %cod.w = $mid($1,2)
        if (a isin %cod.w) {
          if ($isalias($3)) set %cod.c $3
          else goto err
          if (t isin %cod.w) var %cod.� = $iif(s !isin %cod.w,$4,$5), %cod.� = $iif(%cod.� && %cod.� isnum,$v1,10)
          if (s isin %cod.w) {
            if ($4) set %cod.search $4
            else goto err
          }
        }
        elseif (c isin %cod.w) {
          if (t isin %cod.w) var %cod.� = $iif(s !isin %cod.w,$3,$4), %cod.� = $iif(%cod.� && %cod.� isnum,$v1,10)
          if (s isin %cod.w) {
            if ($3) set %cod.search $3
            else goto err
          }
        }
        else goto err
        %cod.f = 1000 | %cod.i = 1 | %cod.u = 1 | %cod.e = 1 | %cod.tmp = 1 | %cod.n = 0
        cod.msg Looking up server information for $br($2) $+ , please hold...
        sockudp -k cod_server $cod.ip($2) $str($chr(255),4) $+ getstatus
        cod.tmr -s
        .timercod4 1 10 cod.timeout
        .timer.cod4 -m 0 1 cod.chk
        if (t isin $1) set $+(-u,%cod.�) % $+ cod.� $calc($ctime + %cod.�)
      }
      else {
        :err
        cod.msg * /codchk: insufficient parameters
      }
    }
    else cod.msg There is already another server lookup in progress, please hold...
  }
  else cod.msg This script was recently used, please try again in $calc(%cod.� - $ctime) second(s).
}

; ###############################
; # ON events                   #
; ###############################

on *:UNLOAD: unset %cod.* %cod4.chan
on *:START: {
  if (!$hget(cod)) .hmake cod 100
  if ($isfile($shortfn($scriptdircod.hsh))) .hload cod $shortfn($scriptdircod.hsh)
}
on *:UDPREAD:cod_server: {
  if ($sockerr) cod.msg The connection timed out - $sock($sockname).wsmsg
  else {
    var %cod.x
    sockread %cod.x
    cod.tmr
    if (!%cod.i) tokenize 32 %cod.x
    elseif ($chr(92) isin %cod.x) {
      %cod.s = $br(Server name) $ck(%cod.x,sv_hostname) $br(Version) $ck(%cod.x,shortversion) $br(Admin) $ck(%cod.x,_admin) $br(Contact) $ck(%cod.x,_email) - $ck(%cod.x,_website) $br(Mode) $iif($ck(%cod.x,sv_pure) != ???,Hardcore,Normal) $br(Kill cam) $iif($ck(%cod.x,scr_killcam) != ???,Yes,No) $br(Type) $gp($ck(%cod.x,g_gametype)) $br(Map) $mp($ck(%cod.x,mapname))
      %cod.o = $ck(%cod.x,ui_maxclients)
      %cod.i = 0
      return
    }
    if ($2) {
      var %cod.v = $regsubex($3,/\^\d|"/gi,)
      if ($len(%cod.z [ $+ [ %cod.tmp ] ]) > 400) inc %cod.tmp
      set $+(%,cod.z,%cod.tmp) %cod.z [ $+ [ %cod.tmp ] ] $b(N:) %cod.v S: $1 P: $2 $+ $i
      if ($2 < %cod.f) { %cod.f = $2 | %cod.q = %cod.v }
      if ($1 > %cod.n) { %cod.n = $1 | %cod.m = %cod.v }
    }
    set -u1 %cod.u 1
  }
}
on *:TEXT:!COD *:#asdasd: { 
  if (c !isincs $chan($chan).mode) && (S !isincs $chan($chan).mode) {
    if ($2 == help) {
      msg $chan The current commands are:
      msg $chan !Cod [add|del|view|info|list] [name] [ip:port] [search nick]
      msg $chan Color referance:
      msg $chan This $+($c(10),color,$c) highlights the user with the highest score, this $+($c(04),color,$c) highlights the user with the lowest ping and this $+($c(03),color,$c) highlights the user you searched for, if any. If the same user matches more than 1 criteria, only one color will be used.
    }
    elseif ($2 == add) && ($cod.op($nick,$chan)) {
      if ($cod.ip($4)) && ($4) {
        msg $chan Successfully $iif($hfind(cod,$3,1,W),replaced,added) $br($3,c) $+ .
        hadd -m cod $3 $replace($cod.ip($4),$chr(32),:)
        cod.save
      }
      else msg $chan Invalid syntax or IP. Try !cod add [name] [ip:port]
    }
    elseif ($2 == clear) && ($cod.op($nick,$chan)) {
      hdel -w cod *
      cod.save
      msg $chan Successfully cleared the database.
    }
    elseif ($2 == info) {
      if ($hfind(cod,$3,1,W)) || ($cod.ip($3)) && ($3) {
        set %cod4.chan $chan
        codchk $iif($4,-ast,-at) $iif($hfind(cod,$3,1,W),$hget(cod,$3),$replace($cod.ip($3),$chr(32),:)) cod.chan $4
      }
      else msg $chan Invalid syntax or ip!
    }
    elseif ($2 == view) {
      if ($3) {
        if ($hfind(cod,$3,1,W)) {
          msg $chan Item $br($3,c) $+ : $hget(cod,$3)
        }
        else msg $chan The item $br($3,c) does not excist!
      }
      else msg $chan Invalid syntax! Try: !cod view [name]
    }
    elseif ($2 == del) && ($cod.op($nick,$chan)) {
      if ($3) {
        if ($hfind(cod,$3,1,W)) {
          hdel cod $3
          cod.save
          msg $chan Successfully deleted $br($3,c)
        }
        else msg $chan The item $br($3,c) does not excist!
      }
      else msg $chan Invalid syntax! Try: !cod del [name]
    }
    elseif ($2 == list) {
      if (!%cod.halt) {
        msg $chan There are currently $br($hget(cod,0).item,c) $iif($hget(cod,0).item = 1,server,servers) stored in the database.
        var %x = 1, %y = 1
        while ($hget(cod,%x).item) {
          var %z $+ %y %z [ $+ [ %y ] ] $qt($v1) $hget(cod,$v1) $+ $i
          if ($len(%z [ $+ [ %y ] ]) > 600) inc %y
          inc %x
        }
        var %i = 1
        while (%z [ $+ [ %i ] ]) {
          msg $chan $left($replace($v1,$chr(1),$chr(44) $chr(32)),-3)
          inc %i
        }
        set -u10 %cod.halt $calc($ctime +10)
      }
      else msg $chan Please wait $br($calc(%cod.halt - $ctime),c) second(s) before reusing this command.
    }
  }
  else msg $chan This script will only work if the mode $iif(c isincs $chan($chan).mode,+c,+S) is removed.
}
; ---------------------------------------------------------
; End of file
; ---------------------------------------------------------

Comments

(13) RSS

Go to Bottom

bourneident

Comments: 26

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 18, 2008 7:33 am

hey bro i like this and it works great maybe throw in a !trigger for use in cod4 channel if you can and a save favorites so private servers can be recalled in the chan with the same info with password to connecti know this would be great for the server i\'m on as we run multiple cod4 100mbit servers

Lindrian

Comments: 729

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 18, 2008 7:38 am

Thanks. I will look into that. I made the alias support redirection to other aliases (-a switch) for the usage of !trigger, so the user would have to code that himself. But I\'ll work on that, and I\'ll also work on the thing to save favorites.

But please elaborate, how do you wan\'t it to work? I need a little more information. What I have in mind atm is:

!cod add <name> <ip:port>
!cod del <name>
!cod info <name>
!cod list

Is that alright?

So basically, !cod info <name> will run a check and return the info to the channel it was triggered in.

bourneident

Comments: 26

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 18, 2008 9:38 am

perfect :)

Lindrian

Comments: 729

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 18, 2008 10:12 am

Where can I get in contact with you? Im done with the script (i think), and I would like some proper test before releasing :)

I am at irc.deltaanime.net @ #Lindrian, if you join, just highlight me and i\'ll hopefully be around.

juhapuha

Comments: 70

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 18, 2008 2:18 pm

The script looks useful.:)

Lindrian

Comments: 729

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 18, 2008 3:29 pm

Thanks juhapuha - wait for the new version, im sure you\'ll like it even more! :)

Lindrian

Comments: 729

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 18, 2008 5:00 pm

Script has been updated, check it out.

dave666

Comments: 3

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 19, 2008 4:51 am

What about doing more on it, like able to see what players are in what slots and able to kick ban from irc and send messages to the server.

Lindrian

Comments: 729

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 19, 2008 5:19 am

Im not entirely sure you can do that, dave666. Ive used all info I can get from a server.

dave666

Comments: 3

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 19, 2008 7:07 am

It can be done I have a bot that will do all that from irc accept the send a message to the server does not seem to work. I am still trying to work why it wont.

It all involves using sockets and parsing. I would like it if someone could work out how to parse the mplog so you could have all chat relayed back to irc.

dave666

Comments: 3

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 19, 2008 7:17 am

This is what I get when i query the server or servers.

[13:16:06] [@``Dave``] !ki
[13:16:07] [@ki|slave] ��{Server IP}�� 85.236.101.123:29660 ��{Ping}�� 16 ��{Players}�� 0/24 ��{Server Name}�� ki | All Out War www.ki-squad.co.uk ��{Current Map}�� mp_crossfire ��{Game}�� Call Of Duty ��{Mod}�� Call of Duty 4

Lindrian

Comments: 729

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 19, 2008 10:03 am

You seem to have modified the script. It works perfectly fine for me.

Lindrian

Comments: 729

mIRC Snippet: Call of Duty 4 server checker
Posted on Feb 19, 2008 11:54 am

Any reason for the \"low\" score (a 6, whoever did that.)

Call of Duty 4 server checker

Introduction

Grab the Code

Comments

Lindrian

My Snippet Tags

Contact

Friends (13)

Sponsors

		Sweden
Last seen: Aug 31, 2008 Profile \| Website Likes (3) Friends (13) Scripts (1) Snippets (34) Images (22) Comments Received (511) Comments Submitted (729) Forum Posts (1190)