DOND (Deal or No Deal) v0.18.3 BETA

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	8.4
Scores Submitted	12
Date Added	Jun 12, 2007
Last Updated	Jul 25, 2007
Tags	deal dealornodeal dond game nodeal

Introduction

Something I've been working on for a while and works just like the TV game show. To load, copy & paste to a new remote file (ALT-R -> File -> New)

Take time to look/check the settings. You have to choose the channel for this to work on.

Right-click on any window -> select DOND -> Settings.

Default settings are set upon loading the script. Before you can start the script, enable it first thru the popup menu. You can start the game remotely or using the popup menu.

Remember: This is just beta version. I'm open for comments & suggestions to improve it. Enjoy! =)

Grab the Code

;================================================
;  DOND (Deal or No Deal)
;  Version 0.18.3 BETA
;  Written by: xDaeMoN
;  Email: xdaemon@xdaemon.us
;  
;================================================

;############ EVENTS #############

On *:LOAD: dond.settings 1

ON *:START: { 
  if ( !$hget($_table) ) hmake $_table 10
  if ( !$hget($_players) ) hmake $_players 10
  if ( $isfile($_data) ) hload $_table $_data
  if ( $isfile($_playdata) ) hload $_players $_playdata
  dond.settings
}

On *:EXIT: dond.save
On *:DISCONNECT: dond.save

On *!:NICK: {
  if ( !$readini($_ini,config,enable) ) return
  if ( $hget($_players,$+($network,:,$dondchan,:,$nick)) ) { 
    hdel $_players $+($network,:,$dondchan,:,$nick)
    hadd $_players $+($network,:,$dondchan,:,$newnick) 1
  }
  elseif ( $nick == %dond.player ) set %dond.player $newnick 
}

