[b]List h1.1

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	4.7
Scores Submitted	3
Date Added	Sep 15, 2006
Last Updated	Sep 17, 2006
Tags	blacklist

Introduction

[b]List: A blacklist that enables users to set individual attributes to blacklistees. Decently scripted dialog for easy control and encrypted output file so noone can "snoop" your blacklist!
Right Click � [b]List

Grab the Code

dialog bList {
  title "[b]List Control Dialog"
  size -1 -1 148 90
  option dbu
  box "[b]List:", 3, 80 2 60 72
  list 9, 82 10 55 61, size
  button "Ok", 1, 1 66 31 9, flat ok
  link "[ A p a x t e a m ]", 2, 34 67 42 8
  box "Enable/Disable", 4, 1 2 74 27
  button "Enable", 5, 4 13 31 9, flat
  button "Disable", 6, 38 13 31 9, flat
  box "Settings", 7, 1 30 75 34
  check "Kick", 10, 6 39 24 10
  check "Ban", 11, 6 49 22 10
  check "KickBan", 12, 39 49 31 10
  check "Slap", 14, 39 39 24 10
  box "Add/Remove", 15, 151 2 79 36
  edit "", 16, 155 12 70 10
  button "Add", 17, 155 24 31 9, flat
  button "Remove", 18, 193 24 31 9, flat
  button "Remove All", 19, 155 41 71 9, flat
  box "Message", 8, 150 50 80 27
  edit "", 13, 154 61 72 10
  button "�", 20, 141 42 6 10, flat
  button "�", 21, 141 29 6 10, flat
  edit "", 22, 1 79 147 10, read
  button "Readme", 23, 155 79 33 10, flat
  button "About", 24, 192 79 33 10, flat
}

