$streamplay

mIRC Code

+ 0 likes

Please Register to submit score.

Average Score	7.7
Scores Submitted	3
Date Added	Oct 18, 2005
Last Updated	Aug 20, 2006
Tags	amp audio stream wmp

Introduction

A snippet to play audio streams from a URL. Requires Windows Media Player.
There are comments included in the code on how to use it.

Grab the Code

Multi feature version.

Email: tidy_trax@mirc.net
IRC: Undernet @#mIRC
Limitations: because mIRC doesn't support COM events I cannot automate the cleanup of objects. You must do this yourself by using /xtcamp::streamstop <object>, unless you use the single-feature version at the end of the file.
Requirements: Windows Media Player (not sure which version).

$getstream(<object>)
Returns: the stream that <object> is connected to.

$getstreamstatus(<object>)
Returns: the status of the specified object. The strings returned from this method are subject to change, but at the time of writing the strings returned are: "Stopped", "Paused" or "Playing: 128 K bits/second" (the number 128 can change) without the quotes.

$streamplay(<stream>)
Description: plays audio from a stream. You can also play files on your hard drive.
Returns: an object that should be used with /xtcamp::streamstop.

/playlistexec <object> <command>
Description: performs <command> on each song in a streaming playlist. The data passed to <command> is "<song> <cr> <URL>" without the quotes.

/setplaylistitem <object> <N>
Description: sets the current item to the Nth item in the playlist.

/streamnext <object>
Description: plays the next song.

/streampause <object>
Description: pauses an audio stream.

/streamprevious <object>
Description: plays the previous song.

/streamresume <object>
Description: resumes a paused audio stream.

/streamstop <object>
Description: stops playing an audio stream and cleans up objects.

Updates:

- Now called just $streamplay, /streamstop, etc.
- Updated to use /noop instead of /!.echo -q
- No longer uses messy $or(,...) hack.

alias getstream {
  if ($com($1)) {
    !.echo -q $com($1,currentMedia,3,dispatch* $1::currentmedia)
    if ($com($1::currentmedia)) {
      noop $com($1::currentmedia,sourceURL,3)
      var %result = $com($1::currentmedia).result
      .comclose $1::currentmedia
      return %result
    }
    return $false
  }
  return $false
}
alias getstreamstatus {
  if ($com($1)) {
    noop $com($1,Status,3)
    return $com($1).result
  }
}
alias playlistexec {
  if ($com($1)) && ($com($1::controls)) {
    noop $com($1,currentPlaylist,3,dispatch* $1::playlist)
    if ($com($1::playlist)) {
      var %count = $or(,$com($1::playlist,Count,3)) $com($1::playlist).result, %item = 0
      while (%item < %count) {
        noop $com($1::playlist,item,3,ui4,%item,dispatch* $1::media)
        if ($com($1::media)) {
          noop $com($1::media,Name,3)
          var %name = $com($1::media).result
          noop $com($1::media,sourceURL,3)
          $2- %name $cr $com($1::media).result
          .comclose $1::media
        }
        inc %item
      }
      .comclose $1::playlist
    }
  }
}
alias setplaylistitem {
  if ($com($1)) && ($com($1::controls)) {
    noop $com($1,currentPlaylist,3,dispatch* $1::playlist)
    if ($com($1::playlist)) {
      noop $com($1::playlist,Count,3)
      if ($2 <= $com($1::playlist).result) {
        noop $com($1::playlist,item,3,ui4,$calc($2 - 1),dispatch* $1::media)
        if ($com($1::media)) {
          noop $com($1::controls,currentItem,4,dispatch,$1::media)
          .comclose $1::media
        }
      }
      .comclose $1::playlist
    }
    noop $com($1,Play,3)
  }
}
alias streampause {
  if ($com($1)) && ($com($1::controls)) !.echo -q $com($1::controls,Pause,3)
}
alias streamnext {
  if ($com($1)) && ($com($1::controls)) !.echo -q $com($1::controls,Next,3)
}
alias streamplay {
  var %obj = obj $+ $ticks
  .comopen %obj WMPlayer.OCX
  if ($com(%obj)) {
    noop $com(%obj,Url,4,bstr,$1)
    noop $com(%obj,Controls,3,dispatch* %obj $+ ::controls)
    if (!$com(%obj $+ ::controls)) {
      .comclose %obj
      return $false
    }
    noop $com(%obj $+ ::controls,Play,3)
    return %obj
  }
  return $false
}
alias streamprevious {
  if ($com($1)) && ($com($1::controls)) noop $com($1::controls,Previous,3)
}
alias streamresume {
  if ($com($1)) && ($com($1::controls)) noop $com($1::controls,Play,3)
}
alias streamstop {
  if ($com($1)) && ($com($1::controls)) {
    noop $com($1::controls,Stop,3)
    .comclose $1::controls
    .comclose $1
  }
}