On *!:QUIT: { 
  if ( !$readini($_ini,config,enable) ) return
  if ( $hget($_players,$+($network,:,$dondchan,:,$nick)) ) hdel $_players $+($network,:,$dondchan,:,$nick)
  elseif ( $nick == %dond.player ) {
    unset %dond.player 
    msg $dondchan 10 $+ $nick just quitted. A new player will be picked shortly...
    .timerdond.rpick 1 2 dond.rpick $network $dondchan new
  }
}
On *!:KICK:$($dondchan): {
  if ( !$readini($_ini,config,enable) ) return
  if ( $hget($_players,$+($network,:,#,:,$knick)) ) hdel $_players $+($network,:,#,:,$knick)
  elseif ( $knick == %dond.player ) {
    unset %dond.player 
    msg $dondchan 10 $+ $nick was kicked. A new player will be picked shortly...
    .timerdond.rpick 1 2 dond.rpick $network $chan new
  }
}
On *!:PART:$($dondchan): { 
  if ( !$readini($_ini,config,enable) ) return
  if ( $hget($_players,$+($network,:,#,:,$nick)) ) hdel $_players $+($network,:,#,:,$nick)
  elseif ( $nick == %dond.player ) {
    unset %dond.player 
    msg $dondchan 10 $+ $nick just left the channel. A new player will be picked shortly...
    .timerdond.rpick 1 2 dond.rpick $network $chan new
  }
}

On !*:JOIN:$($dondchan): {
  $+(.timerdondjoinmsg,$cid,$chan,$nick) 1 2 .notice $nick Welcome to $chan $+ , $nick $+ ! $dond.logo v $+ $dond.version is $iif($readini($_ini,config,enable),10ON. Type 03!dond to start the game.,04OFF.)
}

On *:TEXT:!*:$($dondchan): {
  if ( !$readini($_ini,config,enable) ) return
  if ( $istok(!dond !start,$1,32) ) {
    if ( !%dond.status ) {
      if ( !%dond.start ) {
        dond.start $network $chan
      }
      else msg $chan The game is about to start in %dond.start secs. Type 3!join now.
    }
    else {
      if ( %dond.player == $nick ) msg $chan 07You are already playing the game!
      elseif ( %dond.player ) msg $chan 12Please wait after07 %dond.player 12finishes the game.
    }
  }
  elseif ( $1 == !stop ) && ( $nick isop $chan ) dond.end $nick
  elseif ( $1 == !pass ) && ( %dond.player == $nick ) {
    unset %dond.player
    msg $chan 10 $+ $nick has passed playing the game. 12A new player will be picked shortly...
    if ( $me isop $chan ) mode $chan -v $nick
    .timerdond.* off
    .timerdond.rpick 1 2 dond.rpick $network $chan new
  }
  elseif ( $1 == !stats ) {
    var %n = $iif($2,$2,$nick)
    msg $chan $dond.logo stats for12 %n $+ :03 $comma($iif($hget($_table,$+($network,:,$chan,:,%n)),$v1,0)) Total Points
  }
  elseif ( $1 == !join ) {
    if ( %dond.start ) || ( %dond.status == playing ) {
      if ( !$hget($_players,$+($network,:,$chan,:,$nick)) ) { 
        hadd -m $_players $+($network,:,$chan,:,$nick) 1
        msg $chan Thank you for joining,10 $nick $+ . Player will be randomly picked $iif(%dond.start,in07 %dond.start secs.,after10 %dond.player finishes the game.)
      }
      else msg $chan You already joined the game. Please wait for the game to start.
    }
  }
  elseif ( $1 == !confirm ) {
    if ( %dond.status == confirm ) && ( %dond.player.temp == $nick ) { 
      set %dond.status playing
      .timerdond.noconfirm off
      set %dond.player $nick
      unset %dond.player.temp
      msg $chan GOOD! Then let's play $dond.logo $+ !
      if ( $me isop $chan ) && ( $readini($_ini,config,avplayer) ) mode $chan +v $nick
      ;hadd -m $_prevplayers $+($network,:,$chan,:,$nick)
      dond.createboxes
      .timerdond.chooseanybox 1 2  msg $chan There are 26 boxes. Choose any box (from 1 to 26) so we can start playing. Type 3!choose <number>. You have04 $dond.time(randomchoosebox) secs or I will randomly select a box for you. 
      .timerdond.random.choose 1 $calc($dond.time(randomchoosebox) + 2) dond.randomchoosebox
      set %dond.level 0
    }
  }
  elseif ( $istok(!deal !nodeal,$1,32) ) && ( %dond.player == $nick ) && ( %dond.answerdond ) {
    if ( $timer(dond.autoaccept) ) .timerdond.autoaccept off
    if ( $1 == !deal ) {
      unset %dond.player
      tokenize 32 $hget($_table,$+($network,:,$chan,:,$nick))
      hadd -m $_table $+($network,:,$chan,:,$nick) $calc($1 + %dond.bankerdeal) $2 $3
      msg $chan You have accepted the Banker's offer. You get10 $comma(%dond.bankerdeal) points. Your total points is now03 $comma($hget($_table,$+($network,:,$chan,:,$nick))) $+ . Thank you for playing.
      if ( $me isop $chan ) mode $chan -v $nick     
      .timerdond.rpick 1 2 dond.rpick $network $chan new
    }
    else {
      msg $chan You declined the Banker's offer. Let's continue playing!
      inc %dond.level
      var %d = $dond.casesperlevel
      msg $chan Now, $iif( %dond.level == 8,choose from the last box $+(09,$chr(44),01) $+ $gettok(%dond.boxwdamts,1,58) $+  and your chosen box $+(09,$chr(44),01) $+ $gettok(%dond.chosenbox,1,58) $+ , you have to eliminate04 %d boxes.) Type 03!choose $str($+(<number>,$chr(32)),%d) to eliminate the boxes. You have07 $dond.time(timelimit) secs to respond.
      .timerdond.timelimit 1 $dond.time(timelimit) dond.timelimit $network $chan %dond.player
    }
    unset %dond.answerdond %dond.pickednum
  }
  elseif ( $1 == !choose ) {
    if ( %dond.player == $nick ) {
      dond.choose $nick $network $chan $2-
    }
  }
  elseif ( $1 == !commands ) msg $chan $dond.logo commands: !dond !join !confirm !deal !nodeal !stats !pass !stop !top10
  elseif ( $1 == !top10 ) dond.top $network $chan
}

;############ ALIASES #############

alias -l dondchan return $readini($_ini,config,channel)
alias dond.version return 0.18 BETA
alias -l _table return dond.scores
alias -l _players return dond.players
alias -l _prevplayers return dond.prevplayers
alias -l _playdata return $qt($scriptdirdondplayers.dat)
alias -l _data return $qt($scriptdirdondscores.dat)
alias -l _ini return $qt($scriptdirdond.ini)
alias -l dond.logo return 01,08DEALor08,01NODEAL

alias -l dond.rpick {
  if ( $3 == new ) msg $dondchan 12Let's continue the game. Picking a random player now....
  if ( $dond.players($1,$2) ) {
    var %n = $dond.players($1,$2).rand
    set %dond.player.temp $gettok(%n,3,58)
    hdel $_players %n
    .timerdond.newplayer 1 5 msg $dondchan The new player is ->07 %dond.player.temp <- Please type 03!confirm within04 $dond.time(confirmtime) secs, to confirm that you want to play.
    set %dond.status confirm
    .timerdond.noconfirm 1 $dond.time(confirmtime) dond.noconfirm %dond.player.temp %n
  }
  else {
    msg $dondchan 07Seems like the players are inactive.
    dond.end System Console Auto
  }
}

alias -l dond.noconfirm {
  msg $dondchan 10 $+ $1 did not confirm. Too bad, you lose your chance to play. We will pick another player...
  unset %dond.player.temp
  tokenize 58 $2
  dond.rpick $1 $2
}

alias dond.createboxes {
  unset %dond.boxwdamts
  var %amt = .1 1 5 10 25 50 75 100 200 300 400 500 750 1000 5000 10000 25000 50000 75000 100000 200000 300000 400000 500000 750000 1000000
  var %b = 26, %g
  while %b {
    %g = $gettok(%amt,$r(1,$numtok(%amt,32)),32)
    set %dond.boxwdamts $+(%b,:,%g) %dond.boxwdamts
    %amt = $remtok(%amt,%g,1,32)
    dec %b
  }
}

alias -l dond.getboxes {
  if ( %dond.boxwdamts ) {
    var %n = $numtok($v1,32), %o
    while %n {
      tokenize 58 $gettok(%dond.boxwdamts,%n,32)
      %o = 09,01 $+ $iif($1 isnum 1-9,$+(01,009,$1),$1) $+  %o
      dec %n
    }
    return %o
  }
}

alias -l dond.getamts {
  if ( %dond.boxwdamts ) {
    var %n = $numtok($v1,32), %o, %p , %o2
    while %n {
      tokenize 58 $gettok(%dond.boxwdamts,%n,32)
      %o = $2 %o
      dec %n
    }
    %o = $addtok(%o,$gettok(%dond.chosenbox,2,58),32)
    %o = $sorttok(%o,32,n)
    %p = $numtok(%o,32)
    while %p {
      %o2 = 08,01 $+ $comma($gettok(%o,%p,32)) $+  %o2
      dec %p
    }
    return %o2
  }
}

alias -l dond.bankerdeal {
  if ( %dond.boxwdamts ) {
    var %n = $numtok($v1,32), %o, %p = %n, %t = $1 * 2
    while %n {
      tokenize 58 $gettok(%dond.boxwdamts,%n,32)
      inc %o $2
      dec %n
    }
    ;inc %o $calc($gettok(%dond.chosenbox,2,58) * .25)
    inc %o $gettok(%dond.chosenbox,2,58)
    set %dond.bankerdeal $round($calc(%o / %p * %t / 10),2)
    return %dond.bankerdeal
    ; return $calc(%o / 10)
  }
}

alias -l dond.getboxnum return $wildtok(%dond.boxwdamts,$iif($1 isnum 1-9,$remove($1,0),$1) $+ :*,1,32)

alias -l dond.removebox {
  var %c = $dond.getboxnum($1)
  if ( !%dond.chosenbox ) set %dond.chosenbox %c
  set %dond.boxwdamts $remtok(%dond.boxwdamts,%c,1,32)
}

alias -l dond.casesperlevel {
  var %dond.cpl = 6 5 4 3 3 2 1
  set %dond.casesperlevel $gettok(%dond.cpl,%dond.level,32)
  return %dond.casesperlevel
}

alias -l dond.randomchoosebox {
  var %d = %dond.boxwdamts, %c = $iif(%dond.casesperlevel,$v1,1), %r, %o
  while %c {
    %r = $gettok(%d,$r(1,$numtok(%d,32)),32)
    %d = $remtok(%d,%r,1,32)
    %o = $addtok(%o,$gettok(%r,1,58),32)
    dec %c
  }
  echo -a ** %o
  dond.choose dond.random a a %o
}

alias -l dond.start {
  var %os = $dond.time(onstart)
  set %dond.status 1
  msg $dondchan It's time for another game of $dond.logo $+ ! For those who wants to play, type 03!join to join the game. $& 
    The player will be randomly picked from those who joined. 4You have %os seconds to join.
  set -z %dond.start %os
  .timerdond.rpick 1 %os dond.rpick $1-
}

alias -l dond.end {
  if ( %dond.status ) {
    .timerdond.* off
    msg $dondchan $dond.logo 04has been $iif($3,$+($3,-)) $+ stopped by07 $iif($1,$1-2,System Console) $+ . Type03 !dond to start another game.
    unset %dond.*
    if ( $hget($_players) ) hfree $_players
  }
}

alias -l dond.choose {
  if ( %dond.level == 0 ) {
    if ( $4 isnum 1-26 ) {
      .timerdond.* off
      inc %dond.level
      var %cpl = $dond.casesperlevel
      msg $dondchan $iif(dond.random == $1,A Random box has been selected for you $+ :,You have chosen Box) 10 $+ $chr(35) $+ $4 
      dond.removebox $4
      msg $dondchan Here are the Boxes left: $dond.getboxes
      .timerdond.eliminate 1 2 msg $dondchan Now, you have to eliminate %cpl boxes. Type 3!choose $str($+(<number>,$chr(32)),%cpl) to eliminate the boxes. You have07 $dond.time(timelimit) secs to respond.
      .timerdond.timelimit 1 $calc($dond.time(timelimit) + 2) dond.timelimit $2 $3 %dond.player
    }
    else msg $dondchan %dond.player $+ : 12There are only 0426 12boxes.
  }
  elseif ( %dond.level isnum 1-7 ) {
    if ( $4 ) {
      if ( $timer(dond.timelimit) ) .timerdond.timelimit off
      var %d = $dond.casesperlevel, %net = $2, %ch = $3, %nn, %nb, %ae
      if ( !%dond.pickednum ) set %dond.pickednum 0
      if ( %dond.pickednum < %dond.casesperlevel ) {
        var %w = 1, %n, %f = $4-, %eb
        while ( %dond.pickednum < %dond.casesperlevel ) && $gettok(%f,%w,32) {
          %n = $v1
          if ( $dond.getboxnum(%n) ) { 
            tokenize 58 $v1
            %eb = $addtok(%eb,12 $+ $chr(35) $+ $1 10 $+ $comma($2) $+ ,44)
            dond.removebox %n
            inc %dond.pickednum
          }
          elseif ( %n !isnum ) %nn = $addtok(%nn,12 $+ %n $+ ,44)
          elseif ( %n == $gettok(%dond.chosenbox,1,58) ) msg $dondchan Box12 $chr(35) $+ %n is already your chosen box.
          elseif ( %n !isnum 1-26 ) %nb = $addtok(%nb,12 $+ %n $+ ,44)
          else %ae = $addtok(%ae,12 $+ %n $+ ,44)
          inc %w
        }
        if ( %nn ) msg $dondchan %nn $iif($numtok(%nn,44) > 1,are,is) not a number.
        if ( %nb ) msg $dondchan There $iif($numtok(%nb,44) > 1,are,is) no Box $chr(35) $+ $iif($numtok(%nb,44) > 1,s) %nb
        if ( %ae ) msg $dondchan You have already eliminated Box $chr(35) $+ $iif($numtok(%ae,44) > 1,s) %ae
        if ( %eb ) msg $dondchan You have eliminated07 %dond.pickednum of12 %dond.casesperlevel Boxe(s): %eb
        if ( %dond.pickednum < %dond.casesperlevel ) { 
          .timerdond.pickednum 1 3 msg $dondchan 04 $+ $calc(%dond.casesperlevel - %dond.pickednum) more to eliminate.
          .timerdond.timelimit 1 $calc($dond.time(timelimit) + 3) dond.timelimit %net %ch %dond.player
        }
        else {
          .timerdond.getboxes1 1 1 msg $dondchan Here's the rest of the boxes: $!dond.getboxes
          .timerdond.getamts1 1 2 msg $dondchan Here's the remaining amounts: $!dond.getamts
          .timerbanker1 1 5 msg $dondchan 04! B A N K E R !        
          .timerbanker2 1 6 msg $dondchan The Banker's offer is:10 $comma($dond.bankerdeal(2))
          .timerdond.msg.dond 1 7 $({, ) msg $dondchan To accept the offer, type 12!deal. If you don't accept, type 04!nodeal. You have07 $dond.time(autoaccept) secs to respond. $(|, ) set % $+ dond.answerdond 1 $(}, )
          .timerdond.autoaccept 1 $calc($dond.time(autoaccept) + 7) dond.autoacceptoffer %net %ch %dond.player
        }
      }
      else msg $dondchan You have already eliminated %dond.casesperlevel boxes at this time.
    }
    else msg $dondchan Choose %dond.casesperlevel boxes to elimnate from the remaining ones. Type 3!choose $str($+(<number>,$chr(32)),%dond.casesperlevel) $+ .
  }
  elseif ( %dond.level == 8 ) {
    if ( $istok($gettok(%dond.boxwdamts,1,58) $gettok(%dond.chosenbox,1,58),$4,32) ) {
      if ( $timer(dond.timelimit) ) .timerdond.timelimit off
      var %n = $2
      tokenize 58 $iif($4 $+ :* iswm %dond.boxwdamts,$v2,%dond.chosenbox)
      hinc -m $_table $+(%n,:,$dondchan,:,%dond.player) $2
      msg $dondchan Your chose Box12 $chr(35) $+ $1 with10 $comma($2) and will be added to your total points, which is now03 $comma($hget($_table,$+(%n,:,$dondchan,:,%dond.player))) $+ . Thank you for Playing.
      if ( $me isop $dondchan ) mode $dondchan -v %dond.player       
      unset %dond.player
      .timerdond.rpick 1 2 dond.rpick %n $dondchan new
    }
    else msg $dondchan 10 $+ $4 $+  is neither of your chosen box 09,01 $+ $gettok(%dond.chosenbox,1,58) $+  nor the box left 09,01 $+ $gettok(%dond.boxwdamts,1,58) $+ . You have04 $timer(dond.timelimit).secs secs left to respond.
  }
}

alias -l comma {
  ;By Fiberoptics
  var %a, %b = $regsub($ticks,$1,/\G([+-]?\d+?)(?=(?:\d{3})++(?=\.\d++$|$))/g,\1 $+ $chr(44),%a)
  return %a
}

alias -l dond.save {
  hsave -o $_table $_data
  hsave -o $_players $_playdata
}

alias -l dond.players { 
  var %n = $hfind($_players,$+($1,:,$2,:*),0,w)
  if ( $prop == rand ) return $hfind($_players,$+($1,:,$2,:*),$r(1,%n),w)
  return %n
}

alias -l dond.timelimit {
  unset %dond.player
  msg $dondchan  $+ $3 12seems to be inactive. We will now select a new player...
  if ( $me isop $dondchan ) mode $v2 -v $3
  .timerdond.rpick 1 2 dond.rpick $1 $2
}

alias -l dond.autoacceptoffer {
  hinc -m $_table $+($1,:,$2,:,$3) %dond.bankerdeal
  msg $dondchan 12The Banker's offer has been auto-accepted.10 $comma(%dond.bankerdeal) 12will be added to your points. Your new total points:03 $comma($hget($_table,$+($1,:,$2,:,$3))) 
  dond.timelimit $1-
}

alias -l dond.time return $readini($_ini,config,$1)

alias -l dond.settings {
  if ( !$readini($_ini,config,avplayer) ) wini config avplayer 1
  if ( !$readini($_ini,config,onstart) ) wini config onstart 30
  if ( !$readini($_ini,config,timelimit) ) wini config timelimit 45
  if ( !$readini($_ini,config,randomchoosebox) ) wini config randomchoosebox 45
  if ( !$readini($_ini,config,autoaccept) ) wini config autoaccept 45
  if ( $1 ) echo $colour(info) -a ** $dond.logo v $+ $dond.version - Default Settings has been set.
}

alias -l dond.setchan { 
  writeini -n $_ini config channel $1
  unset %dond.*
}

alias -l wini writeini -n $_ini $1-

alias -l dond.top {
  var %h = $hfind(dond.scores,$+($1,:,$2,:*),0,w), %w = @dond.top, %i
  window -hn %w
  clear %w
  while %h {
    %i = $hfind(dond.scores,$+($1,:,$2,:*),%h,w)
    aline %w $gettok(%i,3,58) $hget(dond.scores,%i)
    dec %h
  }
  filter -cteuww 2 32 %w %w
  var %l = $line(%w,0), %a = 1, %o
  while %a <= 10 {
    %o = $addtok(%o,$+(08,$chr(44),01) $+ $chr(35) $+ %a $+ $+(01,$chr(44),15) $iif($line(%w,%a),$gettok($v1,1,32) $comma($gettok($v1,2,32)),*),32) 
    inc %a
  }
  msg $2 $dond.logo TOP10: %o
}

;############ MENU #############

menu * {
  DOND v $+ $dond.version
  .$style(1) $iif($readini($_ini,config,enable),Enabled,Disabled)
  ..$iif($readini($_ini,config,enable),Disable,Enable) game: { 
    wini config enable $iif($readini($_ini,config,enable),0,1)
    if ( !$readini($_ini,config,enable) ) && ( %dond.status ) dond.end System Console
  }
  .-
  .$iif( $readini($_ini,config,enable), Status)
  ..$iif( !%dond.status, Start, Stop) DoND:  { 
    if ( $me ison $dondchan ) $iif( !%dond.status , dond.start $network $dondchan, dond.end System Console) 
    else echo 04 -a $dond.logo Error: I am not on $dondchan $+ .
  }
  .-
  .Settings
  ..Channel ( $+ $dondchan $+ ) 
  ...$iif(( $chan ) && ( $chan != $dondchan ),Set Current $chr(40) $+ $chan $+ $chr(41)) : dond.setchan $chan
  ...Set Other? : dond.setchan #$$?="Enter the Channel name to play DEAL or NODEAL"
  ..-
  ..$iif($readini($_ini,config,avplayer),$style(1)) Auto voice Player
  ...$iif( !$readini($_ini,config,avplayer), Enable, Disable) :  wini config avplayer $iif($readini($_ini,config,avplayer),0,1)
  ..-
  ..Time 
  ...On Start ( $+ $readini($_ini,config,onstart) $+ ) : wini config onstart $$?="Enter time when starting the game (seconds)"
  ...Time to Confirm ( $+ $readini($_ini,config,confirmtime) $+ ) : wini config confirmtime $$?="Enter time for user to confirm before starting the game (seconds)"
  ...Time Limit ( $+ $readini($_ini,config,timelimit) $+ ) : wini config timelimit $$?="Enter time limit for user to respond (seconds)"
  ...Random 1st box ( $+ $readini($_ini,config,randomchoosebox) $+ ) : wini config randomchoosebox $$?="Enter time limit when choosing the 1st box randomly (seconds)" 
  ...Auto Accept Offer ( $+ $readini($_ini,config,autoaccept) $+ ) : wini config autoaccept $$?="Enter time limit for user to respond before offer is auto-accepted (seconds)" 
  ..-
  ..Scores
  ...Save {
    var %w =  $input(Do you really want to set the default settings?,uy,Deal or No Deal)
    if ( $! ) {
      hsave -o $_table $_data
      echo $colour(info) -a $dond.logo v $+ $dond.version - Scores has been saved!
    }
  }
  ...Reset {
    var %w =  $input(Do you really want to reset All the scores?,uy,Deal or No Deal - Confirm Reset)
    if ( $! ) {
      hfree $_table
      hmake $_table 10
    }
  }
  ..-
  ..Reset : {
    var %w =  $input(Do you really want to set the default settings?,uy,Deal or No Deal - Confirm Reset)
    if ( $! ) {
      dond.settings 1
    }
  }
}

;############ EOF #############

Comments

(70) RSS

Go to Bottom

Mylesmart

Comments: 17

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 12, 2007 11:46 am

Its good =). There are a few things however, mabey you hsould have it be able to set multiple channels as enabled so you don't have to keep resetting the channel. And also it makes me choose 3 cases twice. But other than that it is pretty good

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 12, 2007 12:01 pm

Thanks. =) Multiple channels will be avaible next time. I'm not quite sure when you said "it makes me choose 3 cases twice". Can you paste an example. You can choose any available boxes/cases, but if the boxes where already chosen before, then it would tell you that.

Mylesmart

Comments: 17

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 12, 2007 12:56 pm

What i mean is when in the normal game on tv you choose 6 cases, 5 cases, 4 cases, 3 cases, 2 cases, 1 case, then so on until the game ends.However in yours i choose 6 cases, 5 cases, 4 cases, 3 cases, 3 cases, 2 cases, then 1 case and the game is over after i choose nodeal or deal. I don't know if you did that on purpose or not but just something i saw.

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 12, 2007 1:12 pm

Oh, now I know what you mean. Yes, I did that in purpose. I'll also change it so that on the last 2 boxes (which includes the chosen box before), you can choose if you want to take the last box or your chosen box.

|MELIORITE|

Comments: 144

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 13, 2007 8:57 pm

Nice work :)

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 13, 2007 9:59 pm

Thanks =)

BackoffJackson

Comments: 56

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 14, 2007 2:54 pm

http://fudgeman.org/files/Code/mIRC%20Scripts/Deal%20or%20No%20Deal%20Game%20Bot.mrc

^ Someone elses.

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 14, 2007 3:26 pm

Ok...so?

Lindrian

Comments: 755

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 14, 2007 3:49 pm

I think he tries to say... you ripped it?

Which I dont think you have, as the coding is different.

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 14, 2007 4:05 pm

I was going to say that :P And yep, the coding is way different from the script that he posted.

BackoffJackson

Comments: 56

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 15, 2007 2:06 pm

I wouldn't find any scripts xDaeMoN claimed to have made be ripped.
I was simply saying that I've seen a DoND script before and wanted to post it so you may further improve your coding, you know, to give you ideas.

<3 This script.

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 15, 2007 2:36 pm

Ah, you could have said that in your previous comment so there's no misunderstanding. :)

Bouncer

Comments: 120

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 26, 2007 10:36 am

I put it in my bot and it excess flooded out. Any way to have the game save the current spot until it rejoins the specified channel so you can pick up where you left off?

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 26, 2007 11:21 am

Do you know what was it doing before it excess flooded? I haven't had that happen yet. I'll see what I can do about saving the current play.

Bouncer

Comments: 120

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 26, 2007 6:45 pm

It seems that my logs did not save themselves, but I was in the middle of playing the game. The way I was doing it was I would name 5 cases at once on one round, then on the next name four cases one at a time. Maybe I flooded it out because it had to message the channel so quickly, and so many times, I'm not sure. But an auto save function would be great.

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 28, 2007 10:41 am

why do you need multiple players when deal or no deal is a one player game?

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 28, 2007 10:46 am

i am really confused on how to start the game. When i type !dond and someone else types !join, it says players are inactive, game stopped.
<Dealer> Seems like the players are inactive.
<Dealer> DEALorNODEAL has been Auto-stopped by System Console. Type !dond to start another game.

How do i get it to start???

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 28, 2007 11:30 am

What I did here is anybody can join the game then the script will randomly choose a player from those who joined. Then when that selected player finished, the script will choose another random player from the list. If the player is inactive, it will choose another one then so on.

When start the game, it will give you instructions on how to join to be in the list then confirm that you want to play when you get selected.

To start: !dond
To join: !join
When you get selected: !confirm

The bot will give you instructions on what to type as you play along.

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 29, 2007 11:22 am

Dude, i cant even start the game! Alright, the only ppl in the channel are me, and my bot. The bot has the script. I type !dond. it says

It's time for another game of DEALorNODEAL! For those who wants to play, type !join to join the game. The player will be randomly picked from those who joined. You have 30 seconds to join.

I type !join

Thank you for joining, mountaindew. Player will be randomly picked in 4 secs.

Seems like the players are inactive.
<Dealer> DEALorNODEAL has been Auto-stopped by System Console. Type !dond to start another game.

What does it mean, im inactive? All i wanna do is play just me, and it wont start. I dont know if it matters, but i use vIRC and my bot uses mIRC. So idk what to do...It doesnt even pick anyone cuz it says theyre all inactive. What do i do to not be inactive?

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 29, 2007 12:41 pm

I just tried vIRC and my bot with mIRC and it seems to be working fine.

*** TESTC (~vircuser@XX.XXX.XX.XX) has joined #dondtest
*** Animatrix (~IDENT2@XX.XXX.XX.XX) has joined #dondtest
<Animatrix> It's time for another game of DEALorNODEAL! For those who wants to play, type !join to join the game. The player will be randomly picked from those who joined. You have 30 seconds to join.
[TESTC] !join
<Animatrix> Thank you for joining, TESTC. Player will be randomly picked in 27 secs.
<Animatrix> The new player is -> TESTC <- Please type !confirm within secs, to confirm that you want to play.
[TESTC] !confirm
<Animatrix> GOOD! Then let's play DEALorNODEAL!
*** Mode change [+v TESTC] on #dondtest by Animatrix
<Animatrix> There are 26 boxes. Choose any box (from 1 to 26) so we can start playing. Type !choose <number>. You have 45 secs or I will randomly select for you.

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 29, 2007 12:48 pm

It still doesnt work...I went to my mIRC and right clicked the channel, dond, status, start dond. this is what happens.

*** mountaindew (~mountaind@xxx-xxx-xxx-xxx) has joined #dondtest
[mountaindew] !op
*** Mode change [+o mountaindew] on #dondtest by Dealer
(right click dond start)
<Dealer> It's time for another game of DEALorNODEAL! For those who wants to play, type !join to join the game. The player will be randomly picked from those who joined. You have 30 seconds to join.
[mountaindew] !join
<Dealer> Thank you for joining, mountaindew. Player will be randomly picked in 26 secs.
<Dealer> Seems like the players are inactive.
<Dealer> DEALorNODEAL has been Auto-stopped by System Console. Type !dond to start another game.

I dont know if this happens because im the only player, or what. Why does it say that i am inactive?

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 29, 2007 1:00 pm

I tested mine with multiple players joining & with only a single player and works fine. Did you try the script in a clean mIRC? What version of mIRC are you using?

It will say "Seems like the players are inactive." when there are no players who joined the game. It seems like it didn't add you to the list even though it said that you joined the game. Maybe there is another script that maybe a conflict to this. So far, I can't think of anything else.

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jun 29, 2007 5:15 pm

i use mirc 6.21. I think its wierd that it says that i did join, yet im not at the same time. I dont have any !confirm !join !dond triggers, so idk whats wrong. Is there a way to have a scripted mirc and a clean mirc at the same time, like in a new window?

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jul 23, 2007 2:53 pm

Minor update. You are now able to choose from the last box and your chosen box. I'll update it again when I get time to do it.

airfreshner

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jul 25, 2007 6:23 am

This is a very nice scipt ive been wanting this script for ages and was planning on doing it my self but now its done. Great job xDaeMoN keep up the hard work. P.S found this error * /timerdond.noconfirm: invalid parameters (line 163, script3.mrc)

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jul 25, 2007 10:50 am

Thanks airfreshner. I haven't got that error yet. The only thing I can think of is that there is value for the "confirm time". Try checking the settings on the time to confirm.

If there is a number value and it's still doing it, let me know what is happening or paste here a sample log when you got the error.

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jul 25, 2007 4:54 pm

UPDATE
- Added !top10, !commands
- fixed minor bug

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Aug 15, 2007 3:45 pm

had to take !start out cuz everyone thought !start started my trivia :D

good job, very nice snippet

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Aug 15, 2007 3:47 pm

I know, some use !start too. I might remove that as well so it won't interfere with others. Glad you liked it. :)

spugalo

Comments: 4

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 15, 2007 2:40 pm

I can't get it to work :( When I click to enable it, I get the message
* /writeini: insufficient parameters (line 400, dond)
Have I missed something? Any help would be appreciated.
Thanks :)

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 15, 2007 5:59 pm

What version of mIRC are you using? I've tested it with 6.21 and works fine. I assume that it would work on 6.3 too, but haven't tested it.

spugalo

Comments: 4

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 19, 2007 4:23 am

Thanks for the response. I'm using 6.17.

spugalo

Comments: 4

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 19, 2007 4:25 am

sorry, 6.16 (didn't know how to edit my previous post)

Gummo

Comments: 150

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 19, 2007 4:56 am

That might have something to do with the fact that you can't edit posts.

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 19, 2007 9:08 am

@ spugalo, use at least the 6.21 version.

spugalo

Comments: 4

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 19, 2007 1:17 pm

Thanks xDaeMoN.

airfreshner

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 22, 2007 4:35 pm

* /timerdond.noconfirm: invalid parameters (line 165, DealOrNoDeal.mrc)
<DOND> The new player is -> kestral <- Please type !confirm within secs, to confirm that you want to play.

2 Errors. As stated with the timer and it says within secs does not give how many secs.

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 22, 2007 10:44 pm

That means the settings are incomplete. I have stated on my notes above to check the settings if all are complete before starting the script.

airfreshner

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Oct 27, 2007 6:28 pm

Cheers xDarMoN. One more problem every time i quit the bot I get an error message. When im at the PC its on next Ill paste the error message.

Nice script tho love it :)

classic fox

Comments: 4

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Nov 4, 2007 7:22 pm

The script is great!

I have an idea. What about something like "!choose random" to choose a random box and "!choose allrandom" to randomly choose 6, 5, 4, etc. boxes, depending on the stage you're at. :D That would be pretty nice.

But as I said, the script is great. Good work. :)

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Nov 4, 2007 10:45 pm

Glad that you like it classic fox and thanks for the nice suggestion. I'll add it when I get the time. =)

Korvin

Comments: 238

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Nov 5, 2007 12:23 am

you should make a dialog for the settings, and make them have a default setting =}

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Nov 5, 2007 1:02 am

