Oxyd Last Seen Script

Please Register to submit score.

Average Score	5.8
Scores Submitted	5
Date Added	Jan 29, 2006
Last Updated	Jan 30, 2006
Tags	bot last script seen tracker

Introduction

This script is quite simple. Just load it and you're set. It will keep track of what users do, then when somebody needs to locate them, they can type !seen <username / search> in a channel... and it will find either the username, or the latest matches to the search.

Grab the Code

; Hyper's Last Seen Script
; Last Edit: January 30, 2006
; For help...
; irc.enterthegame.com #null
; ...or...
; http://nullprod.abacionline.com/forum

on *:START:{
  if (!$hget(LastSeen)) { .hmake LastSeen 100 }
  if ($exists(LastSeen.hsh)) { .hload LastSeen LastSeen.hsh }
}
on *:TEXT:!seen*:#:{
  if (!$2) { halt }
  else {
    var %seen.entry = $hget(LastSeen,$2), %seen.action = $null, %seen.name = $2
    if ($nick == $2) { msg $chan Hey, Narcisso, stop looking for yourself. | halt }
    elseif ($2 == $me) { describe $chan waves to $nick $+ . | halt }
    elseif ($2 ison $chan) { msg $chan $2 is currently in the channel! | halt }
    elseif (!%seen.entry) {
      var %seen.num = $hfind(LastSeen,* $+ $2 $+ *,0,w)
      if (%seen.num == 0) {
        msg $chan I found no results for your LastSeen query.
        halt
      }
      else {
        var %seen.i = 1
        while (%seen.i <= $hfind(LastSeen,* $+ $2 $+ *,0,w)) {
          write LastSeen.tmp $hfind(LastSeen,* $+ $2 $+ *,%seen.i,w) $hget(LastSeen,$hfind(LastSeen,* $+ $2 $+ *,%seen.i,w))
          inc %seen.i
        }
        filter -ffteu 3 32 LastSeen.tmp LastSeen2.tmp *
        msg $chan I found %seen.num results for your LastSeen query. $iif(%seen.num > 5,Here are the top 5,Here are the results) $+ , starting with the newest result: $gettok($read(LastSeen2.tmp,1),1,32) $gettok($read(LastSeen2.tmp,2),1,32) $gettok($read(LastSeen2.tmp,3),1,32) $gettok($read(LastSeen2.tmp,4),1,32) $gettok($read(LastSeen2.tmp,5),1,32)
        %seen.name = $gettok($read(LastSeen2.tmp,1),1,32)
        .remove LastSeen.tmp
        .remove LastSeen2.tmp
      }
    }
    %seen.entry = $hget(LastSeen,%seen.name)
    %seen.action = $replace($gettok(%seen.entry,3,32),JOIN,joining $gettok(%seen.entry,4,32) $+ .)
    %seen.action = $iif(%seen.action == $gettok(%seen.entry,3,32),$replace($gettok(%seen.entry,3,32),TEXT,talking in $gettok(%seen.entry,4,32) $+ . They were saying: $gettok(%seen.entry,5-,32)),%seen.action)
    %seen.action = $iif(%seen.action == $gettok(%seen.entry,3,32),$replace($gettok(%seen.entry,3,32),ACT,acting in $gettok(%seen.entry,4,32) $+ . They were saying: * $2 $gettok(%seen.entry,5-,32)),%seen.action)
    %seen.action = $iif(%seen.action == $gettok(%seen.entry,3,32),$replace($gettok(%seen.entry,3,32),PART,parting from $gettok(%seen.entry,4,32) $+ $chr(44) stating: $gettok(%seen.entry,5-,32)),%seen.action)
    %seen.action = $iif(%seen.action == $gettok(%seen.entry,3,32),$replace($gettok(%seen.entry,3,32),QUIT,quitting from IRC $+ $chr(44) saying: $gettok(%seen.entry,4-,32)),%seen.action)
    %seen.action = $iif(%seen.action == $gettok(%seen.entry,3,32),$replace($gettok(%seen.entry,3,32),KICKED,being kicked from $gettok(%seen.entry,5,32) by $gettok(%seen.entry,4,32) $+ $chr(44) who stated: $gettok(%seen.entry,6-,32)),%seen.action)
    %seen.action = $iif(%seen.action == $gettok(%seen.entry,3,32),$replace($gettok(%seen.entry,3,32),KICK,kicking $gettok(%seen.entry,4,32) from $gettok(%seen.entry,5,32) $+ $chr(44) stating: $gettok(%seen.entry,6-,32)),%seen.action)
    %seen.action = $iif(%seen.action == $gettok(%seen.entry,3,32),$replace($gettok(%seen.entry,3,32),FROMNICK,changing nicknames from their old nick $+ $chr(44) which was $gettok(%seen.entry,4,32) $+ .),%seen.action)
    %seen.action = $iif(%seen.action == $gettok(%seen.entry,3,32),$replace($gettok(%seen.entry,3,32),CHNICK,changing their nickname to $gettok(%seen.entry,4,32) $+ .),%seen.action)
    %seen.entry = I last saw  $+ %seen.name $+  ( $+ $gettok(%seen.entry,1,32) $+ ) $duration($calc($ctime - $gettok(%seen.entry,2,32))) ago, %seen.action
    msg $chan %seen.entry
  }
}
on *:JOIN:#:{
  .hadd -m LastSeen $nick $address $ctime JOIN $chan
}
on *:TEXT:*:#:{
  .hadd -m LastSeen $nick $address $ctime TEXT $chan $1-
}
on *:ACTION:*:#:{
  .hadd -m LastSeen $nick $address $ctime ACT $chan $1-
}
on *:PART:#:{
  .hadd -m LastSeen $nick $address $ctime PART $chan $1-
}
on *:QUIT:{
  .hadd -m LastSeen $nick $address $ctime QUIT $1-
}
on *:KICK:#:{
  .hadd -m LastSeen $nick $address $ctime KICK $knick $chan $1-
  .hadd -m LastSeen $knick $remove($address($knick,5),$knick $+ !) $ctime KICKED $nick $chan $1-
}
on *:NICK:{
  .hadd -m LastSeen $newnick $address $ctime FROMNICK $nick
  .hadd -m LastSeen $nick $address $ctime CHNICK $newnick
}
on *:DISCONNECT:{
  .hsave -o LastSeen LastSeen.hsh
}
on *:EXIT:{
  .hsave -o LastSeen LastSeen.hsh
}