menu * {
  -
  [b]List
  .$iif($group(#bList) == on, [Enabled], [Disabled]) { if ($group(#bList) == off) { .enable #bList | set %bList_init 1 } | else { .disable #bList | unset %bList_init } }
  .-
  .Control Dialog: diag
  -
}

alias diag {
  if (!$dialog(bList)) { dialog -md bList bList }
  else { dialog -v bList bList }
}
;simple aliases instead: //echo -ae $x1scht(NICK,1)
alias b_add {
  if ($1) { echo -ae $x1scht($1,1) }
  else { echo -ae [b]List Invalid Parameters }
}

alias b_del {
  if ($1) { echo -ae $x1scht($1,2) }
  else { echo -ae [b]List Invalid Parameters }
}

#bList off
;on join event, filters key(%inscg) to determine method
on 1:JOIN:*: {
  if ($nick != $me) && $istok(%blist,$nick,32) == $true) {
    var %inscg $hget($erac($nick,1),1).item
    if (%inscg == 0001) { describe # slaps $nick around a bit with a large trout }
    elseif (%inscg == 1000) { kick # $nick $hget($erac($nick,1),1).data }
    elseif (%inscg == 0100) { mode # +b $nick $hget($erac($nick,1),1).data }
    elseif (%inscg == 0010) { mode # +b $nick | kick # $nick $hget($erac($nick,1),1).data }
    else { return }
  }
  else { return }
}
#bList end

alias -l filter {
;dialog key(%filter) filter to enable/disable controls
  var %filter = $hget($1,1).item, %diag = bList
  if (%filter == 0001) {
    if ($did(%diag,10).state == 1) { did -u %diag 10 }
    if ($did(%diag,11).state == 1) { did -u %diag 11 }
    if ($did(%diag,12).state == 1) { did -u %diag 12 }
    did -b %diag 10-13 | did -ec %diag 14  | did -r %diag 13
  }
  elseif (%filter == 0010) {
    if ($did(%diag,10).state == 1) { did -u %diag 10 }
    if ($did(%diag,11).state == 1) { did -u %diag 11 }
    if ($did(%diag,14).state == 1) { did -u %diag 14 }
    did -b %diag 10,11,14 | did -ec %diag 12,13
    did -ra %diag 13 $hget($1,1).data
  }
  elseif (%filter == 1000) {
    if ($did(%diag,12).state == 1) { did -u %diag 12 }
    if ($did(%diag,11).state == 1) { did -u %diag 11 }
    if ($did(%diag,14).state == 1) { did -u %diag 14 }
    did -b %diag 12,11,14 | did -ec %diag 10,13
    did -ra %diag 13 $hget($1,1).data
  }
  elseif (%filter == 0100) {
    if ($did(%diag,12).state == 1) { did -u %diag 12 }
    if ($did(%diag,10).state == 1) { did -u %diag 10 }
    if ($did(%diag,14).state == 1) { did -u %diag 14 }
    did -b %diag 12,10,14 | did -ec %diag 11,13
    did -ra %diag 13 $hget($1,1).data
  }
  else { did -eu %diag 10-14 | did -r %diag 13 }
}

on 1:dialog:bList:*:*: {
  if ($devent == init) {
    if ($group(#bList) == on) { did -b $dname 5 | did -e $dname 6 }
    else { did -e $dname 5 | did -b $dname 6 }
    did -b $dname 21 | inscg | did -ra bList 22 [b]List Initialized...
  }
  if ($devent == sclick) {
    if ($did == 23) { run bReadMe.txt }
    if ($did == 24) { run bAbout.txt }
    if ($did == 2) { run http://apaxteam.net/ }
    if ($did == 5) { .enable #bList | did -b $dname 5 | did -e $dname 6 | set %bList_init 1 }
    if ($did == 6) { .disable #bList | did -e $dname 5 | did -b $dname 6 | unset %bList_init }
    if ($did == 14) {
      if ($did(14).state == 1) {
        var %n = $erac($did(16),1), %fi = 0001
        var %sep $+($chr(32),$chr(47))
        did -b $dname 10-13 | hadd -m %n %fi
        write -s $+ %n %bList_dir $+(%n,%sep,$chr(32),%fi)
      }
      else {
        did -e $dname 10-13 | hdel $erac($did(16),1) $hget($erac($did(16),1),1).item
        write -s $+ $erac($did(16),1) %bList_dir $+($erac($did(16),1),$chr(32),$chr(47),$chr(32))
      }
    }
    if ($did == 12) {
      if ($did(12).state == 1) {
        var %n = $erac($did(16),1), %fi = 0010
        var %sep $+($chr(32),$chr(47))
        did -b $dname 10,11,14 | hadd -m %n %fi
        write -s $+ %n %bList_dir $+(%n,%sep,$chr(32),%fi)
      }
      else {
        did -e $dname 10,11,14 | hdel $erac($did(16),1) $hget($erac($did(16),1),1).item
        did -r $dname 22 | write -s $+ $erac($did(16),1) %bList_dir $+($erac($did(16),1),$chr(32),$chr(47),$chr(32))
      }
    }
    if ($did == 10) {
      if ($did(10).state == 1) {
        var %n = $erac($did(16),1), %fi = 1000
        var %sep $+($chr(32),$chr(47))
        did -b $dname 12,11,14 | hadd -m %n %fi
        write -s $+ %n %bList_dir $+(%n,%sep,$chr(32),%fi)
      }
      else {
        did -e $dname 12,11,14 | hdel $erac($did(16),1) $hget($erac($did(16),1),1).item
        did -r $dname 22 | write -s $+ $erac($did(16),1) %bList_dir $+($erac($did(16),1),$chr(32),$chr(47),$chr(32))
      }
    }
    if ($did == 11) {
      if ($did(11).state == 1) {
        var %n = $erac($did(16),1), %fi = 0100
        var %sep $+($chr(32),$chr(47))
        did -b $dname 12,10,14 | hadd -m %n %fi
        write -s $+ %n %bList_dir $+(%n,%sep,$chr(32),%fi)
      }
      else {
        did -e $dname 12,10,14 | hdel $erac($did(16),1) $hget($erac($did(16),1),1).item
        did -r $dname 22 | write -s $+ $erac($did(16),1) %bList_dir $+($erac($did(16),1),$chr(32),$chr(47),$chr(32))
      }
    }
    if ($did == 17) {
      if (!$hget($erac($did(16),1))) {
        did -ra $dname 22 $x1scht($did(16),1)
        did -e $dname 18 | did -b $dname 17 | inscg
      }
      else { return }
    }
    if ($did == 18) {
      if ($hget($erac($did(16),1))) {
        did -ra $dname 22 $x1scht($did(16),2)
        did -e $dname 17 | did -b $dname 18 | inscg
      }
      else { return }
    }
    if ($did == 19) { erad | did -ue $dname 10-14 | did -r $dname 13 }
    if ($did == 9) { did -ra $dname 16 $did(9).seltext | did -e $dname 18 | did -b $dname 17 | filter $erac($did(16),1) }
    if ($did == 20) { dialog -s $dname -1 -1 462 -1 | did -b $dname 20 | did -e $dname 21 }
    if ($did == 21) { dialog -s $dname -1 -1 296 -1 | did -e $dname 20 | did -b $dname 21 }
  }
  if ($devent == edit) {
    if ($did(13).edited == $true) {
      var %sep $+($chr(32),$chr(47)), %init = $hget($erac($did(16),1),1).item
      hadd -m $erac($did(16),1) %init $did(13)
      write -s $+ $erac($did(16),1) bList.bl $+($erac($did(16),1),%sep,$chr(32),%init,$chr(32),$did(13))
    }
    if ($did(16).edited == $true) {
      if ($istok(%blist,$did(16),32) == $false) { did -b $dname 18 | did -e $dname 17 }
      else { did -e $dname 18 | did -b $dname 17 }
    }
  }
}

alias -l erad {
  if ($numtok(%blist,32) > 0) { var %erad = $input(Are you sure you wish to remove all?,qy,[b]List) }
  if (%erad != $false) { unset %blist | .disable #bList | irHsh | dialog -v bList bList }
  did -ra bList 22 [b]List Successfully Cleared | inscg
}

;//echo -a $x1scht($1,1) || $x1scht($1,2)
alias x1scht {
  if (!$1) || (!$2) { return }
  elseif ($2 == 1) && ($istok(%blist,$1,32) == $false) {
    if (!$hget($1,1)) {
      set %blist %blist $1 | hmake $erac($1,1)
      write %bList_dir $+($erac($1,1),$chr(32),$chr(47),$chr(32))
      return [b]List Added: $1 | inscg
    }
  }
  elseif ($2 == 2) && ($istok(%blist,$1,32) == $true) {
    if ($hget($1,1)) {
      set %blist $remtok(%blist,$1,1,32) | hfree $erac($1,1)
      write -ds $+ $erac($1,1) %bList_dir
      return [b]List Removed: $1 | inscg
    }
  }
}

alias -l inscg {
  if ($dialog(bList)) {
    did -r bList 9 | var %c 1
    while (%c <= $lines(%bList_dir)) {
      did -i bList 9 %c $erac($read(%bList_dir,%c),2)
      inc %c 1
    }
  }
}

;instead of the same cmd routine, 1 alias for start and load
on 1:start: { initR }
on 1:load: { initR | echo -ae 2[b]List Loaded; � Right Click for further control  }

alias initR {
  set %bList_dir $scriptdirbList.bl
  if ($file(%bList_dir)) { initL %bList_dir }
  elseif (%bList_init == 1) { .enable #bList }
  elseif (!%bList_init) { .disable #bList }
  elseif (!$file(%bList_dir)) { write bList.bl | set %bList $mircdirbList.bl }
  else { return }
}

alias irHsh {
  if ($file(%bList_dir)) {
    var %file %bList_dir, %c = 1
    while (%c <= $lines(%file)) {
      var %iden = $gettok($read(%file,%c),1,32)
      hfree %iden | inc %c
    }
    write -c %bList_dir
  }
}

alias erac {
  if ($2 == 1) {
    var %enc = $replace($1-,$chr(32),$chr(1)), %i = 0, %x = $len(%enc), %r
    while (%i < %x) {
      inc %i
      %r = $+(%r, ., $base($calc($asc($mid(%enc,%i,1)) * %i),10,16))
    }
    return $mid(%r,2)
  }
  elseif ($2 == 2) {
    var %i = 0, %x = $numtok($1-,46), %r
    while (%i < %x) {
      inc %i
      %r = $+(%r,$chr($calc($base($gettok($1-,%i,46),16,10) / %i)))
    }
    return $replace(%r,$chr(1),$chr(32))
  }
}

alias initL {
  var %i = 1, %x = $1
  while (%i <= $lines(%x)) {
    var %c = $read(%x,%i)
    if ($gettok(%c,3,32) isnum) {
      hadd -m $remtok(%c,$chr(47),1,32)
      inc %i 1
    }
    else { return }
  }
}

Comments

(5) RSS

Go to Bottom

Noutrious

Comments: 355

mIRC Snippet: [b]List h1.1
Posted on Sep 15, 2006 11:31 am

Its a good snippet, but i would give it 7 if it would be in English.

greenlanter420

Comments: 46

mIRC Snippet: [b]List h1.1
Posted on Sep 17, 2006 10:05 am

I must agree converting it to english wouldn't be a bad idea but if you really wanted you or any could use a online translator like babelfish.

sean

Comments: 108

mIRC Snippet: [b]List h1.1
Posted on Sep 17, 2006 7:04 pm

Updated: In english, sorry. lol

Noutrious

Comments: 355

mIRC Snippet: [b]List h1.1
Posted on Oct 13, 2006 5:39 am

Updated my rating.

Tyler222

Comments: 23

mIRC Snippet: [b]List h1.1
Posted on Jun 1, 2007 2:24 pm

doesnt work for me.

[b]List h1.1

Introduction

Grab the Code

Comments

sean

My Snippet Tags

Contact

Friends (10)

Sponsors

		jacksonville, fl
Last seen: Oct 09, 2008 Profile Likes (2) Friends (10) Snippets (11) Images (2) Comments Received (58) Comments Submitted (108) Forum Posts (161)