@ Korvin, it does set the default settings when you load this & I've said this on the author's notes ;). Since this is just a snippet & a beta version, a dialog is not really necessary and there are only a few things to configure which is enough for a simple menu. When I would submit it as an addon, then I would provide a dialog for the settings =). Thanks for the suggestion though.

Comments: 1,400

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Dec 23, 2007 5:05 am

Ok i just found this within my test scripts section from a while back.Well it won't work cause im not on a network im on a server an i tryed to edit it like i did uno al i did there was changed $network to $server an it works fine.But seems in this case it wont work that easily and its hard to stare down code that i can hardly make sense out of to get it to work.Ok so it will trigger the game !dond then you can !join then after that im not sure if you have to have more then 2 player i tryed 3 players to !join an it just counts down an auto stops.it wont go past that part so i have no idea if it will work further.It's nicely scripted i just cant get it to work for me maybe there is something simple i dunno if theres any comments on anything to try i'd appreciate them or if any oen else has had a similar issue.Ty `-.-�

Comments: 1,400

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Dec 23, 2007 5:47 am

Ok i went over the code again with a fine tooth comb with out a doubt i missed one $network -.- so i changed it to $server an then went over the entire code again to make sure i didn't miss any an guess what she works like a champ.Good work an i gave ya a 10 cause its pimp.`-.-�

Legend

Comments: 1

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Dec 25, 2007 11:10 pm

Hello i have also tried this code on my own server and i cannot seem to get it to work I run paperIRC8.0 as my msn chatroom server and it creates %# in front of the names of the channel that you want it to connect to Any ideas on how to add the % code cause i have no idea on how to add it I have read the ini file it creates and it says it in there %#the-devils-dungeon but it just doesnt have it sitting in the brackets next to channel it just displays channel() could anyone help me out i have seen this game being played in a chatroom on the phreik chatroom server and i liked it very much im using mirc 6.17 if i need to upgrade to a higher mirc i can try that

BourneIdent187

Comments: 2

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 4, 2008 8:48 pm

* /writeini: insufficient parameters (line 400, DorNd.mrc)
any idea on why i get this when i try to enable

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 4, 2008 11:08 pm

@ EL, great that you were able to make it work. :-)

@ Legend, I haven't been on a MSN Chatroom. PM me the server you go to then I'll see what I can do. I can't guarantee that I can do it right away though.

@ BourneIdent187, try to make sure that all settings has been configured.

Comments: 1,400

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 5, 2008 12:11 am

Ya man got a channel on muh new server just for it lol ppl love it.And yeah i have to edit alot of scripts for chat space ahhh and another thing i should note: line 197 - %o = 09,01 $+ $iif($1 isnum 1-9,$+(01,009,$1),$1) $+ %o This reads as white on the java applet works fine on my mirc screen tho so any one that may use this on java change it to something like this goto line 197
%o = 4,01 $+ $iif($1 isnum 1-9,$+(1,04,0 $+ $1),$1) $+ %o I used red just cause.Yeah should have said this earlyer on alot of the msg to chan there are 0 infront of the color numerics any one using java plz delete them it wont show.Also edit the logo as well or you ll just end up with spaces where text is supposed to show on your java screen.Other then that i dont suggest tryin to edit this script with out messin it up.Also on teh on join notice when clients enter the chan i suggest adding them to change they colors to defualt settings so the bot can read the commands.Other then thats its a ace game.Thanks agian xDaeMoN.`-.-�

wtfdidido

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 11, 2008 7:37 pm

a very fun game, and great coding
my problem is i use SPCN chats(msn clone type). and have the code in my script, and i'm in on webchats also,
i went into code and tryed to change the $network to $server
i use mirc 6.21
mines not setting the room name in settings, i get channel ()
it does all the others correctly.
in the dond.ini it shows the correct room name %#roomnamehere
shows all the default times correctly
avplayer=1
enable=1
in script i get a echo
DEALorNODEAL Error: I am not on .
and does nothing
the onjoin message shows it is on
Welcome, DEAL or NO DEAL v0.18 BETA is ON . Type !dond to start the game.
i also seen it running in the Phreik chat room, and have been working on this for a whiles, i have recoded quite a few codes to work on old msn chat,spcn, and on phreiks...
i am stuck on this, any and all help will be highly appreciated

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 11, 2008 11:29 pm

@ wtfdidido, like my reply to Legend a few posts above, I havent tested this on MSN chatrooms. PM me a link to your server so I can make some tests. =)

wtfdidido

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 14, 2008 7:53 am

thanks xDaeMoN
i sent the P.M, hope i didnt confuse you on there
also in mean time, i'm still playing with the code, to see if i can figure out what needs changed.

wtfdidido

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 24, 2008 8:20 pm

alian64bit : !start
Sexxy_Guy : It's time for another game of DEAL or NO DEAL ! For those who want to play, type !join to join the game. The player will be randomly picked from those who joined. You have 60 seconds to join.
alian64bit : !join
Sexxy_Guy : Thank you for joining, alian64bit .A Player will be randomly picked in 53 secs.
Sexxy_Guy : Looks like the players are inactive.
Sexxy_Guy : DEAL or NO DEAL game has been Auto-stopped by System Console . Type !dond to start another game.

i got it to this point, but after i !join, i get this error, i removed the !start, as i also have it in trivia,and didn't want the conflict
i see some one else has/had the same problem, and wondered what they did to fix this problem....

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 25, 2008 2:29 pm

i used to have that problem also

jub369

Comments: 52

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 25, 2008 3:21 pm

one way is to run it by it self without any ether scripts on lol thats how i fixed it when i had that problem

xDaeMoN

Comments: 696

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 25, 2008 5:17 pm

Maybe the server you are on doesn't have a "Network" value which would make $network null.

Do "/echo -a $network", if it does not give you a value, then that's one factor which would make the script not work.

Quick solution: Change ALL $network to $server in the script. You can click "Find Text" on mIRC's scripts editor, enter "$network" on 'Find Text' then enter "$server" on 'Replace with' then click the button "Replace all". Make sure that the "Search all files in this section" is unchecked.

Hopefully, that would work for you. If not, let me know.

wtfdidido

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 25, 2008 5:56 pm

i did //echo -a $network
received back this
Sparkpea.Net
i did //echo -a $server
received this back
SPCCHATA03
seems like these are both ok...just to make sure i removed every one of them...i left the $chan in.
everything seems ok, just not showing the joins, to go past this part.....

wtfdidido

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 25, 2008 6:07 pm

one other item, i have every thing turned off, in script, other then this codeor removed, i did a search for commands that might conflict, none are loaded
im in room with the script and webchat nick only.
no other codes are loaded.. not getting any errors either
if it helps, im useing mirc, with a connection added(vincula).
i removed almost all the color codes, and changed it from
on *:input: to on *"text"
also changed it to :#: to work in any room
changed it to msg $chan, or msg $active(as needed) some were showing in status window, so i changed them to show in room...

wtfdidido

Comments: 9

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Jan 26, 2008 12:33 am

oops
for get the on input item, that was a different code :$

bourneident

Comments: 26

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Feb 27, 2008 10:46 am

works great almost perfect but there is a flaw using random player part you might want to make it so it picks random player at start but after that it puts all players up one after the other that way everyone gets a turn as it it half the people who join never get to play because the random

bourneident

Comments: 26

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Mar 1, 2008 3:10 am

forget last comment i see what you did now however maybe add some dialog allowing you to turn voicing on/off and reset scores also maybe have it auto reset scores when say they reach 100 million and when they win 1 mil needs a little something to spruce it up a little celebration of some sort plus maybe add a little mini conversation like in the show when howie calls the banker and makes little random pokes at the contestants and banker additude

Eugenio

Comments: 1,103

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Mar 11, 2008 5:43 pm

This is an amazing script but Mountaindew made himself look stoopid again lol :P

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Mar 11, 2008 5:56 pm

what?

Eugenio

Comments: 1,103

mIRC Snippet: DOND (Deal or No Deal) v0.18.3 BETA
Posted on Mar 11, 2008 6:00 pm

Quote:

thats what lol

mountaindew

Comments: 1,645

mIRC Snippet: DOND (Deal or