New Auto log in

::::::::::::::::::::::::::::
:::::: Coded By eNkIL ::::::
::::::::::::::::::::::::::::
::: Cambiale si sabes =) :::
::::::::::::::::::::::::::::

;Dialogo Autologin

menu menubar,channel,status { 
  Auto-Login con X:diax
  -
}

alias diax {
  if ($dialog(diax) == $null) { dialog -m diax diax } 
  else { .echo -a -Dialogo de Auto-Login con X Ejecutandose.. } 
}

dialog diax {
  title "Auto-Login con X"
  size -1 -1 118 70
  option dbu
  box "",1, 2 2 114 68 
  text "Usuario:",2, 4 10 25 10
  edit "",3, 40 9 45 10, autohs
  text "Contraseña:",4, 4 21 35 10
  edit "",5, 40 19 45 10, pass autohs
  button "Login",6, 85 9 30 10
  button "Limpiar",7, 85 20 30 10  
  check "Mostrar al Conectar",8, 3 32 62 10
  check "Auto-Login al Conectar",9, 3 41 70 10
  check "Esconder IP",10, 3 50 62 10 
  check "Info User",13, 3 59 62 10 
  button "Cerrar", 11, 85 31 30 38, ok 

}

;Alias Dialogo X

alias -l CargaInfologin {
  if (%mostrar.loginalconec) did -c $dname 8
  if (%login.alconectar) did -c $dname 9
  if (%esconde.ip) did -c $dname 10
  if (%muestra.x.info) did -c $dname 13
  did -a $dname 3 %usuario
  did -a $dname 5 %passx2
  unset %passx
  unset %passx3
}

;Eventos dialogo

on *:dialog:diax:*:*: {
  if ($devent = init) {
    CargaInfologin
  }
  if ($devent = edit) { 
    if ($did = 3) { .set %usuario $did($dname,3) }
    if ($did = 5) {
      var %passx $did($dname,5)
      set %passx2 $encode(%passx,m)
    }
  }
  if ($devent = sclick) { 
    if ($did = 6) { 
      if (%esconde.ip) { mode $me +x }
      set %passx3 $decode(%passx2,m)
      .msg X@channels.undernet.org login %usuario %passx3
      unset %passx3
    }
    if ($did = 7) { 
      set %usuario Usuario Nuevo
      set %passx2 
      did -r $dname 3,5 
      did -a $dname 3 %usuario
    }
    if ($did = 8) { set %mostrar.loginalconec $did($dname,8).state }
    if ($did = 9) { set %login.alconectar $did($dname,9).state }
    if ($did = 10) { set %esconde.ip $did($dname,10).state }
    if ($did = 13) { set %muestra.x.info $did($dname,13).state }
  }
}

on *:CONNECT:{
  if (%mostrar.loginalconec) { diax }
  if (%login.alconectar) { 
    if (%esconde.ip) { mode $me +x }
    set %passx3 $decode(%passx2,m)
    .msg X@channels.undernet.org login %usuario %passx3
    unset %passx3
    if (%muestra.x.info) { .msg x info = $+ $me }
  }
}

on 1:input:*: { 
  if ( $1 == xlog )   { 
    var %user123 $input(Usuario,eq,X Logging System.)  
    var %pass123 $input(Contraseña,wp,X Logging System.) 
    .msg X@channels.undernet.org login %user123 %pass123 
    echo -a 14,1(4·!·14)15Sending Info to X.
  }
}