Autojoin - single click save channels

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	6.5
Scores Submitted	2
Date Added	Apr 26, 2007
Last Updated	Aug 09, 2007
Tags	autojoin channels mirc mutli network

Introduction

This code snippit is something i cooked up to manage the auto joining of channels on a network, most scripts i've seen need manual adding of the channels either in script or in a dialog, this script simply saves the channels on click.

When you load the snippit you need to alter some information mainly the identification section (see alias ps) and the specific network data.

Once it is initially set up, that is with the passwords, extra commands, and nicknames, you simply join the networks and channels you want and hit set in the menu on the tool bar. You can manually add or remove channels, but the 'set' is the easiest way. You can turn autojoin off for which it will prompt you to join or not join channels or networks.

Grab the Code

;Settings that aren't set anywhere else.

;This is the alias to identify yourself to the network chances are you already have one of these alias's if so simply replace the body of this with the command to run.
;Make sure you update this to be accurate.
alias ps {
  if ($server == irc.chat-addict.net) {
    ns identify password1
  }
  if ($network == SwiftIRC) {
    ns identify password2
  }
}

;This is an area to add extra on connect events, the example is to connect to channel '#'
alias aj.networkspec {

;syntax for a single/first network
  ;if ($network == imperial) {
  ;  join $chr(35)
  ;}
  ;syntax for an additional network performs
  ;elseif ($network == hashmark) {
  ;  mode $me +x
  ;}
}

;this is the actual on connect event, only alter what you understand
on 1:CONNECT: {

;this is the main nick, the nick which will be selected on connect
  set %mnick Killer_Hobbits

;this is the backup nick, what will be used if the other is taken
  set %anick Killer-Hobbits

;this is default realname
  set %realname Killer-Hobbits

;this is default ident/email
  set %emailaddr khobbits@khobbits.co.uk

;these just turn on some typical mirc options
  ial on
  notify on

;these are the modes set upon connect
  mode $me +iswk

mnick %mnick
  anick %anick
  if (%aj.on == 1) { .timer 1 4 aj.normjoin }
  elseif ($?!="Normal autojoin?" == $true) { .timer 1 4 aj.normjoin }
  elseif ($?!="Join channels on this network?" == $true) { .timer 1 4 aj.justjoin }
  else { .timer 1 4 aj.justid }

}

alias aj.on {
  set %aj.on 1
  set %aj.onsay On
}

alias aj.off {
  set %aj.on 0
  set %aj.onsay Off
}

alias aj.whichchans {
  if ($?="Add channel to auto join (eg. #pants).  Use 0 to disable/clear for this network." == 0) {
    unset $eval($+(%,aj.chans.,$1),1)
    set %aj.nets $remtok(%aj.nets,$1,1,59)
  }
  elseif ($! != $null) {
    set %aj.nets $addtok(%aj.nets,$1,59)
    if ($eval($+(%,aj.chans.,$1),2) != $null) {
      set $eval($+(%,aj.chans.,$1),1) $eval($+(%,aj.chans.,$1),2) $+ ; $+ $!
    }
    else {
      set $eval($+(%,aj.chans.,$1),1) $!
    }

}
}

alias aj.setwhichchans {
  var %i = 1
  while (%i <=  $chan(0)) {
    if (%chanlist != $null) {
      var %chanlist %chanlist $+ ; $+ $chan(%i)
    }
    else {
      var %chanlist $chan(%i)
    }
    inc %i
  }
  set %aj.nets $addtok(%aj.nets,$1,59)
  set $eval($+(%,aj.chans.,$1),1) %chanlist
}

menu menubar {
  Auto Join
  .Status - %aj.onsay
  ..On:/aj.on
  ..Off:/aj.off
  .-
  .Channel (click to add/remove)
  ..$submenu($aj.chan($1))
  ..-
  ..Set Channels ( $+ $network $+ ):/aj.setwhichchans $network
  ..Set Host/Email ( $+ $network $+ ):/set $+(%,aj.emailaddr.,$network) $$?="Enter Email Address"
}

alias aj.chan {
  if ($1 == begin) return -
  if (($numtok(%aj.nets,59) == 0) && ($1 == 1)) { return Add for $network $+ :aj.whichchans $network }
  while ($1 <= $numtok(%aj.nets,59)) {
    return $gettok(%aj.nets,$1,59) $+ - $eval($+(%,aj.chans.,$gettok(%aj.nets,$1,59)),2) $+ :aj.whichchans $gettok(%aj.nets,$1,59)
    if ($1 == end) return -
  }
}

alias jc {
  if ($eval($+(%,aj.chans.,$network),2) != $null) {
    join $replace($eval($+(%,aj.chans.,$network),2),;,$chr(44))
  }
}

alias aj.normjoin {
  aj.justjoin
  aj.joinnw
}

alias aj.justjoin {
  aj.justid
  aj.networkspec
  jc
}

alias aj.justid {
  ps
}

alias aj.runnet {
  var %i = 1
  while (%i <=  $scid(0)) {
    if ($eval($+(%,$1,.,$scon(%i).network),2) != $null) {
      scon %i $2-
    }
    inc %i
  }
}

alias aj.joinnw {
  var %i = 1
  var %aj.concheck %aj.nets
  while (%i <= $scon(0)) {
    if ($scon(%iserver).status == connecting) {
      echo -s Currently connecting, 4 sec delay.
      timer 1 4 aj.joinnw
      halt
    }
    if ($istok(%aj.concheck,$scon(%i).network,59) == $true) {
      set %aj.concheck $remtok(%aj.concheck,$scon(%i).network,1,59)
    }
    inc %i
  }
  var %i = 1
  while (%i <= $numtok(%aj.concheck,59)) {
    var %usem $iif($status != disconnected,-m)
    if ($($+(%,aj.emailaddr.,$gettok(%aj.concheck,%i,59)),2)) {
      server %usem $gettok(%aj.concheck,%i,59) -i %mnick %anick $v1 %realname
    }
    else {
      server %usem $gettok(%aj.concheck,%i,59) -i %mnick %anick %emailaddr %realanme
    }
    inc %i
  }
}

Comments

(2) RSS

Go to Bottom

|MELIORITE|

Comments: 144

mIRC Snippet: Autojoin - single click save channels
Posted on Apr 27, 2007 6:39 am

I think this could have been approached from another angle. There is quite a lot of user input required into the substance of the snippet... I might have preferred entering the information into a dialog box or something. Although it has no practical use for me I can see you\'ve given the coding some thought and is otherwise a pretty good job.

Bobbtyisdead

Comments: 6

mIRC Snippet: Autojoin - single click save channels
Posted on May 6, 2007 12:10 pm

Heh, your right ofc, I wasn\'t however coding this snippit for others to use, rather as something for myself and thought it would be useful for others, I\'m not really very good with dialog\'s so I decided to leave it as it is.

Bobbtyisdead

		Student
Last seen: Jun 02, 2007 Profile Snippets (3) Comments Received (10) Comments Submitted (6) Forum Posts (8)

My Snippet Tags

Contact

Add to Friends

Send Private Message