Single feature version.

This version of the snippet will cleanup objects, but will not let you stop the song or return the current stream of an object.
Usage: /nstreamplay <stream>

alias nstreamplay {
  var %obj = obj $+ $ticks
  .comopen %obj WMPlayer.OCX
  if ($com(%obj)) {
    noop $com(%obj,Url,4,bstr,$1-)
    noop $com(%obj,Controls,3,dispatch* %obj $+ ::controls)
    if (!$com(%obj $+ ::controls)) {
      .comclose %obj
      return
    }
    noop $com(%obj $+ ::controls,Play,3)
    .comclose %obj
    .comclose %obj $+ ::controls
  }
}

Example:
Type /streamex to open an example dialog.
Sorry about the crappy ascii buttons but I'm not going to include a dll with this just for an example dialog.

alias -l add did -a xtcampstreamex 1 $gettok($1-,1,13)
alias streamex dialog -m xtcampstreamex xtcampstreamex

dialog xtcampstreamex {
  title "XTCAmp Stream Example"
  size -1 -1 229 219
  option dbu
  list 1, 0 11 229 193, size vsbar
  edit "", 2, 0 0 229 10, autohs
  check "||", 5, 116 206 25 12, push
  button "[]", 6, 90 206 25 12
  button "|<<", 7, 38 206 25 12
  button "|>", 8, 64 206 25 12
  button ">>|", 9, 142 206 25 12
}
on *:dialog:xtcampstreamex:*:*:{
  if ($devent == init) did -a $dname 2 Enter a stream and then click on |>...
  elseif ($devent == sclick) {
    if ($did == 5) {
      if (Playing: * iswm $getstreamstatus(%stream)) streampause %stream
      else streamresume %stream
    }
    elseif ($did == 6) {
      streamstop %stream
      did -r $dname 1
    }
    elseif ($did == 7) streamprevious %stream
    elseif ($did == 8) {
      set %stream $streamplay($$did(2))
      did -r $dname 1
      .timer 1 3 playlistexec %stream add
    }
    elseif ($did == 9) streamnext %stream
    if ($did isnum 6-) did -u $dname 5
  }
  elseif ($devent $did == dclick 1) {
    setplaylistitem %stream $did(1).sel
    did -u $dname 5
  }
  elseif ($devent == close) {
    streamstop %stream
    unset %stream
  }
}

Comments

(8) RSS

Go to Bottom

Pariah

Comments: 45

mIRC Snippet: $streamplay
Posted on Oct 19, 2005 2:17 pm

why do all the snippets you\'ve posted say they\'re made by tidy_trax?

xDaeMoN

Comments: 696

mIRC Snippet: $streamplay
Posted on Oct 19, 2005 2:43 pm

hixxy is aka tidy_trax.

Yoinx

Comments: 424

mIRC Snippet: $streamplay
Posted on Oct 19, 2005 7:08 pm

hopefully they\'re really the same person, I\'ve seen tidy_trax posting on other scripting sites. But it seems a little odd that he\'d change his nick to post here.

hixxy

Comments: 28

mIRC Snippet: $streamplay
Posted on Oct 19, 2005 8:17 pm

I didn\'t change my nick to post here. I changed my nick a while ago because I got bored of my old one.
The reason I haven\'t bothered changing my email is because I\'ve put that email in every snippet/addon I\'ve released so it\'d be too much of a pain to go around and change them. I\'ve also used it to register at several websites.

Yoinx

Comments: 424

mIRC Snippet: $streamplay
Posted on Oct 19, 2005 11:43 pm

Sorry, I didnt mean anything by it. There are just a buch of people here who rip other people\'s stuff. (you can tell it by what they post in the forums versus what they post for snippets) But regardless. It\'s great to have you here. You\'re one of the better scripters I\'ve met.

hixxy

Comments: 28

mIRC Snippet: $streamplay
Posted on Oct 20, 2005 11:13 am

Yeah I know what you mean.
A lot of the time though, if any of the scripts I post on the forum don\'t work it\'s simply because I haven\'t bothered testing the code (sometimes I\'m over confident that the code will work, I don\'t bother checking that it actually does).

Yoinx

Comments: 424

mIRC Snippet: $streamplay
Posted on Oct 20, 2005 12:23 pm

yeah thats not really what I meant. I mean the people that post asking about simple things with variables. Then post a full addon as a snippet.

hixxy

Comments: 28

mIRC Snippet: $streamplay
Posted on Oct 20, 2005 12:29 pm

Ah I see. Yeah that can be quite annoying sometimes.

$streamplay

Introduction

Grab the Code

Comments

hixxy

My Snippet Tags

Contact

Sponsors

		Unemployed England
Last seen: Jan 07, 2008 Profile \| Website Snippets (12) Comments Received (61) Comments Submitted (28) Forum Posts (97)