I created this snippet for a topic on the forum, and now I've modified it a bit. This snippet will lookup stats from Outwar.com for any specified player. Refer to the snippet for usage

/*
 Outwar.com Stats Script
 --
 Usage:
  !outwar <Sigil/Torax/Fabar> <User's name>
 --
*/

on *:TEXT:!outwar*:#: {
  if (!$regex($2,(S|s)igil|(T|t)orax|(F|f)abar)) || (!$3) { halt }
  sockopen outwar $+($lower($regml(1)),.outwar.com) 80
  sockmark outwar $2- $chan
}
on *:SOCKOPEN:outwar: {
  var %s = sockwrite -n $sockname
  %s GET $+(/profile.php?transnick=,$gettok($sock($sockname).mark,2,32)) HTTP/1.1
  %s Host: $+($gettok($sock($sockname).mark,1,32),.outwar.com)
  %s Connection: close
  %s $crlf
}
on *:SOCKREAD:outwar: {
  var %a
  sockread -f %a
  if ($+(%s.exp,%s.cl,%s.gr,%s.pa,%s.un)) {
    var %r = $iif(%s.pa,$gettok(%a,5,60),$gettok(%a,4,60))
    var %r = $gettok(%r,2,62)
    set %s $+(%s,$chr(42),$+(%s.exp,%s.cl,%s.gr,%s.pa,%s.un) %r)
    unset %s.*
  }
  else {
    if (*size="1">EXPERIENCE</font>* iswm %a) {
      set %s.exp EXPERIENCE
    }
    if (*size="1">CLASS</font>* iswm %a) {
      set %s.cl CLASS
    }
    if (*size="1">Growth Yesterday</font>* iswm %a) {
      set %s.gr GROWTH YESTERDAY
    }
    if (*size="1">PARENT</font>* iswm %a) {
      set %s.pa PARENT
    }
    if (*href="followers.php?id=4">UNDERLINGS</a>* iswm %a) {
      set %s.un UNDERLINGS
    }
    if (*<a href="crewprofile.php?id=* iswm %a) {
      var %r = $gettok(%a,4,60)
      %r = $gettok(%r,2,62)
      set %s $+(%s,$chr(42),$gettok($sock($sockname).mark,2,32) is a %r)
    }
    if (*</b> Trophy Points</b>* iswm %a) {
      var %r = $gettok(%a,4,60)
      %r = $gettok(%r,2,62)
      set %s $+(%s,$chr(42),TROPHY POINTS %r)
    }
    if (%s.sn) {
      if (*<td width="50%" bgcolor="#666666"><font size="2">* iswm %a) { halt }
      var %r = $gettok(%a,3,60)
      %r = $replace($gettok(%r,2,62),&lt;,<,&tl;,>)
      set %s $+(%s,$chr(42),%s.sn %r)
      unset %s.sn
    }
    if (*<b>SCREEN NAME</b>* iswm %a) {
      set %s.sn AIM S/N
    } 
  }
}
on *:SOCKCLOSE:outwar: {
  var %x = $numtok(%s,42),%y = 1
  msg $gettok($sock($sockname).mark,3,32) 4- Stats for $gettok($sock($sockname).mark,2,32) on $gettok($sock($sockname).mark,1,32) 4-
  while (%y <= %x) {
    .timer 1 1 msg $gettok($sock($sockname).mark,3,32) $gettok(%s,%y,42)
    inc %y
  }
  .timer 1 1 msg $gettok($sock($sockname).mark,3,32) 4- End of Stats 4-
  unset %s
}