Split tokens

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	6.3
Scores Submitted	4
Date Added	Oct 18, 2005
Last Updated	Aug 20, 2006
Tags	split token tokeniser tokenizer

Introduction

Basically works like /tokenize, except you specify a character or string to split tokens by instead of an ascii number. It also fills $sN, $sN-, $sN-N, etc instead of $N, $N- and $N-N.

There are comments in the snippet to show how to use it.

Grab the Code

/*
**
** /split by hixxy (hixxy@mirc.net) for mIRC 6.16 or above.
**
**
** What the script does
** ��������������������
**
** This script is very similar to /tokenize in that it will create a list of token identifiers by tokenizing a string. The main difference is that this lets
** you supply a string to split the string by. You can also keep more than one token list at one time, by giving the list a name.
**
** The easiest way to explain what the token list will contain is with an example.
** If you split "hello.world.x" by "." and name the list "s", the list will be:
**
** $s0  : 3
** $s1  : hello
** $s1-2 : hello world
** $s1-3 : hello world x
** $s1-  : hello world x
** $s2  : world
** $s2-3 : world x
** $s2-  : world x
** $s3  : x
** $s-1  : x
** $s-2  : world
** $s-3  : hello
**
** The $s0 token is the number of tokens.
** The -N tokens are basically the same as the N tokens, but they work backwards. So $-1 is the last token, $-2 the second last, etc.
**
** How to load
** �����������
**
** You can load this script by typing /load -rs <path to split.mrc>
** If you saved the file in your mIRC directory you can just do /load -rs split.mrc
** You can also just copy/paste it into remote from a website and then hit the OK button.
**
** How to use
** ����������
**
** The syntax is /split <name> <string> <string to split>
**
** <name> = the name you want to give the list of tokens. This will be $<name><N>, where <N> is a number.
** <string> = the string you want to use to split up the split string. If you split "x!y!z" by "!", the token list will be x, y and z. Cannot contain spaces.
** <string to split> = the string you want to split up.
**
** The second syntax is /split -c <name>
** This will clear the token list for <name>
**
** If you have aliases named n0, n1, n2, etc, and then use /split n a~b~c, these aliases will be replaced. So I would use unique names for the <name>
** argument. I take no blame should you damage your scripts with this as I have warned you here.
**
** Examples
** ��������
**
** //split s ! hello!world | echo -a $!s1: $s1 ~ $!s2: $s2
** //split n ~ a~b~c~d~e~f | echo -a Split a~b~c~d~e~f into $n0 tokens: $n1-
**
** Contact
** �������
**
** If you have a feature suggestion, bug report or question, please send an email to hixxy@mirc.net
** If you got the script from a scripting website and I (hixxy) submitted the code, you may also leave feedback on the script's comment page.
**
*/

alias -l raiseerror {
  if (!$line($active,0)) { linesep -a }
  echo $colour(info) -a $1-
  linesep -a
  halt
}

alias split {
  if (($1 == -c) && ($0 < 2)) || (($1 != -c) && ($0 < 3)) { raiseerror * /split: Insufficient parameters }
  var %c, %g, %i = 1, %name = $iif($1 == -c,$2,$v1)
  if ($1 == -c) { var %c = $true }
  .alias %name $+ 0
  while ($isalias(%name $+ %i)) {
    .alias %name $+ %i
    %g = %i + 1
    while ($isalias($+(%name,%i,-,%g))) {
      .alias $+(%name,%i,-,%g)
      inc %g
    }
    .alias $+(%name,%i,-)
    inc %i
  }
  %i = %i - 1
  while (%i) {
    .alias $+(%name,-,%i)
    dec %i
  }
  if (!%c) {
    %i = 1
    tokenize 13 $replace($3-,$2,$cr)
    while ($eval($ $+ %i,2) != $null) {
      if (%i < $0) {
        %g = %i + 1
        while ($eval($ $+ %g,2) != $null) {
          .alias $+(%name,%i,-,%g) return $eval($+($,%i,-,%g),2)
          inc %g
        }
      }
      .alias $+(%name,%i) return $eval($ $+ %i,2)
      .alias $+(%name,%i,-) return $eval($+($,%i,-),2)
      inc %i
    }
    %i = %i - 1
    .alias %name $+ 0 return %i
    while (%i) {
      inc %c
      .alias $+(%name,-,%c) return $eval($ $+ %i,2)
      dec %i
    }
  }
}

on *:load:{
  if ($version < 6.16) {
    noop $input(This script is intended for mIRC 6.16 or later, you are using $version $+ .,dho,Invalid version)
    .unload -rs $script
  }
}

Comments

(3) RSS

Go to Bottom

Mpdreamz

Comments: 29

mIRC Snippet: Split tokens
Posted on Oct 27, 2005 5:28 am

Ive had the need to tokenize twice before nice work, ive always wondered (seen this snippet before) why you limited this to just $s and not have it do something like a 3rd split would do $ss and a 4th $sss ?

hixxy

Comments: 28

mIRC Snippet: Split tokens
Posted on Oct 27, 2005 10:18 am

I don\'t understand what you mean by $ss, $sss, etc.

hixxy

Comments: 28

mIRC Snippet: Split tokens
Posted on Aug 20, 2006 1:19 am

Added support for named lists now.

Split tokens

Introduction

Grab the Code

Comments

hixxy

My Snippet Tags

Contact

Sponsors

		Unemployed England
Last seen: Jan 07, 2008 Profile \| Website Snippets (12) Comments Received (61) Comments Submitted (28) Forum Posts (97)