Comments

(13) RSS

Go to Bottom

xDaeMoN

Comments: 696

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 12:15 am

On each event, you don't have to do /hdel since if the item name is already there, it will just be overwritten.

On this part, '$remove($address($nick,5),$nick $+ !)', you just use '$address'

Hyper

Comments: 11

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 2:31 pm

I do hdel so that it orders the entries. :) I have it sort search results by the newest.

xDaeMoN

Comments: 696

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 2:35 pm

Instead of doing that, you could use /filter to sort the entries :). Just a suggestion.

Hyper

Comments: 11

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 3:47 pm

well, I could do that, but this way works fine. No need to fix it if it isn't broken. :P

bulgarianMAN

Comments: 2

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 5:32 pm

* /hdel: no such table 'LastSeen' (line 49, script14.ini)
-
* /hdel: no such table 'LastSeen' (line 57, script14.ini)
-
* /hdel: no such table 'LastSeen' (line 45, script14.ini)
-
* /hdel: no such table 'LastSeen' (line 45, script14.ini)
-

sux...

Hyper

Comments: 11

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 5:35 pm

restart mIRC, maybe? That script ought to work.

xDaeMoN

Comments: 696

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 5:49 pm

Or just type /hmake LastSeen 100

Yoinx

Comments: 424

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 5:59 pm

Hey xdaemon, do you have a way of filtering a hash table? or are you just saying to save it as an ini/text and filtering that?

xDaeMoN

Comments: 696

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 30, 2006 6:05 pm

@ Yoinx, I loop to each entry, save it in a text file & /filter it there. You could also use a window & /filter it there. I heard that using a window will be much faster.

`Kazuma

Comments: 254

mIRC Snippet: Oxyd Last Seen Script
Posted on Jan 31, 2006 12:15 pm

This is nice, I didn't have problems like bulgarianMAN stated in his comment. I dont have alot of people in and out of my chan, so i wouldnt need a hash table. But it's nice. Good feature.

bearruler

Comments: 24

mIRC Snippet: Oxyd Last Seen Script
Posted on Feb 3, 2006 9:11 am

It has its advantages and disadvantages
I like the last 5 things they did, but theres alot of code involved.
Instead of all those $gettoks, you could make an alias like $s_t($nick) for the time. It can save alot of code space

Bear

ch1zra

Comments: 68

mIRC Snippet: Oxyd Last Seen Script
Posted on Apr 18, 2006 5:20 am

nice code...a good base for developing a full addon anyway :)

I've never wrote a !seen script of mine... you gave me the idea now :)

:thumbsup:

HassanAbbas

Comments: 18

mIRC Snippet: Oxyd Last Seen Script
Posted on Dec 1, 2006 12:03 pm

Good :D

Hyper


Last seen: May 21, 2008 Profile \| Website Scripts (2) Snippets (4) Comments Received (59) Comments Submitted (11) Forum Posts (22)

My Snippet Tags

Contact

Add to Friends

Send Private Message

AOL AIM:

Oxyd Last Seen Script

Introduction

Grab the Code

Comments

Hyper

My Snippet Tags

Contact

Sponsors