Countdown Timer

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	8.6
Scores Submitted	5
Date Added	May 19, 2007
Last Updated	May 20, 2007
Tags	countdown fun timer

Introduction

This allows people to set a date & time in the future, then be able to track how long until that date & time.
Required parameter got missed. Code has been repaired, and messages have been added/updated to make the code more flexible and understandable. Option to delete a tracking has been added. Note: The person using the !del command must have ops in at least one common channel.

Grab the Code

on *:text:!setdate*:*:{
  if !$ctime($2-) {
    .msg $nick Sorry, but I don't recognize the format used.
    .msg $nick Examples of recognized formats are:
    .msg $nick January 1 1970 00:00:00
    .msg $nick 3rd August 1987 3:46pm
    .msg $nick 21/4/72 1:30:37
    .msg $nick Wed 1998-3-27 21:16
  }
  elseif $ctime($2-) < $ctime {
    .msg $iif($chan,$v1,$nick) Sorry, but $2- has already passed
  }
  else {
    .hadd -m setdate  $ctime($2-) $2-
    .msg $iif($chan,$v1,$nick) Countdown timer $hget(setdate,0).item has been initiated.
  }
}
on *:text:!timeleft*:*:{
  if $2 == $null {
    .msg $iif($chan,$v1,$nick)  There are $hget(setdate,0).item countdown timings in progress.
    .msg $iif($chan,$v1,$nick) Please specify which timing you wish, or use 0 (zero) for all
  }
  elseif $2 == 0 {
    var %a = 1, %b = $hget(setdate,0).item
    while %a <= %b {
      var %setdate = $hget(setdate,%a).data, %settime = $hget(setdate,%a).item
      .timer 1 %a .msg $iif($chan,$v1,$nick) $iif(%settime < $ctime,%setdate passed $duration($calc($ctime - %settime)),Time left to %setdate is $duration($calc(%settime - $ctime)))
      inc %a
    }
  }
  else {
    if !$hget(setdate,$2).item {
      .msg $iif($chan,$v1,$nick) Sorry, no entry found for $2
    }
    elseif $hget(setdate,$2).item < $ctime {
      .msg $iif($chan,$v1,$nick) $hget(setdate,$2).data passed $duration($calc($ctime - $hget(setdate,$2).item))
    }
    else {
      .msg $iif($chan,$v1,$nick) Time left to $hget(setdate,$2).data is $duration($calc($hget(setdate,$2).item - $ctime))
    }
  }
}
on *:start:{
  if !$hget(setdate) { .hmake setdate 100 }
  if $exists(setdate.hsh) { .hload setdate setdate.hsh }
}
on *:exit:{
  .hsave -o setdate setdate.hsh
}
on *:disconnect:{
  .hsave -o setdate setdate.hsh
}
on *:text:!del*:*:{ 
  var %op = 0, %a = 1, %b = $comchan($nick,0) 
  while %a <= %b { 
    if $nick isop $comchan($nick,%a) { 
      inc %op 
    } 
    inc %a 
  } 
  if %op { 
    .msg $iif($chan,$v1,$nick) Time Left tracking for $hget(setdate,$2).data has been deleted.
    .hdel setdate $hget(setdate,$2).item 
  } 
  else { 
    .notice $nick Insufficient Access 
  } 
}

Comments

(4) RSS

Go to Bottom

|MELIORITE|

Comments: 144

mIRC Snippet: Countdown Timer
Posted on May 20, 2007 4:16 am

I really love this idea, this could be a lot of fun. The coding is of great quality... I have not tested its functionality yet, but your hash tables are always of the highest order.

CharltonJ

Comments: 37

mIRC Snippet: Countdown Timer
Posted on May 21, 2007 1:25 pm

very nice!!! i love it :D Good job RusselB :)))

Pangaea

Comments: 15

mIRC Snippet: Countdown Timer
Posted on Sep 6, 2007 12:42 pm

Great.. is there a way to make it msg the channel when the time is up.. or even better give 5, 4, 3, 2, 1.. 5 seconds before the time is up?

RusselB

Comments: 100

mIRC Snippet: Countdown Timer
Posted on Sep 28, 2007 9:16 pm

I'll see what I can do, Pangaea.

Countdown Timer

Introduction

Grab the Code

Comments

RusselB

My Snippet Tags

Contact

Friends (8)

Sponsors

		Sarnia, ON, Canada
Last seen: Oct 05, 2008 Profile Likes (1) Friends (8) Snippets (21) Images (2) Comments Received (203) Comments Submitted (100) Forum Posts (5436)